M5Stack Modbus 485リレー4CHの使い方

#include <M5Stack.h>      // CORE2の場合は <M5Core2.h>
#include "ModbusMaster.h" // modbusライブラリのインクルード

#define RX_PIN 16     // シリアル通信端子番号(RX)※CORE2は13
#define TX_PIN 17     // シリアル通信端子番号(TX)※CORE2は14
#define SLAVE_NO 1    // スレーブアドレス指定

ModbusMaster node0;   // スレーブアドレス読み書き専用の通信用インスタンスを作成
ModbusMaster node1;   // 指定したスレーブアドレスとの通信用インスタンスを作成

// 変数宣言
uint8_t result = 0;         // 通信結果取得用
uint8_t read_slave_address; // スレーブアドレス 確認用
uint8_t read_relay_state;   // リレー状態 確認用
uint8_t read_input_state;   // 入力状態 確認用
bool relay[4];              // リレー1〜4 ON/OFFビット格納用
bool input[4];              // 入力端子1〜4 ON/OFFビット格納用
bool in_state[4];           // 入力状態保持用

// 関数 ********************************************************************
// スレーブアドレス設定関数（node0で実行）---------------------------------------
void setSlaveAddress(uint8_t address) {
  // 0x10：保持レジスタ連続書込み
  node0.setTransmitBuffer(0, address);              // 書込む値を準備（バッファ番号, スレーブアドレスNo）
  result = node0.writeMultipleRegisters(0x0000, 1); // 連続書込み実行(アドレス, 書込みレジスタ数)
  delay(10);  // 通信完了待ち
}
// スレーブアドレス読込み、接続設定関数 -----------------------------------------
void slaveConnectionSetting() {
  // 0x03：保持レジスタ連続読込み
  result = node0.readHoldingRegisters(0x0000, 1);   // 保持レジスタ読込み（開始アドレス, 読込みレジスタ数）
  read_slave_address = node0.getResponseBuffer(0);  // 受信データバッファ取得
  delay(10);  // 通信完了待ち

  // Modbus通信初期化
  node1.begin(read_slave_address, Serial2);  // 読み取ったスレーブアドレスでシリアル通信2を介して通信開始
}
// リレーON／OFF状態確認関数 --------------------------------------------------
void readRelayState() {
  // 0x01：コイルON／OFF状態読込み（リレー1〜4状態読込み、下位4bitで取得）
  result = node1.readCoils(0x0000, 8);            // (開始アドレス, 読込みコイル数)
  read_relay_state = node1.getResponseBuffer(0);  // 受信データバッファ取得
  delay(10);  // 通信完了待ち
  // リレーON／OFF確認ビットセット
  relay[0] = read_relay_state & 0b0001; // リレー1ビットがONだったなら1セット
  relay[1] = read_relay_state & 0b0010; // リレー2ビットがONだったなら1セット
  relay[2] = read_relay_state & 0b0100; // リレー3ビットがONだったなら1セット
  relay[3] = read_relay_state & 0b1000; // リレー4ビットがONだったなら1セット
}
// 入力端子ON／OFF状態確認関数 ------------------------------------------------
void readInputStatus() {
  // 0x02：入力ON／OFF状態読込み（入力端子状態読込み）
  result = node1.readDiscreteInputs(0x0000, 8);   // (開始アドレス, 読込み入力数)
  read_input_state = node1.getResponseBuffer(0);  // 受信データバッファ取得
  delay(10);  // 通信完了待ち
  // 入力端子ON／OFFビットセット
  input[0] = read_input_state & 0b0001; // IN1が1なら1セット
  input[1] = read_input_state & 0b0010; // IN1が2なら1セット
  input[2] = read_input_state & 0b0100; // IN1が3なら1セット
  input[3] = read_input_state & 0b1000; // IN1が4なら1セット
}
// リレーON/OFF出力関数 -----------------------------------------------------
void outputSingleRelay(uint8_t relay_num, uint16_t address, bool signal) {
  // 0x05：コイルのON／OFF単独書込み
  if (signal == false) {                  // リレー信号がfalseなら
    node1.writeSingleCoil(address, 0x00); // リレー OFF実行
  } else {
    node1.writeSingleCoil(address, 0xFF); // リレー ON実行
  }
  delay(10);        // 通信完了待ち
  readRelayState(); // リレーON/OFF状態確認関数呼び出し
}
// 全リレーON/OFF出力関数 ----------------------------------------------------
void outputAllRelay(uint16_t value) {
  // 0x0F：コイル状態連続書込み
  node1.setTransmitBuffer(0, value);                  // 書込む値を準備（0x01FF/0x0100 = 全ON/全OFF）
  result = node1.writeMultipleCoils(0x0000, 0x0008);  // コイル状態連続書込み(アドレス, 書込みコイル数)
  delay(10);                                          // 通信完了待ち
  readRelayState();                                   // リレーON/OFF状態確認関数呼び出し 
}
// 初期設定 *******************************************************************
void setup() {
  M5.begin();   // 本体初期化
  // Modbus通信初期設定（SERIAL_8N1：データビット幅[8]、パリティチェック[No]、ストップビット[1]）
  Serial2.begin(9600, SERIAL_8N1, RX_PIN, TX_PIN);  // シリアル通信2 初期化(RX, TX)
  node0.begin(0, Serial2);                          // スレーブアドレス読み書き専用の通信をシリアル通信2で設定
  delay(10);                                        // 通信安定待ち
  // スレーブアドレス設定
  setSlaveAddress(SLAVE_NO);          // スレーブアドレス設定関数呼び出し
  slaveConnectionSetting();           // スレーブアドレス読込み、接続設定関数呼び出し
  // 液晶画面初期設定
  M5.Lcd.setTextColor(WHITE, BLACK);  // 文字色
  M5.Lcd.setTextFont(4);              // フォント
}
// メイン処理 *******************************************************************
void loop() {
  M5.update();        // ボタン状態初期化
  // 入力端子の状態確認
  readInputStatus();  // 入力端子ON／OFF状態確認関数呼び出し

  // 入力端子によるリレーON/OFF単独出力、ON/OFF状態確認(入力状態保持により入力変化時のみ実行)
  for(int i=0; i<4; i++) {                // 入力端子の数だけ繰り返す
    if(input[i] != in_state[i]) {         // 入力状態が変化した場合のみ実行
      outputSingleRelay(i, 0x0000+i, input[i]); // リレー出力実行(リレー番号, Coilアドレス, ON/OFF=True/false)
      in_state[i] = input[i];             // 入力状態を更新する
    }
  }
  // ボタン操作(設定値書込み)
  if (M5.BtnA.wasPressed()) {   // AボタンONならスレーブアドレス2に変更
    setSlaveAddress(2);         // スレーブアドレス設定関数呼び出し
    slaveConnectionSetting();   // スレーブアドレス読込み、接続設定関数呼び出し
  }
  if (M5.BtnB.wasPressed()) {   // BボタンONならスレーブアドレス3に変更
    setSlaveAddress(3);         // スレーブアドレス設定関数呼び出し
    slaveConnectionSetting();   // スレーブアドレス読込み、接続設定関数呼び出し
  }
  if (M5.BtnC.wasPressed()) {   // CボタンONで全リレー ON
    outputAllRelay(0x01FF);     // 全リレーON/OFF出力関数呼び出し（書込む値を指定：0x01FF/0x0100 = 全ON/全OFF）
  }
  if (M5.BtnC.wasReleased()) {  // CボタンOFFで全リレー OFF
    outputAllRelay(0x0100);     // 全リレーON/OFF出力関数呼び出し（書込む値を指定：0x01FF/0x0100 = 全ON/全OFF）
  }
  // 液晶表示
  M5.Lcd.setCursor(0, 0); // 表示座標
  M5.Lcd.printf("Slave No.%02d\n", read_slave_address); // スレーブアドレス表示
  // 入力端子1〜4 状態確認表示
  M5.Lcd.printf("Input  : %d, %d, %d, %d\n", input[0], input[1], input[2], input[3]);
  // リレー1〜4 状態確認表示
  M5.Lcd.printf("Relay : %d, %d, %d, %d\n", relay[0], relay[1], relay[2], relay[3]);

  // エラー表示
  if (result != 0) {                  // 通信成功以外ならエラー表示
    M5.Lcd.fillScreen(BLACK);         // 背景色
    M5.Lcd.setCursor(0, 0);           // 表示座標
    M5.Lcd.println("ERROR");          // 「ERROR」表示
    M5.Lcd.printf("0x%02X", result);  // 16進数の「エラーコード」表示
  }
  delay(100); // 遅延時間
}

