タイマー割込みをストプウォッチの動作で紹介「ATOM LITE ＋ OLED液晶」

#include <M5Atom.h>
#include <M5UnitOLED.h> //M5GFXライブラリ使用

// OLED設定(M5GFX)
M5UnitOLED display(26, 32, 400000); //任意の端子でI2Cを使用する場合（SDA, SCL, FREQ）

// FastLED（CRGB構造体）設定
CRGB dispColor(uint8_t r, uint8_t g, uint8_t b) {
  return (CRGB)((r << 8) | (g << 16) | b);
}

// グローバル変数宣言
int start = 0;    //カウント開始フラグ
int sec = 0;      //秒カウント用
int minute = 0;   //分カウント用

// 割込み内で使用する変数宣言(volatileで保持領域を固定して宣言)
volatile int count = 0;   //10msタイマカウンタ用
volatile int sec_up = 0;  //1秒経過フラグ用

// タイマ割込み設定
hw_timer_t * tim0 = NULL;                   //タイマー0の割り込みtim0で定義
volatile SemaphoreHandle_t timerSemaphore;  //セマフォの宣言（割込み発生の確認用）
portMUX_TYPE timerMux = portMUX_INITIALIZER_UNLOCKED; //排他制御の利用を宣言

// tim0のタイマー割り込みハンドラ。この処理はsetupより先に書く
// タイマ割込み発生時に実行される処理 (IRAM_ATTRで宣言してRAM上に配置）
void IRAM_ATTR onTimer() {
  portENTER_CRITICAL_ISR(&timerMux);  //排他制御で以下を実行（割込み禁止）
  if(start == 1) {                    //カウント開始フラグが1なら
    count++;                          //10msタイマカウンタ +1
    if (count >= 100) {               //100回＝1秒経過していたら
      sec_up = 1;                     //1秒経過フラグをON (メイン処理でリセットする）
      count = 0;                      //10msタイマカウンタをリセット
    }
  }
  portEXIT_CRITICAL_ISR(&timerMux);   //排他制御終了（割り込み許可）
  xSemaphoreGiveFromISR(timerSemaphore, NULL);  //セマフォを開放
}

//-------------------------------------------------
// 初期設定
//-------------------------------------------------
void setup() {
  M5.begin(false, false, true);  //Serial,POWER,LED

  // タイマ割込み設定
  timerSemaphore = xSemaphoreCreateBinary();  //バイナリセマフォを作成(0か1のバイナリ)
  tim0 = timerBegin(0, 80, true);             //タイマー0を80MHz/80（1us）動作ｶｳﾝﾄｱｯﾌﾟでtim0に設定
  timerAttachInterrupt(tim0, &onTimer, true); //tim0割込みが発生した時に実行する処理を指定「onTime」
  timerAlarmWrite(tim0, 10000, true);         //tim0割込み発生周期を10ms（1us × 10000）に設定
  timerAlarmEnable(tim0);                     //タイマー0割込みを有効化

  // OLED液晶表示設定（M5GFXライブラリ使用）
  display.init();               //表示器の初期化
  display.setRotation(1);       //表示方向(コネクタ位置基準)：0下、1右、2上、3左
  display.setColorDepth(1);     //モノクロ
  display.setTextWrap(false);   //自動改行をしない

  //　OLED液晶初期画面
  display.clearDisplay();             //表示クリア

  display.setFont(&fonts::lgfxJapanGothicP_16); //フォント設定（ゴシック体）
  display.setTextSize(1);             //文字サイズ）
  display.setCursor(0, 0);            //座標を指定（1行目）
  display.printf("ストップウォッチ");  //タイトル

  display.drawFastHLine(0, 20, 128, TFT_WHITE);               //横線
  display.fillTriangle(50, 24, 52, 24, 50, 28, TFT_WHITE);    //三角
  display.fillTriangle(103, 24, 105, 24, 103, 28, TFT_WHITE); //三角
  display.fillTriangle(108, 24, 110, 24, 108, 28, TFT_WHITE); //三角

  display.setFont(&fonts::Font7);   //フォント設定（7セグ）
  display.setTextSize(0.8);         //文字サイズ
  display.setCursor(0, 26);         //座標を指定（2行目、時間）
  display.printf("%02d", minute);   //時間カウント値
  display.setCursor(52, 26);        //座標を指定（2行目、分）
  display.printf("%02d", sec);      //分カウント値

  M5.dis.drawpix(0, dispColor(20, 20, 20)); //本体LED（白）
}
//-------------------------------------------------
// メイン
//-------------------------------------------------
void loop() {
  M5.update();                      //ボタン状態更新
  // 本体スイッチ処理
  if (M5.Btn.wasPressed()) {        //本体ボタンが押されていれば
    start = !start;                 //カウント開始フラグ反転
    if(start == 1) {                //カウント開始フラグが1なら
      M5.dis.drawpix(0, dispColor(0, 0, 200));  //本体LED（青）
    } else {                        //カウント開始フラグが0なら
      M5.dis.drawpix(0, dispColor(20, 20, 20)); //本体LED（白）
    }
  }
  // 分：秒カウント処理（割込み処理が完了したら実行）
  if (xSemaphoreTake(timerSemaphore, 0) == pdTRUE) { //セマフォが解放されたら
    if(sec_up == 1) {       //1秒カウントフラグが1なら
      sec++;                //秒カウント+1
      portENTER_CRITICAL(&timerMux);  //排他制御で以下を実行（割込み禁止）
      sec_up = 0;           //1秒カウントフラグクリア
      portEXIT_CRITICAL(&timerMux);   //排他制御終了（割り込み許可）
      if(sec == 60) {       //秒カウントが60なら
        minute++;           //分カウント+1
        sec = 0;            //秒カウントリセット
        if(minute == 99)    //分カウントが100なら
        start = !start;     //カウント終了
      }
      display.setTextSize(0.8);       //文字サイズ
      display.setCursor(0, 26);       //座標を指定（2行目、時間）
      display.printf("%02d", minute); //時間カウント値
      display.setCursor(52, 26);      //座標を指定（2行目、分）
      display.printf("%02d", sec);    //分カウント値
    }
  }
  // OLED表示
  display.setCursor(105, 45);     //座標を指定（10ms表示位置）
  display.setTextSize(0.4);       //文字サイズ
  display.printf("%02d", count);  //10msカウント

  //遅延時間（メイン処理時間が10msより少し早くなるように設定）
  delay(7);
}

