DCモータの速度制御方法(Arduinoコマンド)3V以下モータ対応

#include <M5AtomS3.h> // ATOMS3用ライブラリ

#define BTN_GPIO 41 // 本体ボタン端子指定
#define INT1 8      // モーター1正転信号端子（INT1）
#define INT2 7      // モーター1逆転信号端子（INT2）

// 変数設定
bool state = false; // 本体ボタン状態格納用
int mode = 0;       // 動作モード切り替え用（0:停止、1:正転、2:ブレーキ、3:逆転）

// 表示更新関数 *******************************************************
void displayUpdate() {
  M5.Lcd.setCursor(13, 0);          // カーソル座標
  M5.Lcd.printf("MODE : %d", mode); // 文字表示
  M5.Lcd.drawCentreString("PUSH!", M5.lcd.width()/2, 55, 4); // 文字表示（中央表示）
}
// 初期設定 ----------------------------------------------------------
void setup() {
  M5.begin(true, true, false, false); // AtomS3初期設定（LCD,UART,I2C,LED）

  // PWM初期設定（必要に応じてコメントアウトして指定。書かなければ初期値で動作可）
  // analogWriteFrequency(500);  // PWM周波数設定（書かなければ初期値の1000Hz）
  // analogWriteResolution(12);  // PWM分解能設定（書かなければ初期値の8で分解能は256）

  // 液晶表示
  M5.Lcd.begin();         // 画面初期化
  M5.Lcd.setRotation(2);  // 画面向き設定（0～3で設定、4～7は反転)※初期値は1
  M5.Lcd.setTextColor(WHITE, BLACK); // 文字色, 文字背景
  M5.Lcd.setTextFont(4);  // フォント
  displayUpdate();        // 表示更新関数呼び出し
}
// メイン -------------------------------------------------------------
void loop() {
  // 本体ボタン モード切り替え処理
  if (digitalRead(BTN_GPIO) == LOW && state == false) { // 本体ボタンONでstateがfalseなら
    state = true;                 // 本体ボタン状態をtrueへ
    mode++;                       // モード切り替え（+1）
    if (mode == 4) { mode = 0; }  // モードリセット
    displayUpdate();              // 表示更新関数呼び出し
  }
  if (digitalRead(BTN_GPIO) == HIGH) { state = false; } // 本体ボタンOFFなら、stateをfalseへ

  // モーター動作処理
  switch (mode) { // モードによって動作を分岐
  case 0: // 停止
    analogWrite(INT1, 0);     // 正転PWM出力（INT1）OFF（DUTY比0）
    analogWrite(INT2, 0);     // 逆転PWM出力（INT2）OFF（DUTY比0）
    break;
  case 1: // 正転：
    analogWrite(INT1, 127);   // 正転PWM出力（INT1）にDUTY比を指定（0〜256）
    analogWrite(INT2, 0);     // 逆転PWM出力（INT2）OFF（DUTY比0）
    break;
  case 2: // ブレーキ：
    analogWrite(INT1, 256);   // 正転と逆転PWM出力（INT1）にDUTY比100%（256）に指定
    analogWrite(INT2, 256);   //   ※DUTY比を小さくするとブレーキ力低下
    break;
  case 3: // 逆転：
    analogWrite(INT1, 0);     // 正転PWM出力（INT1）OFF（DUTY比0）
    analogWrite(INT2, 256);   // 逆転PWM出力（INT2）にDUTY比を指定（0〜256）
    break;
  }
  delay(100); // 遅延時間
}

#include <M5AtomS3.h> // ATOMS3用ライブラリ

#define BTN_GPIO 41 // 本体ボタン端子指定
#define INT1 8      // モーター1正転信号端子（INT1）
#define INT2 7      // モーター1逆転信号端子（INT2）

#define CH_INT1 0   // PWM出力チャンネル設定（0,1/ 2,3/ 4,5/ 6,7/ 8,9/ 10,11 /12,13 /14,15で周波数、分解能設定が共通）
#define CH_INT2 1   //  ※チャンネル7は液晶バックライトと共用になるため指定禁止
#define FREQ 500    // PWM出力周波数
#define BIT_NUM 12  // PWM出力bit数（今回は12bit指定。分解能は2の12乗で4096）