#include <M5Stack.h>      // CORE2の場合は <M5Core2.h>
#include "ModbusMaster.h" // modbusライブラリのインクルード

#define RX_PIN 16     // シリアル通信端子番号(RX)※CORE2は13
#define TX_PIN 17     // シリアル通信端子番号(TX)※CORE2は14
#define SLAVE_NO 1    // スレーブアドレス指定

ModbusMaster node0;   // スレーブアドレス読み書き専用の通信用インスタンスを作成
ModbusMaster node1;   // 指定したスレーブアドレスとの通信用インスタンスを作成

// 変数宣言
uint8_t result = 0;         // 通信結果取得用

void setup() {
  M5.begin();   // 本体初期化
  // Modbus通信初期設定（SERIAL_8N1：データビット幅[8]、パリティチェック[No]、ストップビット[1]）
  Serial2.begin(9600, SERIAL_8N1, RX_PIN, TX_PIN);  // シリアル通信2 初期化(RX, TX)
  node0.begin(0, Serial2);                          // スレーブアドレス読み書き専用の通信をシリアル通信2で設定
  delay(10);                                        // 通信安定待ち
  // スレーブアドレス設定
  setSlaveAddress(SLAVE_NO);          // スレーブアドレス設定関数呼び出し
  slaveConnectionSetting();           // スレーブアドレス読込み、接続設定関数呼び出し
  // 液晶画面初期設定
  M5.Lcd.setTextColor(WHITE, BLACK);  // 文字色
  M5.Lcd.setTextFont(4);              // フォント
}

