LoRa E220 + M5StickC Plus2で無線相互通信する方法

#include <M5Unified.h>        // M5Unified ライブラリ
#include "M5_LoRa_E220_JP.h"  // LoRa E220 JP ライブラリ

#define LED 19  // 本体LED
M5Canvas canvas(&M5.Display); // メモリ描画領域表示（スプライト）のインスタンス作成

LoRa_E220_JP lora;  // LoRa E220 インスタンス作成
struct LoRaConfigItem_t config; // LoRa E220 設定構造体
struct RecvFrame_t data;        // 受信データ構造体

// 関数プロトタイプ宣言
void LoRaRecvTask(void *pvParameters);  // 受信タスク

// グローバル変数宣言
String data_str = ""; // 受信データ保存用文字列

// ログ表示関数（メモリ描画領域とシリアル出力両方に表示）
void print_log(String info) {
  canvas.println(info);     //  メモリ描画領域にログ追記
  canvas.pushSprite(0, 0);  // 画面に反映
  Serial.println(info);     // シリアル出力
}

// メッセージ送信関数
void send_message(String msg) {
  if (lora.SendFrame(config, (uint8_t *)msg.c_str(), msg.length()) == 0) { // メッセージ送信を実行して成功なら
    print_log("Send msg: " + msg); // 送信ログ表示
  } else {
    print_log("Send failed.");  // 送信失敗ログ表示
  }
}

// 初期設定 ***********************************************
void setup() {
  auto cfg = M5.config();       // M5Unified設定取得
  cfg.serial_baudrate = 115200; // シリアル出力初期化
  M5.begin(cfg);                // M5Unified初期化

  // 出力端子設定
  pinMode(LED, OUTPUT);   // 本体LED赤
  digitalWrite(LED, LOW); // 本体LED初期値OFF（LOW）

  // 液晶画面の初期設定
  M5.Display.begin(); // M5.Display初期化
  M5.Display.fillScreen(BLACK); // 背景色
  M5.Display.setRotation(1);    // 画面向き設定（USB位置基準 0：下/ 1：右/ 2：上/ 3：左）
  canvas.createSprite(M5.Display.width(), M5.Display.height()); // canvasサイズ（メモリ描画領域）設定（画面サイズに設定）

  canvas.setFont(&fonts::Font2);          // フォント指定
  canvas.setTextScroll(true);             // 文字スクロール有効化
  canvas.println(">>LoRa E220 JP TEST");  // タイトル表示
  canvas.pushSprite(0, 0);                // 画面に反映

  delay(1000);  // シリアル通信安定化待ち
  // LoRa E220 の UART 設定（Grove: RX=33, TX=32）
  lora.Init(&Serial2, 9600, SERIAL_8N1, 33, 32);

  lora.SetDefaultConfigValue(config); // デフォルト設定値読み込み

  // LoRa E220 初期設定値（日本国内向け推奨設定）
  config.own_address              = 0x0000;           // 自分のアドレス
  config.baud_rate                = BAUD_9600;        // 通信速度(9600bps推奨)
  config.air_data_rate            = BW125K_SF9;       // 空中伝送速度（SF7〜11、大きいほど長距離だが遅い。9が安定）
  config.subpacket_size           = SUBPACKET_200_BYTE; // サブパケットサイズ（200byte MAX）
  config.rssi_ambient_noise_flag  = RSSI_AMBIENT_NOISE_ENABLE;  // RSSI環境雑音表示有効
  config.transmitting_power       = TX_POWER_13dBm;   // 送信出力(13dBmは日本の法規に準拠した最大値)
  config.own_channel              = 0x00;             // 自分のチャンネル
  config.rssi_byte_flag           = RSSI_BYTE_ENABLE; // RSSIバイト表示（ENABLEで受信データ末尾にRSSI値を含める）
  config.transmission_method_type = UART_P2P_MODE;    // 通信方式 P2Pモード（UART_TT_MODE：トランスペアレントモード）
  config.lbt_flag                 = LBT_DISABLE;      // LBT無効
  config.wor_cycle                = WOR_2000MS;       // WORサイクル（WOR通信未使用ならなんでもOK）
  config.encryption_key           = 0x0000;           // 暗号化キー ※同じ暗号化キー同士でのみ通信可能
  config.target_address           = 0x0000;           // 相手のアドレス
  config.target_channel           = 0x00;             // 相手のチャネル

  // 初期化処理
  if (lora.InitLoRaSetting(config) != 0) { // 初期化失敗なら
    print_log("Init error, SW M0,M1 to OFF"); // 設定モード切換え案内
    print_log("or click Btn to skip");  // ボタン押下で初期化スキップ案内
    while (lora.InitLoRaSetting(config) != 0) { // 初期化失敗
      M5.update();  // ボタン状態更新
      if (M5.BtnA.wasPressed() || M5.BtnB.wasPressed()) {
        break;
      }
    }
  }
  print_log("Init succeeded, SW M0,M1 to ON");
  print_log("Click Btn to Send Data");

  // マルチタスク処理開始
  xTaskCreateUniversal(LoRaRecvTask, "LoRaRecvTask", 8192, NULL, 1, NULL, APP_CPU_NUM); // 受信タスク
}

