AtomS3の便利な使い方、日本語表示、並列処理、PWM、ｶｳﾝﾄﾀﾞｳﾝﾀｲﾏ

#include <M5AtomS3.h>

#define BTN_GPIO 41       // 本体ボタン端子番号指定
#define BZ_GPIO 2         // Groveコネクタ接続ブザー用端子番号指定（未接続でも可）

static M5Canvas canvas(&M5.Lcd);   // メモリ描画領域をcanvasという名前で準備
static void count_task(void *); // マルチタスク（並列処理）の関数宣言

// 変数宣言
uint16_t count = 18000;   // 総カウント値（1秒＝100）
uint16_t min_cnt;         // 分カウント値格納用
uint16_t sec_cnt;         // 秒カウント値格納用
uint16_t msec_cnt;        // ミリ秒カウント値格納用
bool btn_state = false;   // ボタン単押し状態確認用
bool start_flag = false;  // カウントダウンスタートフラグ
bool limit_flag = false;  // カウントリミット（10秒以下）判定用
bool press_state = false; // ボタン長押し状態確認用
int press_time;           // ボタン長押し時間カウント用

// 初期設定 ----------------------------------------------------------
void setup() {
  auto cfg = M5.config(); // 本体初期設定
  AtomS3.begin(cfg);

  Serial.begin(9600);  // シリアル通信初期化
  delay(1000);            // シリアル出力開始待ち
  Serial.println("ATOM S3 [3min Countdown Timer]");  // シリアル出力

  // 本体端子初期化
  pinMode(BTN_GPIO, INPUT_PULLUP);  // 本体ボタン端子入力設定

  // PWM出力設定
  pinMode(BZ_GPIO, OUTPUT); // GroveコネクタG2端子出力設定（外付けブザー）
  ledcSetup(1, 1000, 10);   // PWM初期設定（ﾁｬﾝﾈﾙ, 周波数Hz, bit数）
  ledcWrite(1, 512);        // PWM出力開始（ﾁｬﾝﾈﾙ、Duty比：MAXはbit数の分解能）

  // 液晶初期化
  M5.Lcd.init();                         // 初期化
  M5.Lcd.setTextWrap(false);             // テキストが画面からはみ出した時の折り返し無し
  M5.Lcd.clear(M5.Lcd.color565(20, 0, 0));  // 背景色
  M5.Lcd.setTextColor(TFT_WHITE);        // 文字色

  // 初期画面
  M5.Lcd.fillRect(0, 0, 128, 25, TFT_WHITE);       // タイトルエリア背景
  M5.Lcd.setTextColor(M5.Lcd.color565(20, 20, 20));   // 文字色
  M5.Lcd.drawString("ATOM", 12, 2, &fonts::Font4); // 上中央座標を基準に文字表示（表示内容, x, y）
  M5.Lcd.setTextColor(TFT_RED);                    // 文字色
  M5.Lcd.drawString("S3", 88, 2, &fonts::Font4);   // 上中央座標を基準に文字表示（表示内容, x, y）
  M5.Lcd.fillRect(16, 14, 7, 2, TFT_RED);          // ATOMの「A」の横線用

  M5.Lcd.setTextColor(TFT_CYAN);                   // 文字色
  M5.Lcd.drawCentreString("3分ｶｳﾝﾄﾀﾞｳﾝﾀｲﾏ", 64, 28, &fonts::lgfxJapanGothicP_16); // 上中央座標を基準に文字表示（表示内容, x, y, フォント）
  M5.Lcd.drawFastHLine(0, 46, 128, TFT_WHITE);     // 指定座標から横線(x, y, 長さ, 色)
  M5.Lcd.drawFastHLine(0, 112, 128, TFT_WHITE);    // 指定座標から横線(x, y, 長さ, 色)
  M5.Lcd.setTextColor(TFT_WHITE);                  // 文字色
  M5.Lcd.drawCentreString("Long Press Reset", 64, 113, &fonts::Font2); // 上中央座標を基準に文字表示（表示内容, x, y, フォント）

  // メモリ描画(カウント値表示)領域初期化
  canvas.setColorDepth(16);     // カラーモード設定(16bit)
  canvas.setTextWrap(false);    // テキストが画面からはみ出した時の折り返し無し
  canvas.createSprite(128, 64); // メモリ描画(カウント値表示)領域を設定(X, Y)

  // マルチタスク（並列処理）設定（カウントダウン処理）
  xTaskCreatePinnedToCore(count_task, "count_task", 4096, NULL, 1, NULL, 0);
}