// 変数設定
bool state = false; // 本体ボタン状態格納用   
int mode = 0;       // 動作モード切り替え用（0:停止、1:正転、2:ブレーキ、3:逆転）

// 表示更新関数 *******************************************************
void displayUpdate() {
  M5.Lcd.setCursor(13, 0);          // カーソル座標
  M5.Lcd.printf("MODE : %d", mode); // 文字表示
  M5.Lcd.drawCentreString("PUSH!", M5.lcd.width()/2, 55, 4); // 文字表示（中央表示）
}

// 初期設定 ----------------------------------------------------------
void setup() {
  M5.begin(true, true, false, false); // AtomS3初期設定（LCD,UART,I2C,LED）

  // PWM初期設定
  pinMode(INT1, OUTPUT);              // PWM出力端子（INT1：正転用）を出力設定
  pinMode(INT2, OUTPUT);              // PWM出力端子（INT2：逆転用）を出力設定
  ledcSetup(CH_INT1, FREQ, BIT_NUM);  // PWM出力設定（チャンネル, 周波数, bit数）
  ledcSetup(CH_INT2, FREQ, BIT_NUM);
  ledcAttachPin(INT1, CH_INT1);       // PWMチャンネルを端子に割り当て（端子番号, チャンネル）
  ledcAttachPin(INT2, CH_INT2);

  // 液晶表示
  M5.Lcd.begin();         // 画面初期化
  M5.Lcd.setRotation(2);  // 画面向き設定（0～3で設定、4～7は反転)※初期値は1
  M5.Lcd.setTextColor(WHITE, BLACK); // 文字色, 文字背景
  M5.Lcd.setTextFont(4);  // フォント
  displayUpdate();        // 表示更新関数呼び出し
}

// メイン -------------------------------------------------------------------
void loop() {
  // 本体ボタン モード切り替え処理
  if (digitalRead(BTN_GPIO) == LOW && state == false) { // 本体ボタンONでstateがfalseなら
    state = true;                 // 本体ボタン状態をtrueへ
    mode++;                       // モード切り替え（+1）
    if (mode == 4) { mode = 0; }  // モードリセット
    displayUpdate();              // 表示更新関数呼び出し
  }
  if (digitalRead(BTN_GPIO) == HIGH) { state = false; } // 本体ボタンOFFなら、stateをfalseへ

  // モーター動作処理
  switch (mode) { // モードによって動作を分岐
  case 0: // 停止
    ledcWrite(CH_INT1, 0);      // 正転PWM出力（INT1）OFF（DUTY比0）
    ledcWrite(CH_INT2, 0);      // 逆転PWM出力（INT2）OFF（DUTY比0）
    break;
  case 1: // 正転：
    ledcWrite(CH_INT1, 2048);   // 正転PWM出力（INT1）にDUTY比を指定（0〜4096）
    ledcWrite(CH_INT2, 0);      // 逆転PWM出力（INT2）OFF（DUTY比0）
    break;
  case 2: // ブレーキ：
    ledcWrite(CH_INT1, 4096);   // 正転と逆転PWM出力（INT1）にDUTY比100%（4096）に指定
    ledcWrite(CH_INT2, 4096);   //   ※DUTY比を小さくするとブレーキ力低下
    break;
  case 3: // 逆転：
    ledcWrite(CH_INT1, 0);      // 正転PWM出力（INT1）OFF（DUTY比0）
    ledcWrite(CH_INT2, 4096);   // 逆転PWM出力（INT2）にDUTY比を指定（0〜4096）
    break;
  }
  delay(100); // 遅延時間
}

// #include <M5AtomS3.h> // ATOMS3用ライブラリ※ArduinoIDEで書き込む場合はエラーになったため無効にしています。
#include "M5GFX.h"    // グラフィック処理ライブラリ

#define BTN_GPIO 41   // 本体ボタン端子指定
#define INPUT_PIN0 39 // ボタンスイッチ（青）端子
#define INPUT_PIN1 38 // ボタンスイッチ（赤）端子
#define ADC_PIN1 1    // モーター速度指定ボリュームアナログ入力端子
#define INT1 8        // モーター1正転信号端子（INT1）
#define INT2 7        // モーター1逆転信号端子（INT2）
#define INT3 6        // モーター2正転信号端子（INT3）
#define INT4 5        // モーター2逆転信号端子（INT4）