// メインループ ***********************************************
void loop() {
  M5.update();  // ボタン状態更新

  // ボタンA処理
  if (M5.BtnA.wasPressed()) {
    send_message("ON"); // LED点灯コマンド送信
  }
  // ボタンB処理
  if (M5.BtnB.wasPressed()) {
    send_message("OFF");  // LED消灯コマンド送信
  }

  // 受信データ処理
  if (data_str == "ON") { // LED点灯コマンド受信なら
    digitalWrite(LED, HIGH);      // 本体LED赤点灯
    send_message("LED_ON_OK!");   // 返信メッセージ送信
    data_str = "";                // 受信データクリア
  } else if (data_str == "OFF") { // LED消灯コマンド受信なら
    digitalWrite(LED, LOW);       // 本体LED赤消灯
    send_message("LED_OFF_OK!");  // 返信メッセージ送信
    data_str = "";                // 受信データクリア
  }
  delay(100);
}

// 受信タスク
void LoRaRecvTask(void *pvParameters) {
  while (1) {
    if (lora.RecieveFrame(&data) == 0) {  // 受信成功なら
      // 受信データを文字列として格納
      String msg = "";
      for (int i = 0; i < data.recv_data_len; i++) {  // 受信データ表示
        msg += (char)data.recv_data[i];
        // Serial.printf("%c", data.recv_data[i]);
      }
      data_str = msg; // 受信データをグローバル変数に保存
      print_log("recv data: " + msg); // 受信データ表示
      print_log("RSSI: " + String(data.rssi) + " dBm"); // RSSI表示
      Serial.flush(); // シリアル出力フラッシュ
      canvas.pushSprite(0, 0);
    }
    delay(1);
  }
}

#include <M5Unified.h>  // M5Unifiedライブラリ
#define LED 19  // 本体LED

HardwareSerial LoraSerial(2); // UART2を使用（RX=33, TX=32）

// 固定送信モードの宛先アドレスとチャンネル設定
uint8_t header[3] = {0x00, 0x00, 0x00};  // 送信先アドレスH,L + チャンネル　※アドレス0xFFFFならブロードキャスト
// グローバル変数宣言
String data_str = ""; // 受信データ保存用文字列

// ログ表示関数（液晶画面とシリアル出力両方に表示）
void print_log(String info) {
  M5.Lcd.println(info); // 画面出力
  Serial.println(info); // シリアル出力
}

// メッセージ送信関数
void send_message(const String& msg) {
  LoraSerial.write(header, 3); // 固定送信モードの宛先アドレスとチャンネル（ヘッダー）送信
  LoraSerial.print(msg);       // メッセージ本体を送信
  print_log("Send: " + msg);   // ログ表示
}

