Arduinoタッチスイッチの使い方、M5Stack AtomS3 Lite使用

// 使用例
touchRead(5);

// 使用例
touchSetCycles(500, 500);

// 使用例
// タッチ割り込み処理関数
void gotTouch() {
  touchdetected = true;  // タッチ割り込みフラグON
}
// タッチイベント設定（初期設定）
void setup() {
  touchAttachInterrupt(5, gotTouch, 1000);
}

// 使用例
if (touchInterruptGetLastStatus(5) {  // 端子5に触れていれば
  // ここに触れている時の処理を書く
} else {                              // 端子5に触れていいなければ
  // ここに触れていない時の処理を書く
}

// 使用例
touchDetachInterrupt(5);

// 使用例
touchSleepWakeUpEnable(5, 3000);

#include <M5AtomS3.h> // ヘッダーファイル準備（別途FastLEDライブラリをインストール）

#define TOUCH_PIN1 5  // タッチ端子番号1
#define TOUCH_PIN2 6  // タッチ端子番号2

// FastLEDライブラリでフルカラーLEDを使用するための設定
CRGB dispColor(uint8_t r, uint8_t g, uint8_t b) {
  return (CRGB)((r << 8) | (g << 16) | b);
}
// 変数宣言
int threshold1 = 3000;        // しきい値1（感度）充放電回数の変化（小さいと感度が良い）
int threshold2 = 1000;        // しきい値2（感度）充放電回数の変化（小さいと感度が良い）
bool touch1detected = false;  // タッチ割り込み発生フラグ1
bool touch2detected = false;  // タッチ割り込み発生フラグ2
bool toggle = false;          // タッチ状態格納用
int cnt = 0;                  // シリアル出力タイミングカウント用

// 割り込み処理 ----------------------------------------------
// タッチ割り込み処理1
void gotTouch1() {
  touch1detected = true;  // タッチ割り込みフラグ1 ON
}
// タッチ割り込み処理2
void gotTouch2() {
  touch2detected = true;  // タッチ割り込みフラグ2 ON
}

  // 初期設定 -------------------------------------------------
void setup() {
  auto cfg = M5.config(); // 本体初期設定
  AtomS3.begin(cfg, true);

  Serial.begin(9600); // USBシリアル通信初期化
  delay(1000);        // シリアル出力開始待ち
  Serial.println("AtimS3 Lite TEST"); // シリアル通信出力

  // タッチスイッチ設定（ピン番号, タッチ割り込み発生時実行関数, しきい値）
  touchAttachInterrupt(TOUCH_PIN1, gotTouch1, threshold1); // タッチ1設定
  touchAttachInterrupt(TOUCH_PIN2, gotTouch2, threshold2); // タッチ2設定

  AtomS3.dis.drawpix(dispColor(40, 40, 40));  // 本体LED色指定
}

// メイン ---------------------------------------------------
void loop() {
  // タッチスイッチ処理1（モーメンタリ：触れた時と離した時に処理を実行）
  if (touch1detected) {                             // タッチ割り込みフラグ1がONなら
    touch1detected = false;                         // タッチ割り込みフラグ1をOFFする
    Serial.printf("Value1: %d - ", touchRead(TOUCH_PIN1)); // タッチ1の値シリアル出力
    if (touchInterruptGetLastStatus(TOUCH_PIN1)) {  // タッチ1に触れていれば
      AtomS3.dis.drawpix(dispColor(50, 0, 0));          // 本体LED色指定
      Serial.println("Touch1 Touched!");         // タッチ状態シリアル出力
    } else {                                        // タッチ1に触れていなければ
      AtomS3.dis.drawpix(dispColor(40, 40, 40));        // 本体LED色指定
      Serial.println("Touch1 Released!");        // タッチ状態シリアル出力
    }
  }
  // タッチスイッチ1に触れている間ずっと実行したい場合有効にする
  // if (touchInterruptGetLastStatus(TOUCH_PIN1)) {
  //   AtomS3.dis.drawpix(dispColor(0, 50, 0));  // 本体LED色指定
  // }

  // タッチスイッチ処理2（オルタネイト:ONするごとに処理を切り替え）
  if (touch2detected) {                                               // タッチ割り込みフラグ2がONなら
    touch2detected = false;                                           // タッチ割り込みフラグ2をOFFする
    Serial.printf("Value2: %d - ", touchRead(TOUCH_PIN2));         // タッチ2の値シリアル出力
    if (touchInterruptGetLastStatus(TOUCH_PIN2) && toggle == false) { // タッチスイッチに触れていて、toggleがfalseなら
      AtomS3.dis.drawpix(dispColor(0, 0, 50));                            // 本体LED色指定
      Serial.println("Touch2 Touched!(false)");                    // タッチ状態シリアル出力
    }
    if (touchInterruptGetLastStatus(TOUCH_PIN2) && toggle == true) {  // タッチスイッチに触れていて、toggleがtrueなら
      AtomS3.dis.drawpix(dispColor(40, 40, 40));                          // 本体LED色指定
      Serial.println("Touch2 Touched!(true)");                     // タッチ状態シリアル出力
    }
    if (!touchInterruptGetLastStatus(TOUCH_PIN2)) {   // タッチスイッチに触れていなければ
      toggle = !toggle;                               // タッチ2状態反転
      Serial.println("Touch2 Released!");          // タッチ状態シリアル出力
    }
  }
  // タッチボタン1状態シリアル出力
  if (cnt == 40) { // シリアル出力タイミングカウントが40なら
    cnt = 0;       // カウント値初期化
    Serial.printf("Value1: %d, State1: %d\n", touchRead(TOUCH_PIN1), touchInterruptGetLastStatus(TOUCH_PIN1));  // シリアル出力
  }

  cnt++;          // シリアル出力タイミングカウント+1
  AtomS3.dis.show();  // 本体フルカラーLED出力
  delay(50);      // 遅延時間
}

// タッチスイッチ処理1（モーメンタリ：触れた時と離した時に処理を実行）
if (touch1detected) {                             // タッチ割り込みフラグ1がONなら
  touch1detected = false;                         // タッチ割り込みフラグ1をOFFする
  if (touchInterruptGetLastStatus(TOUCH_PIN1)) {  // タッチ1に触れていれば
    // ここに触れた時に実行したい処理を書く・・・
  } else {                                        // タッチ1に触れていなければ
    // ここに離した時に実行したい処理を書く・・・
  }
}
// タッチスイッチ1に触れている間ずっと実行したい場合有効にする
// if (touchInterruptGetLastStatus(TOUCH_PIN1)) {
//   // ここに触れている間ずっと実行したい処理を書く・・・
// }

// タッチスイッチ処理2（オルタネイト:ONするごとに処理を切り替え）
if (touch2detected) {                                               // タッチ割り込みフラグ2がONなら
  touch2detected = false;                                           // タッチ割り込みフラグ2をOFFする
  if (touchInterruptGetLastStatus(TOUCH_PIN2) && toggle == false) { // タッチスイッチに触れていて、toggleがfalseなら
    // ここにONした時に実行したい処理を書く・・・
  }
  if (touchInterruptGetLastStatus(TOUCH_PIN2) && toggle == true) {  // タッチスイッチに触れていて、toggleがtrueなら
    // ここにもう一度ONした時に実行したい処理を書く・・・
  }
  if (!touchInterruptGetLastStatus(TOUCH_PIN2)) {   // タッチスイッチに触れていなければ
    toggle = !toggle;                               // タッチ2状態反転
  }
}