#define CH_INT1 0     // PWM出力チャンネル（0,1/ 2,3/ 4,5/ 6,7/ 8,9/ 10,11 /12,13 /14,15で周波数、分解能設定が共通）
#define CH_INT2 1     //  ※チャンネル7は液晶バックライトと共用になるため指定禁止
#define CH_INT3 2
#define CH_INT4 3
#define FREQ 500      // PWM出力周波数（200〜1000推奨　※高いとトルク低下）
#define BIT_NUM 10    // PWM出力bit数（8bit〜14bit推奨）

static M5GFX lcd;              // M5GFXのインスタンス作成
static M5Canvas canvas(&lcd);  // スプライト1（メモリ描画領域）をcanvasとして準備

// 変数設定
int adc_value;            // モーター速度指定アナログ値格納用
float adc_volt;           // モーター電圧換算表示用
int resolution = 1;       // 分解能算出用
int duty;                 // Duty比算出用
bool btn_state = false;   // 本体ボタン状態格納用
bool on_signal = false;   // ON信号状態格納用

// PWM出力実行関数 ********************************************************************
void pwmOutput(int duty1, int duty2, int duty3, int duty4) {
  ledcWrite(CH_INT1, duty1);  // PWM出力実行（チャンネル, Duty比）
  ledcWrite(CH_INT2, duty2);
  ledcWrite(CH_INT3, duty3);
  ledcWrite(CH_INT4, duty4);
}

// 初期設定 ----------------------------------------------------------
void setup() {
  USBSerial.begin(9600);  // シリアル通信初期化
  delay(1000);            // シリアル出力開始待ち
  USBSerial.println("ATOM S3 DC MOTOR TEST!!");  // シリアル出力

  // 入出力設定
  pinMode(INPUT_PIN0, INPUT_PULLUP);  // ボタン青入力
  pinMode(INPUT_PIN1, INPUT_PULLUP);  // ボタン赤入力

  // アナログ入力設定
  pinMode(ADC_PIN1, ANALOG);  // モーター速度指定アナログ入力

  // PWM出力に使用する端子を出力設定
  pinMode(INT1, OUTPUT);   // モーター1正転
  pinMode(INT2, OUTPUT);   // モーター1逆転
  pinMode(INT3, OUTPUT);   // モーター2正転
  pinMode(INT4, OUTPUT);   // モーター2逆転

  // PWM初期設定
  ledcSetup(CH_INT1, FREQ, BIT_NUM); // PWM設定（ﾁｬﾝﾈﾙ, 周波数, bit数）
  ledcSetup(CH_INT2, FREQ, BIT_NUM); // PWM設定（ﾁｬﾝﾈﾙ, 周波数, bit数）
  ledcSetup(CH_INT3, FREQ, BIT_NUM); // PWM設定（ﾁｬﾝﾈﾙ, 周波数, bit数）
  ledcSetup(CH_INT4, FREQ, BIT_NUM); // PWM設定（ﾁｬﾝﾈﾙ, 周波数, bit数）
  ledcAttachPin(INT1, CH_INT1);  // PWMﾁｬﾝﾈﾙ割り当て（端子番号, ﾁｬﾝﾈﾙ）（モーター1正転）
  ledcAttachPin(INT2, CH_INT2);  // PWMﾁｬﾝﾈﾙ割り当て（端子番号, ﾁｬﾝﾈﾙ）（モーター1逆転）
  ledcAttachPin(INT3, CH_INT3);  // PWMﾁｬﾝﾈﾙ割り当て（端子番号, ﾁｬﾝﾈﾙ）（モーター2正転）
  ledcAttachPin(INT4, CH_INT4);  // PWMﾁｬﾝﾈﾙ割り当て（端子番号, ﾁｬﾝﾈﾙ）（モーター2逆転）

  // 液晶表示内容設定
  lcd.init();                                     // lcdインスタンス初期化
  canvas.setColorDepth(16);                       // カラーモード設定(16bit)
  canvas.createSprite(lcd.width(), lcd.height()); // canvasサイズ（メモリ描画領域）設定（画面サイズに設定）

  // 分解能算出（2のbit数乗）
  for (int i = 0; i < BIT_NUM; i++) { // bit数分繰り返し
    resolution *= 2;                  // 2乗して分解能を更新
  }
}