// 割込み内で使用する変数宣言(volatileで保持領域を固定して宣言)
volatile int count = 0;   //10msタイマカウンタ用
volatile int sec_up = 0;  //1秒経過フラグ用

// タイマ割込み設定
hw_timer_t * tim0 = NULL;                   //タイマー0の割り込みtim0で定義
volatile SemaphoreHandle_t timerSemaphore;  //セマフォの宣言（割込み発生の確認用）
portMUX_TYPE timerMux = portMUX_INITIALIZER_UNLOCKED; //排他制御の利用を宣言

// tim0のタイマー割り込みハンドラ。この処理はsetupより先に書く
// タイマ割込み発生時に実行される処理 (IRAM_ATTRで宣言してRAM上に配置）
void IRAM_ATTR onTimer() {
  portENTER_CRITICAL_ISR(&timerMux);  //排他制御で以下を実行（割込み禁止）
  if(start == 1) {                    //カウント開始フラグが1なら
    count++;                          //10msタイマカウンタ +1
    if (count >= 100) {               //100回＝1秒経過していたら
      sec_up = 1;                     //1秒経過フラグをON (メイン処理でリセットする）
      count = 0;                      //10msタイマカウンタをリセット
    }
  }
  portEXIT_CRITICAL_ISR(&timerMux);   //排他制御終了（割り込み許可）

xSemaphoreGiveFromISR(timerSemaphore, NULL);  //セマフォを開放

// タイマ割込み設定
  timerSemaphore = xSemaphoreCreateBinary();  //バイナリセマフォを作成(0か1のバイナリ)
  tim0 = timerBegin(0, 80, true);             //タイマー0を80MHz/80（1us）動作ｶｳﾝﾄｱｯﾌﾟでtim0に設定
  timerAttachInterrupt(tim0, &onTimer, true); //tim0割込みが発生した時に実行する処理を指定「onTime」
  timerAlarmWrite(tim0, 10000, true);         //tim0割込み発生周期を10ms（1us × 10000）に設定
  timerAlarmEnable(tim0);                     //タイマー0割込みを有効化

// 分：秒カウント処理（割込み処理が完了したら実行）
  if (xSemaphoreTake(timerSemaphore, 0) == pdTRUE) { //セマフォが解放されたら
    if(sec_up == 1) {       //1秒カウントフラグが1なら
      sec++;                //秒カウント+1
      portENTER_CRITICAL(&timerMux);  //排他制御で以下を実行（割込み禁止）
      sec_up = 0;           //1秒カウントフラグクリア
      portEXIT_CRITICAL(&timerMux);   //排他制御終了（割り込み許可）
      if(sec == 60) {       //秒カウントが60なら
        minute++;           //分カウント+1
        sec = 0;            //秒カウントリセット
        if(minute == 99)    //分カウントが100なら
        start = !start;     //カウント終了
      }

// OLED液晶表示設定（M5GFXライブラリ使用）
  display.init();               //表示器の初期化
  display.setRotation(1);       //表示方向(コネクタ位置基準)：0下、1右、2上、3左
  display.setColorDepth(1);     //モノクロ
  display.setTextWrap(false);   //自動改行をしない