// 初期設定 *********************************************
void setup() {
  auto cfg = M5.config();       // M5Unified設定取得
  cfg.serial_baudrate = 115200; // シリアル出力初期化
  M5.begin(cfg);                // M5Unified初期化

  // 出力端子設定
  pinMode(LED, OUTPUT);   // 本体LED赤
  digitalWrite(LED, LOW); // 本体LED初期値OFF（LOW）

  // UART2初期化（LoRa E220用）
  LoraSerial.begin(9600, SERIAL_8N1, 33, 32); // RX=33, TX=32 ※Groveコネクタ端子指定
  delay(1000);  // シリアル通信安定化待ち

  // 画面表示設定
  M5.Lcd.setRotation(1);          // 画面回転設定
  M5.Lcd.setFont(&fonts::Font2);  // フォント設定
  M5.Lcd.setTextScroll(true);     // 文字スクロール有効化

  print_log("LoRa E220 JP TEST"); // ログ表示
  print_log("Init Start");

  // LoRa通信 設定書込み（日本国内向け推奨設定）
  uint8_t writeCmd[11] = {0xC0, 0x00, 0x08, // 書込みコマンドC0, 開始Add, 書込みByte数
                          0x00, 0x00,  // ADD_H, ADD_L ※自分のアドレス
                          0x70,   // 7-5bit:UART設定 9600bps（推奨） / 4-0bit：空中伝送速度 125kHz_SF9（安定通信向け）
                          0x20,   // 7-6bit:パケットサイズ 200byte（最大） / 5bit：RSSI環境ノイズ有効 / 4-2bit：none / 1-0bit：送信出力電力 13dBm（最大）
                          0x00,   // 周波数チャンネル 920.6MHz（BW125kHzの時）
                          0xC3,   // 7bit:RSSIバイト有効 / 6bit：固定送信(P2P)モード /5-3bit：none / 2-0bit：WORサイクル2000ms ※トランスペアレントモードは0x83
                          0x00, 0x00}; // KEY_H, KEY_L ※同じ暗号化キー同士でのみ通信可能
  LoraSerial.write(writeCmd, 11); // 書込みコマンド送信
  delay(1000); // 書込み完了待ち

  // 設定モード（M0,M1スイッチOFF）なら設定完了結果を表示（FF FF FFはエラー）
  if (LoraSerial.available()) { // 返答があれば
    while (LoraSerial.available()) {  // 返答を読み取る
      uint8_t b = LoraSerial.read();  // 受信バイト取得
      Serial.printf("%02X ", b);  // シリアル出力
      M5.Lcd.printf("%02X ", b);  // 画面出力
    }
    Serial.println();
    M5.Lcd.println();
  } else { // 返答がない場合、スイッチ確認を促す
    print_log("No Response. Check M0/M1 Switch.");
  }
}

// メインループ *********************************************
void loop() {
  M5.update();  // M5ボタン状態更新

  // ボタンA処理
  if (M5.BtnA.wasPressed()) {
    send_message("ON"); // LED点灯コマンド送信
  }
  // ボタンB処理
  if (M5.BtnB.wasPressed()) {
    send_message("OFF"); // LED消灯コマンド送信
  }

  // 受信データ処理
  if (LoraSerial.available()) { // 受信データがあれば
    uint8_t buf[200];  // 受信バッファ
    int len = 0;       // 受信データ長
    // 受信データをバッファに格納
    while (LoraSerial.available()) {
        buf[len++] = LoraSerial.read();
    }
    // 最後の1バイトからRSSI値を取得
    uint8_t rssi_raw = buf[len - 1];  // RSSI生データ取得
    len--;                            // データ本体の長さを調整
    int rssi_dbm = -(256 - rssi_raw); // RSSI換算値計算（データシートより）

    // 受信データ本体を文字列に変換して表示
    char msg[201];  // 終端文字分 +1
    for (int i = 0; i < len; i++) {
        msg[i] = (char)buf[i];  // バイトを文字に変換
    }
    msg[len] = '\0';  // 終端文字を付ける
    data_str = msg;   // 受信データをグローバル変数に保存

    print_log("Recv data: " + String(msg)); // ログ表示
    print_log("RSSI: " + String(rssi_dbm) + " dBm"); // ログ表示
  }

  // 受信データ処理
  if (data_str == "ON") {         // LED点灯コマンド受信なら
    digitalWrite(LED, HIGH);      // 本体LED赤点灯
    send_message("LED_ON_OK!");   // 完了メッセージ送信
    data_str = "";                // 受信データクリア
  } else if (data_str == "OFF") { // LED消灯コマンド受信なら
    digitalWrite(LED, LOW);       // 本体LED赤消灯
    send_message("LED_OFF_OK!");  // 完了メッセージ送信
    data_str = "";                // 受信データクリア
  }
  delay(100); 
}