M5StickC Plus2 I2C通信で温度、湿度測定ENV IVセンサの使い方

#include <M5StickCPlus2.h>
#include <Wire.h>

#define SHT3X_ADDR 0x44   // SHT3X（温度、湿度センサ）I2C通信アドレス
M5Canvas canvas(&M5.Lcd); // 液晶表示用、メモリ描画領域表示（スプライト）のインスタンスを作成

// 変数宣言
float data[6];           // 温度、湿度受信データ格納用
float t_ticks;           // 温度計算用
float rh_ticks;          // 湿度計算用
unsigned int checksum_t; // 温度受信データチェックサム(CRC)
unsigned int checksum_rh;// 湿度受信データチェックサム(CRC)
float t_degC = 0.0;      // 温度換算データ格納用
float rh_pRH = 0.0;      // 湿度換算データ格納用

// 初期設定 -----------------------------------------
void setup() {
  auto cfg = M5.config();  // 本体初期設定
  StickCP2.begin(cfg);  

  Wire.begin(32, 33);  // I2C通信初期化　SDA=32, SCL=33
  Serial.begin(9600);  // シリアル通信初期化
  while (!Serial) {
      delay(100);
  }
  // ベース画面の初期設定
  M5.Lcd.fillScreen(BLACK); // 背景色
  M5.Lcd.setRotation(1);    // 画面向き設定（USB位置基準 0：下/ 1：右/ 2：上/ 3：左）
  M5.Lcd.setTextSize(1);    // 文字サイズ（整数倍率）

  canvas.setTextWrap(false);  // 改行をしない（画面をはみ出す時自動改行する場合はtrue。書かないとtrue）
  canvas.createSprite(M5.Lcd.width(), M5.Lcd.height()); // canvasサイズ（メモリ描画領域）設定（画面サイズに設定）
}

// メイン -----------------------------------------
void loop() {
  // I2Cデータ送信
  Wire.beginTransmission(SHT3X_ADDR); // デバイスアドレスを指定して I2C通信開始
  Wire.write(0xFD);           // 要求コマンド送信（高精度測定を指定）
  Wire.endTransmission(true); // 書き込み完了
  delay(10);                  // データ受信待ち（時間はデータシートによる:0.01s）

  // I2Cデータ受信（温度、湿度それぞれ 測定データ:8bit ×2 + CRC:8bit で合計6byte）
  Wire.requestFrom(SHT3X_ADDR, 6); // 受信データリクエスト（6byte）
  for (int i = 0; i < 6; i++) {    // 6byte分繰り返し
    data[i] = Wire.read();         // 受信データ格納
  }

  // 受信データを温度、湿度に換算（データシートより抜粋）
  t_ticks = data[0] * 256 + data[1];
  checksum_t = data[2];
  rh_ticks = data[3] * 256 + data[4];
  checksum_rh = data[5];
  t_degC = -45 + 175 * t_ticks/65535;
  rh_pRH = -6 + 125 * rh_ticks/65535;
  if (rh_pRH > 100) {
    rh_pRH = 100;
  }
  if (rh_pRH < 0) {
    rh_pRH = 0;
  }

  // 各データシリアル出力
  Serial.printf("%.0f, %.0f, %.1f, %.1f, 0x%02X, 0x%02X\n", t_ticks, rh_ticks, t_degC, rh_pRH, checksum_t, checksum_rh);

  // LCD表示
  canvas.fillScreen(BLACK);                 // 画面初期化
  canvas.setCursor(0, 0);                   // メモリ描画領域の表示座標指定
  canvas.setFont(&fonts::Font4);            // フォント
  canvas.printf("I2C  ENV.IV ( SHT40 )\n"); // タイトル表示
  canvas.drawFastHLine(0, 30, 230, WHITE);  // 水平線（x, y, 長さ）
  canvas.setCursor(0, 35);                  // メモリ描画領域の表示座標指定
  canvas.setFont(&fonts::lgfxJapanGothicP_36); // フォント（日本語：ゴシック体）
  canvas.printf("温度：%.1f℃\n", t_degC);    // 温度表示
  canvas.printf("湿度：%.1f％\n", rh_pRH);   // 湿度表示

  canvas.pushSprite(&M5.Lcd, 8, 8);  // モリ描画領域を指定座標に一括表示実行
  delay(1000);  // 遅延時間
}

#include <Wire.h>

// 初期設定
void setup() {
  Wire.begin(32, 33); // I2C通信端子指定(SDA, SCL)
}

// I2C通信データ要求コマンド送信
Wire.beginTransmission(I2C_ADDR); // デバイスアドレスを指定して通信開始
Wire.write(REG_ADDR1);            // 読み取りレジスタアドレス（要求コマンド）を指定して書き込み
Wire.write(REG_ADDR2);            // 複数指定する必要がある時は続けて書き込み
Wire.endTransmission(true);       // 書き込み完了
delay(100)                        // データ受信待機（時間はデータシートで確認）

// データ受信（読み取り）
Wire.requestFrom(I2C_ADDR, byte); // 受信データリクエスト（I2Cアドレスと受信データバイト数指定）
data = Wire.read();               // データを受信し変数（複数バイトは配列）に格納