// スレーブアドレス設定関数（node0で実行）---------------------------------------
void setSlaveAddress(uint8_t address) {
  // 0x10：保持レジスタ連続書込み
  node0.setTransmitBuffer(0, address);              // 書込む値を準備（バッファ番号, スレーブアドレスNo）
  result = node0.writeMultipleRegisters(0x0000, 1); // 連続書込み実行(アドレス, 書込みレジスタ数)
  delay(10);  // 通信完了待ち
}

// 0x10：保持レジスタ連続書込み
node0.setTransmitBuffer(0, 1);              // 書込む値を準備（バッファ番号, スレーブアドレスNo）
result = node0.writeMultipleRegisters(0x0000, 1); // 連続書込み実行(アドレス, 書込みレジスタ数)

// スレーブアドレス読込み、接続設定関数 -----------------------------------------
void slaveConnectionSetting() {
  // 0x03：保持レジスタ連続読込み
  result = node0.readHoldingRegisters(0x0000, 1);   // 保持レジスタ読込み（開始アドレス, 読込みレジスタ数）
  read_slave_address = node0.getResponseBuffer(0);  // 受信データバッファ取得
  delay(10);  // 通信完了待ち

  // Modbus通信初期化
  node1.begin(read_slave_address, Serial2);  // 読み取ったスレーブアドレスでシリアル通信2を介して通信開始
}

// 0x03：保持レジスタ連続読込み
result = node0.readHoldingRegisters(0x0000, 1);   // 保持レジスタ読込み（開始アドレス, 読込みレジスタ数）

// リレーON／OFF状態確認関数 --------------------------------------------------
void readRelayState() {
  // 0x01：コイルON／OFF状態読込み（リレー1〜4状態読込み、下位4bitで取得）
  result = node1.readCoils(0x0000, 8);            // (開始アドレス, 読込みコイル数)
  read_relay_state = node1.getResponseBuffer(0);  // 受信データバッファ取得
  delay(10);  // 通信完了待ち
  // リレーON／OFF確認ビットセット
  relay[0] = read_relay_state & 0b0001; // リレー1ビットがONだったなら1セット
  relay[1] = read_relay_state & 0b0010; // リレー2ビットがONだったなら1セット
  relay[2] = read_relay_state & 0b0100; // リレー3ビットがONだったなら1セット
  relay[3] = read_relay_state & 0b1000; // リレー4ビットがONだったなら1セット
}

// 0x01：コイルON／OFF状態読込み（リレー1〜4状態読込み、下位4bitで取得）
result = node1.readCoils(0x0000, 8);            // (開始アドレス, 読込みコイル数)

// 入力端子ON／OFF状態確認関数 ------------------------------------------------
void readInputStatus() {
  // 0x02：入力ON／OFF状態読込み（入力端子状態読込み）
  result = node1.readDiscreteInputs(0x0000, 8);   // (開始アドレス, 読込み入力数)
  read_input_state = node1.getResponseBuffer(0);  // 受信データバッファ取得
  delay(10);  // 通信完了待ち
  // 入力端子ON／OFFビットセット
  input[0] = read_input_state & 0b0001; // IN1が1なら1セット
  input[1] = read_input_state & 0b0010; // IN1が2なら1セット
  input[2] = read_input_state & 0b0100; // IN1が3なら1セット
  input[3] = read_input_state & 0b1000; // IN1が4なら1セット
}

// リレーON/OFF出力関数 -----------------------------------------------------
void outputSingleRelay(uint8_t relay_num, uint16_t address, bool signal) {
  // 0x05：コイルのON／OFF単独書込み
  if (signal == false) {                  // リレー信号がfalseなら
    node1.writeSingleCoil(address, 0x00); // リレー OFF実行
  } else {
    node1.writeSingleCoil(address, 0xFF); // リレー ON実行
  }
  delay(10);        // 通信完了待ち
  readRelayState(); // リレーON/OFF状態確認関数呼び出し
}

// 0x05：コイルのON／OFF単独書込み
node1.writeSingleCoil(0x0000, 0xFF); // リレー ON実行

// 全リレーON/OFF出力関数 ----------------------------------------------------
void outputAllRelay(uint16_t value) {
  // 0x0F：コイル状態連続書込み
  node1.setTransmitBuffer(0, value);                  // 書込む値を準備（0x01FF/0x0100 = 全ON/全OFF）
  result = node1.writeMultipleCoils(0x0000, 0x0008);  // コイル状態連続書込み(アドレス, 書込みコイル数)
  delay(10);                                          // 通信完了待ち
  readRelayState();                                   // リレーON/OFF状態確認関数呼び出し 
}

// 0x0F：コイル状態連続書込み
node1.setTransmitBuffer(0, 0x01FF);                 // 書込む値を準備（0x01FF/0x0100 = 全ON/全OFF）
result = node1.writeMultipleCoils(0x0000, 0x0008);  // コイル状態連続書込み(アドレス, 書込みコイル数)