// メイン -------------------------------------------------------------------
void loop() {
  // ボリュームアナログ入力値処理、DUTY比換算
  adc_value = 4096 - analogRead(ADC_PIN1);          // モーター速度指定アナログ値取得（ボリュームに合わせて反転）
  adc_volt = ((float)adc_value / 4096.0) * 3.3;     // アナログ値電圧換算
  duty = (int)(((float)adc_value / 4096.0) * (float)resolution);  // 設定した分解能に合わせてDuty比設定値を算出

  // 本体ボタン処理（押すごとに正転／停止切り替え）
  if (digitalRead(BTN_GPIO) == LOW && !btn_state) {         // 本体ボタンONでstateがfalseなら
    on_signal = !on_signal;                                 // ON信号状態を反転
    btn_state = true;                                       // 本体ボタン状態をtrueに設定
  } else if (digitalRead(BTN_GPIO) == HIGH && btn_state) {  // 本体ボタンOFFでstateがtrueなら
    btn_state = false;                                      // 本体ボタン状態をfalseに設定
  }
  if (on_signal) {                                // ON信号がtrueなら
    canvas.fillScreen(lcd.color565(20, 120, 0));  // 背景緑
  } else {                                        // ON信号がfalseなら
    canvas.fillScreen(BLACK);                     // 背景黒
  }

  // モーター動作処理
  bool sw_blue = digitalRead(INPUT_PIN0); // 外部スイッチ青の状態確認
  bool sw_red = digitalRead(INPUT_PIN1);  // 外部スイッチ赤の状態確認
  if ((sw_blue == false || on_signal == true) && sw_red == true) {  // 外部スイッチ青がONまたはON信号がtrueで、かつスイッチ赤がOFFなら
    pwmOutput(duty, 0, duty, 0);                               // 正転：正転端子のみPWM出力
    canvas.drawCentreString("FORWARD", lcd.width()/2, 105, &fonts::Font4);
  } else if (sw_red == false && sw_blue == true) {             // 外部スイッチ赤がONかつ青がOFFなら
    pwmOutput(0, duty, 0, duty);                               // 逆転：逆転端子のみPWM出力
    canvas.drawCentreString("REVERSE", lcd.width()/2, 105, &fonts::Font4);
  } else if (sw_blue == false && sw_red == false) {            // 外部スイッチが両方ONなら
    pwmOutput(resolution, resolution, resolution, resolution); // ブレーキ：PWM出力最大（分解能の最大値）で指定
    canvas.drawCentreString("BREAK", lcd.width()/2, 105, &fonts::Font4);
  } else {                                                     // その他なら
    pwmOutput(0, 0, 0, 0);                                     // 停止：PWM出力停止（Duty比を0へ）
    canvas.drawCentreString("STOP", lcd.width()/2, 105, &fonts::Font4);
  }

  // 液晶表示
  canvas.fillRect(0, 0, 128, 38, WHITE);         // 塗り潰し四角
  canvas.setTextColor(lcd.color565(200, 0, 0));  // 文字色
  canvas.drawCentreString("DC Motor", lcd.width()/2, 2, &fonts::Font4);  // 上中央座標を基準に文字表示（表示内容, x, y, フォント）
  canvas.drawCentreString("- DRIVER MX1508 -", lcd.width()/2, 22, &fonts::Font2);
  canvas.drawFastHLine(0, 37, 128, WHITE);       // 指定座標から横線
  canvas.setCursor(0, 40);                       // カーソル座標指定
  canvas.setTextColor(WHITE);                    // 文字色
  canvas.setFont(&fonts::lgfxJapanGothicP_16);   // フォント
  canvas.printf(" Duty値 : %d\n", duty);                                    // DUTY値表示
  canvas.printf(" Duty率 : %.1f%%\n", ((float)duty/(float)resolution)*100); // DUTY比率表示
  canvas.printf(" Vol電圧 : %.1fv\n", adc_volt);                            // ボリューム電圧換算値表示
  canvas.drawFastHLine(0, 100, 128, WHITE);      // 指定座標から横線

  canvas.pushSprite(0, 0); // canvasを座標を指定して表示（スプライト）
  delay(100);               // 遅延時間
}