// メイン -------------------------------------------------------------------
void loop() {
  AtomS3.update();           //本体ボタン状態更新

  // カウント値換算（分：秒：ミリ秒）
  min_cnt = count / 6000;                                 // 分カウント値換算
  sec_cnt = (count - (min_cnt * 6000))/100;               // 秒カウント値換算
  msec_cnt = count - (min_cnt * 6000) - (sec_cnt * 100);  // ミリ秒カウント値換算

  // カウントエリア液晶表示（スプライト）
  canvas.clear(M5.Lcd.color565(20, 0, 0)); // 背景色
  canvas.setCursor(0, 10);              // カーソル座標
  canvas.setFont(&fonts::Font7);        // フォント
  if (limit_flag == false) {            // カウントリミットフラグがfalseなら
    canvas.setTextColor(TFT_YELLOW);    // 文字色（黄）
  } else {                              // カウントリミットフラグがtrueなら
    canvas.setTextColor(TFT_RED);       // 文字色（赤）
  }
  canvas.setTextSize(0.9);              // 文字サイズ倍率
  canvas.printf("%d:%02d", min_cnt, sec_cnt); // カウント値表示（分：秒）

  canvas.setCursor(95, 27);             // カーソル座標
  canvas.setTextSize(0.47);             // 文字サイズ倍率
  canvas.printf(":%02d", msec_cnt);     // カウント値表示（：ミリ秒）
  canvas.pushSprite(0, 48); // 座標を指定してメモリ描画領域表示実行(x, y)

  // ボタン長押しカウント値リセット
  if (digitalRead(BTN_GPIO) == LOW) {     // 本体ボタンONなら
    ledcDetachPin(BZ_GPIO);               // ブザーOFF：PWMﾁｬﾝﾈﾙ割り当て解除（ピン番号, ﾁｬﾝﾈﾙ）
    if (press_state == false) {           // ボタン長押し状態でなければ
      press_time = millis();              // ボタン長押し時間初期値セット
      press_state = true;                 // ボタン長押し状態に変更
    }
    if (millis() >= (press_time + 800)) { // ボタン長押し時間初期値 + 800msなら
      count = 18000;                      // カウント値初期化
      start_flag = false;                 // カウントダウンスタートフラグをfalseへ
      limit_flag = false;                 // カウントリミットフラグをfalseへ
    }
  }
  // ボタンON
  if (digitalRead(BTN_GPIO) == LOW && btn_state == false) { // 本体ボタンONでボタン単押し状態がfalseなら
    btn_state = true;         // ボタン単押し状態をtrueへ
    start_flag = !start_flag; // カウントダウンスタートフラグを反転
  }
  // ボタンOFF
  if (digitalRead(BTN_GPIO) == true) {  // 本体ボタンがOFFなら
    btn_state = false;                  // ボタン単押し状態をfalseへ
    press_state = false;                // ボタン長押し状態をfalseへ
  }

  // カウントリミット処理
  if (min_cnt == 0 && sec_cnt <= 10) {  // 分カウント換算値が0で、秒カウントが10以下なら
    limit_flag = true;                  // カウントリミットフラグをtrueへ
  }
  // カウント終了ブザー出力
  if (count == 0) {             // 総カウント値が0なら
    ledcAttachPin(BZ_GPIO, 1);  // ブザーON：PWMﾁｬﾝﾈﾙ割り当て（ピン番号, ﾁｬﾝﾈﾙ）
  }
  delay(7); // メイン処理遅延時間
}

// カウントダウン処理（マルチタスク：並列処理）---------------------------------------
static void count_task(void *) {
  while (true) {  // ずっと実行（並列処理）
    delay(10);    // 0.01秒カウント
    // カウントダウンスタートフラグでカウントが0ではなく、本体ボタンがOFFならカウント実行
    if (start_flag == true && count != 0 && digitalRead(BTN_GPIO) == HIGH) {
      count--;    // 総カウント値 -1
    }
  }
}

#include <M5AtomS3.h>

static M5Canvas canvas1(&M5.Lcd); // スプライト1（メモリ描画領域）をcanvas1として準備
static M5Canvas canvas2(&M5.Lcd); // スプライト2（メモリ描画領域）をcanvas2として準備

bool change_flag = false; // 表示変更フラグ