// I2C通信データ送信（書き込み）※受信の時と同じ手順
Wire.beginTransmission(I2C_ADDR); // デバイスアドレスを指定して通信開始
Wire.write(REG_ADDR);             // 書き込みレジスタアドレス指定して書き込み
Wire.write(data1);                // データ書き込み（複数の場合はfor文等で連続指定）
Wire.endTransmission(true);       // 書き込み完了

Sensirion I2C SHT4x
Sensirion Core
Adafruit BMP280 Library
Adafruit Unified Sensor

#include <M5StickCPlus2.h>
#include <SensirionI2cSht4x.h>
#include <Adafruit_BMP280.h>
#include "Adafruit_Sensor.h"

Adafruit_BMP280 bmp;      // 気圧センサBMP280用のインスタンスを作成
SensirionI2cSht4x sht4x;  // 温湿度センサSHT40用のインスタンスを作成
M5Canvas canvas(&M5.Lcd); // 液晶表示用、メモリ描画領域表示（スプライト）のインスタンスを作成

// 変数宣言
float temperature, pressure, humidity;  // 測定値格納用
uint16_t error;         // SHT40エラー格納用
char errorMessage[256]; // SHT40エラーメッセージ格納用

// 初期設定 -----------------------------------------
void setup() {
  auto cfg = M5.config();  // 本体初期設定
  StickCP2.begin(cfg);  

  Wire.begin(32, 33);  // I2C通信初期化　SDA=32, SCL=33
  Serial.begin(9600);  // シリアル通信初期化
  while (!Serial) {
      delay(100);
  }
    
  // ベース画面の初期設定
  M5.Lcd.fillScreen(BLACK); // 背景色
  M5.Lcd.setRotation(1);    // 画面向き設定（USB位置基準 0：下/ 1：右/ 2：上/ 3：左）
  M5.Lcd.setTextSize(1);    // 文字サイズ（整数倍率）

  canvas.setTextWrap(true); // 改行をする（画面をはみ出す時自動改行する場合はtrue。書かないとtrue）
  canvas.createSprite(M5.Lcd.width()-10, M5.Lcd.height()); // canvasサイズ（メモリ描画領域）設定（画面サイズに設定）
  canvas.setCursor(0, 0);   // 表示座標
  canvas.setFont(&fonts::Font4); // フォント

  // 気圧センサ BMP280初期化
  while (!bmp.begin(0x76)) {  // 通信失敗でエラー処理
    Serial.println("BMP280 fail"); // シリアル出力
    canvas.setCursor(0, 0);        // 液晶表示
    canvas.println("BMP280 fail");
    canvas.pushSprite(&M5.Lcd, 10, 15); // 画面を指定座標に一括表示実行
    delay(1000);
  }
  // BMP280のサンプリングレートとフィルタ設定
  bmp.setSampling(Adafruit_BMP280::MODE_NORMAL,   // モード：ノーマル
                  Adafruit_BMP280::SAMPLING_X2,   // 温度サンプリングレート：2倍
                  Adafruit_BMP280::SAMPLING_X16,  // 圧力サンプリングレート：16倍
                  Adafruit_BMP280::FILTER_X16,    // フィルタ：16倍
                  Adafruit_BMP280::STANDBY_MS_500);  // 待ち時間：500ms
  Serial.println("BMP280 OK!");

  // 温湿度センサ SHT40初期化
  sht4x.begin(Wire, 0x44);
  uint32_t serialNumber;                     // シリアルナンバー格納用
  error = sht4x.serialNumber(serialNumber);  // シリアルナンバー取得実行
  if (error) {  // シリアルナンバー取得失敗でエラー処理
    Serial.print("SHT40 Error: ");
    errorToString(error, errorMessage, 256);
    Serial.println(errorMessage);
  } else {      // シリアルナンバー取得成功で準備完了
    Serial.println("SHT40 OK!");
    Serial.print("Serial Number: ");
    Serial.println(serialNumber);
  }
}

// メイン -----------------------------------------
void loop() {
  // LCD表示設定
  canvas.fillScreen(BLACK); // 画面初期化
  canvas.setFont(&fonts::lgfxJapanGothicP_28);  // フォント
  canvas.setCursor(0, 0);   // メモリ描画領域の表示座標指定

  // 圧力データ取得
  pressure = bmp.readPressure();

  // 温湿度データ取得、エラー処理
  error = sht4x.measureHighPrecision(temperature, humidity);
  if (error) {  // trueならエラー処理
    errorToString(error, errorMessage, 256); // エラーを文字列に変換
    Serial.print("SHT40 Error: "); // シリアル出力
    Serial.println(errorMessage);

    canvas.setFont(&fonts::Font4); // 液晶表示
    canvas.printf("SHT40 Error:\n");
    canvas.print(errorMessage);
  } else {      // falseで測定データ表示実行
    Serial.printf("Press:%.0fhPa, Temp:%.1fc, Hum:%.1f%%\n", pressure, temperature, humidity); // シリアル出力

    canvas.printf("気圧：%.0fhPa\n", pressure / 100); // 液晶表示
    canvas.printf("温度：%.1f℃\n", temperature);
    canvas.printf("湿度：%.1f％\n", humidity);
  }
  canvas.pushSprite(&M5.Lcd, 10, 15);  // 画面を指定座標に一括表示実行
  delay(1000);  // 遅延時間
}