NTPサーバーから時間取得、WiFiMultiで接続先 複数登録

#include <M5StickCPlus.h>
#include <WiFi.h>
#include <WiFiMulti.h>
WiFiMulti wifiMulti;  // WiFiMultiのインスタンスを準備
/****************** WiFiMultiを使用して複数のSSIDに接続 ******************/
void wifiConnect() {
  // wifiMultiの接続先を複数登録(SSID, PASSWORD)
  wifiMulti.addAP("SSID1", "パスワード1");  // 接続先1
  wifiMulti.addAP("SSID2", "パスワード2");  // 接続先2
  wifiMulti.addAP("SSID3", "パスワード3");  // 接続先3
  // WiFiMulti実行
  while (WiFi.status() != WL_CONNECTED) { // 接続完了するまで繰り返す
    M5.Lcd.fillScreen(BLACK); // 背景黒リセット
    M5.Lcd.setTextFont(4);    // フォント
    M5.Lcd.setCursor(5, 2);   M5.Lcd.setTextColor(WHITE, BLACK);  // 座標、文字色
    M5.Lcd.println("Wi-Fi Search ...   "); // 初期表示
    wifiMulti.run();  // WiFiMultiを実行
    delay(1000);      // 接続実行後は少し待つ
    // Wi-Fi接続結果表示
    if (WiFi.status() == WL_CONNECTED) {  // 接続成功ならIPアドレス、SSID表示
      M5.Lcd.fillScreen(BLACK);                                     // 背景黒リセット
      M5.Lcd.setTextFont(2);                                        // フォント
      M5.Lcd.setCursor(5, 2);   M5.Lcd.setTextColor(ORANGE, BLACK); // 座標、文字色
      M5.Lcd.print("IP : ");    M5.Lcd.print(WiFi.localIP());       // IPアドレス
      M5.Lcd.setCursor(5, 18);  M5.Lcd.setTextColor(CYAN, BLACK);   // 座標、文字色
      M5.Lcd.print("SSID : ");  M5.Lcd.print(WiFi.SSID());          // SSID表示
      M5.Lcd.drawFastHLine(0, 37, 240, WHITE);                      // 指定座標から水平線
    } else {                              // 接続失敗ならエラーメッセージ表示
      M5.Lcd.setTextColor(RED, BLACK);            // 座標、文字色
      M5.Lcd.println("Wi-Fi Nothing!\nRetry!!");  // エラー表示
      delay(1000);
    }
  }
}
/************************ NTPサーバと時間を同期 ************************/
char ntpServer[] = "pool.ntp.org";    // 最適なNTPサーバーへ誘導してくれる
const long gmtOffset_sec = 9 * 3600;  // UTC（協定世界時）をJST（日本標準時）にするため9時間加算
const int daylightOffset_sec = 0;     // サマータイムのオフセットは無しに設定
struct tm timeinfo;                   // tmのインスタンスを準備
char date[11];                        // 年月日データ格納バッファ
char now_time[9];                     // 時間データ格納バッファ