// 初期設定 ----------------------------------------------------------
void setup() {
  auto cfg = M5.config(); // 本体初期設定
  AtomS3.begin(cfg);

  Serial.begin(9600); // シリアル通信初期化
  delay(1000);        // シリアル出力開始待ち
  Serial.println("ATOM S3 Simple Disp");  // シリアル出力

  // 液晶表示内容設定
  M5.Lcd.init(); // Lcdインスタンス初期化
  // スプライト1（メモリ描画領域）表示内容
  canvas1.setColorDepth(16);                        // カラーモード設定(16bit)
  canvas1.createSprite(M5.Lcd.width(), M5.Lcd.height());  // canvas1サイズ（メモリ描画領域）設定（画面サイズに設定）
  canvas1.fillScreen(TFT_BLACK);                    // 背景色（透明）
  canvas1.fillCircle(64, 64, 63, TFT_LIGHTGRAY);    // 塗り潰し円
  canvas1.fillCircle(64, 64, 59, TFT_ORANGE);       // 塗り潰し円
  canvas1.setTextColor(TFT_WHITE);                  // 文字色
  canvas1.drawCentreString("ロジカラ", 64, 37, &fonts::lgfxJapanGothicP_28);  // 上中央座標を基準に文字表示（表示内容, x, y, フォント）
  canvas1.drawCentreString("ブログ", 64, 65, &fonts::lgfxJapanGothicP_28);    // 上中央座標を基準に文字表示（表示内容, x, y, フォント）

  // スプライト2（メモリ描画領域）表示内容
  canvas2.setColorDepth(16);                        // カラーモード設定(16bit)
  canvas2.createSprite(M5.Lcd.width(), M5.Lcd.height());  // canvas2サイズ（メモリ描画領域）設定（画面サイズに設定）
  canvas2.fillScreen(TFT_BROWN);                    // 背景色
  canvas2.fillCircle(64, 64, 63, TFT_DARKGREY);     // 塗り潰し円
  canvas2.fillCircle(64, 64, 59, M5.Lcd.color565(30, 0, 0));  // 塗り潰し円
  canvas2.setTextColor(TFT_WHITE);                  // 文字色
  canvas2.drawCentreString("Logikara", 64, 40, &fonts::lgfxJapanMinchoP_24);  // 上中央座標を基準に文字表示（表示内容, x, y, フォント）
  canvas2.drawCentreString("Blog", 64, 68, &fonts::lgfxJapanMinchoP_24);      // 上中央座標を基準に文字表示（表示内容, x, y, フォント）
}

// メイン -------------------------------------------------------------------
void loop() {
  AtomS3.update(); //本体状態更新
  // 本体ボタンON
  if (M5.BtnA.wasPressed()) { // ボタンAが押されたら
    change_flag = !change_flag; // 表示変更フラグを反転
  }
  // 液晶表示変更
  if (change_flag == false) {   // 表示変更フラグがfalseなら
    canvas1.pushSprite(0, 0);   // canvas1を座標を指定して表示（スプライト）
  } else {                      // 表示変更フラグがtrueなら
    canvas2.pushSprite(0, 0);   // canvas2を座標を指定して表示（スプライト）
  }
  delay(100); // 遅延時間
}

#include <M5AtomS3.h>

AtomS3.update(); //本体状態更新
// 本体ボタンON
if (M5.BtnA.wasPressed()) { // ボタンAが押されたら
  change_flag = !change_flag; // 表示変更フラグを反転
}

static M5Canvas canvas1(&M5.Lcd);  // スプライト1（メモリ描画領域）をcanvas1として準備
static M5Canvas canvas2(&M5.Lcd);  // スプライト2（メモリ描画領域）をcanvas2として準備

canvas1.pushSprite(0, 0);   // canvas1を座標を指定して表示（スプライト）

canvas2.pushSprite(0, 0);   // canvas2を座標を指定して表示（スプライト）

// マルチタスク（並列処理）設定（カウントダウン処理）
xTaskCreatePinnedToCore(count_task, "count_task", 4096, NULL, 1, NULL, 0);

// カウントダウン処理（マルチタスク：並列処理）---------------------------------------
static void count_task(void *) {
  while (true) {  // ずっと実行（並列処理）
    delay(10);    // 0.01秒カウント
    // カウントダウンスタートフラグでカウントが0ではなく、本体ボタンがOFFならカウント実行
    if (start_flag == true && count != 0 && digitalRead(BTN_GPIO) == HIGH) {
      count--;    // 総カウント値 -1
    }
  }
}

// PWM出力初期設定
pinMode(BZ_GPIO, OUTPUT); // GroveコネクタG2端子出力設定（外付けブザー）
ledcSetup(1, 1000, 10);   // PWM初期設定（ﾁｬﾝﾈﾙ, 周波数Hz, bit数）
ledcWrite(1, 512);        // PWM出力開始（ﾁｬﾝﾈﾙ、Duty比：MAXはbit数の分解能）

ledcAttachPin(BZ_GPIO, 1);  // ブザーON：PWMﾁｬﾝﾈﾙ割り当て（ピン番号, ﾁｬﾝﾈﾙ）

ledcDetachPin(BZ_GPIO);     // ブザーOFF：PWMﾁｬﾝﾈﾙ割り当て解除（ピン番号, ﾁｬﾝﾈﾙ）