ラズパイPicoでSSD1306有機ELディスプレイの使い方 C言語編

#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h> // 別途「Adafruit BusIO」ライブラリ必要

// OLED設定
#define SCREEN_WIDTH 128  // OLED 幅指定
#define SCREEN_HEIGHT 64  // OLED 高さ指定（高さ32のものを使用する場合は32）
#define OLED_RESET -1     // リセット端子（未使用-1）
#define BTN1 11           // ボタン1端子番号指定
#define BTN2 15           // ボタン2端子番号指定

// I2Cに接続されたSSD1306用「display」の宣言
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

// 変数宣言
int cnt = 0;        // ボタンを押した回数カウント用
bool state = false; // ボタン状態保持用

// 初期設定 --------------------------------------------------
void setup() {
  // 本体初期化
  Wire.setSDA(16);  // I2C0 SDA 端子番号設定
  Wire.setSCL(17);  // I2C0 SCL 端子番号設定
  Wire.begin();     // I2C通信開始設定(SDA,SDL)　※(0, 1 / 4, 5 / 8, 9 / 12, 13 / 16, 17 / 20, 21)

  // OLED初期設定
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("SSD1306:0 allocation failed"));
    for (;;); // エラーなら無限ループ
  }
  // OLED表示設定
  display.setTextColor(SSD1306_WHITE);  // 文字色

  pinMode(BTN1, INPUT_PULLUP); // ボタン1の端子を入力端子（プルアップ）に設定
  pinMode(BTN2, INPUT_PULLUP); // ボタン2の端子を入力端子（プルアップ）に設定
}
// メイン -------------------------------------------------
void loop() {
  display.clearDisplay();     // 表示クリア

  // タイトル表示
  display.setTextSize(1);     // 文字サイズ（1）
  display.setCursor(4, 0);    // 表示開始位置左上角（X,Y）
  display.println("OLED");    // 表示内容
  display.setCursor(4, 10);   // 表示開始位置左上角（X,Y）
  display.println("TEST");    // 表示内容

  display.setTextSize(2);     // 文字サイズ（2）
  display.setCursor(39, 2);   // 表示開始位置左上角（X,Y）
  display.println("SSD1306"); // 表示内容

  // 本体ボタンON/OFF状態表示
  display.setTextSize(1);         // 文字サイズ（1）
  display.setCursor(5, 28);       // 表示開始位置左上角（X,Y）
  if (digitalRead(BTN1) == 0) {   // ボタン1が押されていれば（ずっと）
    display.println("BTN = ON");  // 表示内容
  } else {                        // ボタン1が押されてなければ
    display.println("BTN = OFF"); // 表示内容
  }
  
  // ボタン2 ON回数カウント表示
  if (digitalRead(BTN2) == 0 && state == false) {  // ボタン2が押されていたら（押された時だけ）
    state = true;                 // ボタン状態ONセット
    cnt++;                        // カウント+1
  }
  if (digitalRead(BTN2) == 1) {   // ボタン2が押されてなければ
    state = false;                // ボタン状態OFFセット
  }
  display.setCursor(72, 28);          // 座標を指定
  display.printf("CNT=%04d\n", cnt);  // カウント数

  // 図形表示
  display.drawLine(0, 20, 128, 20, WHITE);   // 線（始点終点指定）
  display.drawFastVLine(64, 22, 17, WHITE);  // 線（指定座標から垂線）
  display.drawFastHLine(0, 40, 128, WHITE);  // 線（指定座標から平行線）

  display.drawCircle(10, 55, 8, WHITE);      // 円
  display.fillCircle(30, 55, 8, WHITE);      // 円（塗り潰し）

  display.drawTriangle(46, 62, 54, 48, 62, 62, WHITE); // 三角
  display.fillTriangle(66, 62, 74, 48, 82, 62, WHITE); // 三角（塗り潰し）

  display.drawRect(90, 47, 16, 16, WHITE);   // 四角
  display.fillRect(110, 47, 16, 16, WHITE);  // 四角（塗り潰し）

  display.display();  // 表示実行

  delay(100);
}

#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h> // 別途「Adafruit BusIO」ライブラリ必要

// 本体初期化（UART無効, I2C有効, LED有効）
M5.begin(false, true, true);
Wire.begin(26, 32);   //Grove端子をI2C設定(SDA,SDL)

// 本体初期化
Wire.setSDA(16);  // I2C0 SDA 端子番号設定
Wire.setSCL(17);  // I2C0 SCL 端子番号設定
Wire.begin();     // I2C通信開始設定(SDA,SDL)　※(0, 1 / 4, 5 / 8, 9 / 12, 13 / 16, 17 / 20, 21)

// 文字の表示
display.setTextSize(倍率);   // 文字サイズの倍率を指定（1〜8）※実用的なのは4まで
display.setCursor(x, y);    // 表示開始位置左上角座標指定（x, y）
display.println("表示内容"); // 表示出力

// 図形の表示
display.drawLine(x1, y1, x2, y2, WHITE);      // x1,y1 から x2,y2 の線
display.drawFastVLine(x1, y1, 長さ, WHITE);   // x1,y1 から下へ垂線
display.drawFastHLine(x1, y1, 長さ, WHITE);   // x1,y1 から左から右へ平行線

display.drawCircle(x1, y1, 半径, WHITE);      // 中心座標x1,y1 から半径を指定した円
display.fillCircle(x1, y1, 半径, WHITE);      // 中心座標x1,y1 から半径を指定した塗り潰し円

display.drawTriangle(x1, y1, x2, y2, x3, y3, WHITE); // x1,y1 と x2,y2 と x3,y3 を結ぶ三角
display.fillTriangle(x1, y1, x2, y2, x3, y3, WHITE); // x1,y1 と x2,y2 と x3,y3 を結ぶ塗り潰し三角

display.drawRect(x1, y1, 幅, 高さ, WHITE);   // x1,y1（左上）から幅と高さを指定した四角
display.fillRect(x1, y1, 幅, 高さ, WHITE);   // x1,y1（左上）から幅と高さを指定した塗り潰し四角