void getTimeFromNTP() {
  configTime(gmtOffset_sec, daylightOffset_sec, ntpServer); // 時間取得条件を指定
  while (!getLocalTime(&timeinfo)) { delay(1000); }         // 時間の同期が完了するまで待つ
}
/**************** NTPサーバから取得した情報で日付時刻を更新 ****************/
void getTime() {
  getLocalTime(&timeinfo);          // 時間情報を構造体で取得
  sprintf(date, "%02d/%02d/%02d",   // 年月日をdateに結合
          timeinfo.tm_year + 1900,  // 年（1900年からの経過年）
          timeinfo.tm_mon + 1,      // 月（0〜11で取得するため+1）
          timeinfo.tm_mday          // 日
  );
  sprintf(now_time, "%02d:%02d:%02d", // 時分秒をnow_timeに結合
          timeinfo.tm_hour,           // 時
          timeinfo.tm_min,            // 分
          timeinfo.tm_sec             // 秒
  );
  // 時刻表示
  if (WiFi.status() == WL_CONNECTED) {  // Wi-Fi接続有りなら
    M5.Lcd.setTextColor(WHITE, BLACK);  // 文字色白
  } else {                              // Wi-Fi接続無しなら
    M5.Lcd.setTextColor(RED, BLACK);    // 文字色赤
  }
  M5.Lcd.setCursor(5, 44);  M5.Lcd.setTextFont(4);  // 座標指定、フォント 4(26px)
  M5.Lcd.print(date);                               // 年月日dateを表示
  M5.Lcd.setCursor(13, 78); M5.Lcd.setTextFont(7);  // 座標指定、フォント（7セグ）
  M5.Lcd.print(now_time);                           // 現在時刻now_timeを表示
}
// 初期設定 -------------------------------------------------
void setup() {
  M5.begin();             // 本体初期化
  M5.Lcd.setRotation(1);  // 画面向き設定（USB位置基準 0：下/ 1：右/ 2：上/ 3：左）
  M5.Lcd.setTextSize(1);  // 文字サイズ（整数倍率）
  wifiConnect();          // Wi-Fi接続実行
  if (WiFi.status() == WL_CONNECTED) {  // Wi-Fi接続有りなら
    getTimeFromNTP();     // NTPサーバーと時間を同期
  }
}
// メイン ---------------------------------------------------
void loop() {
  M5.update();  // ボタン状態更新
  getTime();    // NTPサーバーより時間取得表示（一度同期すればWi-Fi接続が遮断されてもカウント継続）
  // 電源ボタン（Wi-Fi再接続のため再起動）
  if (M5.Axp.GetBtnPress()) { // 電源ボタンが押されたら
    ESP.restart();  // 再起動実行
  }
  // バッテリー残量（MAX約4.2V、限界電圧3V）パーセント換算表示
  float battery;    // バッテリー残量表示用
  battery = (M5.Axp.GetBatVoltage() - 3.1) * 100;   // バッテリー残量取得、3.1Vで0%として換算
  if (battery > 100) {                              // 換算値が100以上なら
    battery = 100;                                  // 100にする
  }
  M5.Lcd.setCursor(205, 2); M5.Lcd.setTextFont(2);  // 座標、フォント 2(16px)
  M5.Lcd.setTextColor(DARKGREY, BLACK);             // 文字色
  M5.Lcd.printf("%3.0f%%", battery);                // バッテリー残量表示

  // RSSI（受信信号強度）を強度によって色分けして表示
  M5.Lcd.setCursor(193, 18);  // 座標
  if (WiFi.RSSI() >= -67) {                             //RSSI -67dBm以上なら良好
    M5.Lcd.setTextColor(CYAN, BLACK);                   //水色表示
  } else if (WiFi.RSSI() < -67 && WiFi.RSSI() >= -70) { //RSSI -67dBmより低くて-70dBm以上なら不安定
    M5.Lcd.setTextColor(GREENYELLOW, BLACK);            //黄色表示
  } else if (WiFi.RSSI() < -70 && WiFi.RSSI() >= -80) { //RSSI -70dBmより低くて-80dBm以上なら悪い
    M5.Lcd.setTextColor(ORANGE, BLACK);                 //橙色表示
  } else {                                              //RSSI -80dBmより低いなら使用不可
    M5.Lcd.setTextColor(RED, BLACK);                    //赤色表示
  }
  M5.Lcd.printf("%3ddBm", WiFi.RSSI());      // SSID表示
  delay(500); // 遅延時間
}

#include <WiFi.h>
#include <WiFiMulti.h>
WiFiMulti wifiMulti;  // WiFiMultiのインスタンスを準備

// wifiMultiの接続先を複数登録(SSID, パスワード)
wifiMulti.addAP("SSID1", "パスワード1");  // 接続先1
wifiMulti.addAP("SSID2", "パスワード2");  // 接続先2
wifiMulti.addAP("SSID3", "パスワード3");  // 接続先3

while (WiFi.status() != WL_CONNECTED) { // 接続完了するまで繰り返す
  wifiMulti.run();                      // WiFiMultiを実行
  delay(1000);                          // 接続実行後は少し待つ
}

if (M5.Axp.GetBtnPress()) { // 電源ボタンが押されたら
  ESP.restart();  // 再起動実行
}

char ntpServer[] = "ntp.nict.jp";     // 日本標準時刻と直結したNTPサーバ
const long gmtOffset_sec = 9 * 3600;  // UTC（協定世界時）をJST（日本標準時）するため9時間加算
const int daylightOffset_sec = 0;     // サマータイムのオフセットは無しに設定
struct tm timeinfo;                   // tmのインスタンスを準備
char date[11];                        // 年月日データ格納バッファ
char now_time[9];                     // 時間データ格納バッファ

void getTimeFromNTP() {
  configTime(gmtOffset_sec, daylightOffset_sec, ntpServer); // 時間取得条件を指定
  while (!getLocalTime(&timeinfo)) { delay(1000); }         // 時間の同期が完了するまで待つ
}

void getTime() {
  getLocalTime(&timeinfo);          // 時間情報を構造体で取得
  sprintf(date, "%02d/%02d/%02d",   // 年月日をdateに結合
          timeinfo.tm_year + 1900,  // 年（1900年からの経過年）
          timeinfo.tm_mon + 1,      // 月（0〜11で取得するため+1）
          timeinfo.tm_mday          // 日
  );
  sprintf(now_time, "%02d:%02d:%02d", // 時分秒をnow_timeに結合
          timeinfo.tm_hour,           // 時
          timeinfo.tm_min,            // 分
          timeinfo.tm_sec             // 秒
  );
  // 時刻表示
  if (WiFi.status() == WL_CONNECTED) {  // Wi-Fi接続有りなら
    M5.Lcd.setTextColor(WHITE, BLACK);  // 文字色白
  } else {                              // Wi-Fi接続無しなら
    M5.Lcd.setTextColor(RED, BLACK);    // 文字色赤
  }
  M5.Lcd.setCursor(5, 44);  M5.Lcd.setTextFont(4);  // 座標指定、フォント 4(26px)
  M5.Lcd.print(date);                               // 年月日dateを表示
  M5.Lcd.setCursor(13, 78); M5.Lcd.setTextFont(7);  // 座標指定、フォント（7セグ）
  M5.Lcd.print(now_time);                           // 現在時刻now_timeを表示
}