ジョイスティック(JoyStick)の使い方、つなぎ方、動作原理等を回路図も使って詳しく解説

#include <M5StickCPlus.h>     // ヘッダーファイル
// 変数宣言
float x_data;   // ジョイスティックX軸
float y_data;   // ジョイスティックY軸
int press;      // ジョイスティック押し込みボタン
float setting[16][5]; // チャンネル[0〜15]ごとの[周波数, bit数, 0゜パルス時間ms, 最大角度パルス時間ms, 最大動作角度]格納配列
float x_angle;        // X軸角度指示値
float y_angle;        // Y軸角度指示値
float duty_angle;     // X軸角度初期値
float duty_y_angle;   // Y軸角度初期値
float read_x_angle;   // X軸角度現在値
float read_y_angle;   // Y軸角度現在値
int cnt = 0;  // カウント用
/******************* PWM出力、サーボ仕様設定関数 *******************/
void servo_set(int pin, int channel, float freq, float bit_num, float time_min, float time_max, float angle_max) {
  // サーボ設定値をチャンネルごとの配列に格納
  setting[channel][0] = freq;       // 周波数
  setting[channel][1] = bit_num;    // bit数
  setting[channel][2] = time_min;   // 0゜パルス時間ms
  setting[channel][3] = time_max;   // 最大角度パルス時間ms
  setting[channel][4] = angle_max;  // 最大動作角度
  // PWM設定
  pinMode(pin, OUTPUT);               // PWM用ピンを出力設定
  ledcSetup(channel, freq, bit_num);  // PWM設定（ﾁｬﾝﾈﾙ, 周波数, ビット数）
  ledcAttachPin(pin, channel);        // PWMﾁｬﾝﾈﾙ割り当て（ピン番号, ﾁｬﾝﾈﾙ）
}
/******************* サーボ動作実行関数 *******************/
float servo(int channel, float angle) {
  float resolution;   // 分解能
  float period;       // 周期ms
  float duty_min;     // 0゜Duty計算値
  float duty_max;     // 最大角度Duty計算値
  float duty_active;  // 動作範囲のDuty計算値
  int duty_value;     // PWM出力Duty値（High状態）※整数型として小数点以下切り捨て
  float read_angle;   // PWM出力Duty値からの角度換算

  // サーボ定数算出
  resolution = pow(2, setting[channel][1]);                 // 分解能（2のbit数乗）
  period = 1000 / setting[channel][0];                      // 周期（1000ms / 周波数） 
  duty_min = (resolution / period) * (setting[channel][2]); // 0゜Duty計算値（(分解能/周期)*0゜パルス時間μs）
  duty_max = (resolution / period) * (setting[channel][3]); // 最大角度Duty計算値（(分解能/周期)*最大角度パルス時間μs）
  duty_active = duty_max - duty_min;                        // 動作範囲のDuty計算値
  duty_value = (angle * (duty_active / setting[channel][4])) + duty_min;  // 角度指定値（浮動小数点数） → PWM出力Duty値（整数）換算

  if (duty_value <= duty_min) { // PWM出力Duty値が0゜Duty計算値以下なら
    duty_value = duty_min + 1;  // PWM出力Duty値＋1
  }
  // PWM出力実行
  ledcWrite(channel, duty_value); // 指定したﾁｬﾝﾈﾙにDuty値を指定してPWM出力実行
  read_angle = (ledcRead(channel) - duty_min) * setting[channel][4] / duty_active;  // PWM出力Duty値を取得して角度に換算
  return read_angle;  // 角度を返す
}
// 初期設定 ----------------------------------------------------------
void setup(){
  M5.begin();  // 本体初期化
  // アナログ入力設定
  pinMode(32, ANALOG);  //アナログ入力
  pinMode(33, ANALOG);  //アナログ入力
  // G36とG25は同時使用不可。使っていない方は以下のようにフローティング入力にする
  gpio_pulldown_dis(GPIO_NUM_36);
  gpio_pullup_dis(GPIO_NUM_36);
  // 入力設定
  pinMode(0, INPUT_PULLUP); //入力設定（プルアップ）

  // PWM出力、サーボ仕様設定（サーボごとに使用する端子、ﾁｬﾝﾈﾙ等を設定）
  // PWM出力のﾁｬﾝﾈﾙは 0,1/ 2,3/ 4,5/ 6,7/ 8,9/ 10,11 /12,13 /14,15でペア ※周波数と分解能はペアで同じにする必要があります。
  // (出力端子, ﾁｬﾝﾈﾙ, 周波数, bit数, 0゜パルス時間ms, 最大角度動作時間ms, 最大動作角度)
  servo_set(26, 1, 50, 12, 0.5, 2.4, 180); // ﾁｬﾝﾈﾙ1（X軸）：PWM出力、サーボ仕様設定関数呼び出し
  servo_set(25, 2, 50, 12, 0.5, 2.4, 180); // ﾁｬﾝﾈﾙ2（Y軸）：PWM出力、サーボ仕様設定関数呼び出し

  // LCD表示設定
  M5.Lcd.setTextFont(4);  // フォント設定
  M5.Lcd.fillScreen(BLACK);  M5.Lcd.setTextColor(WHITE, BLACK); // 背景、文字色
}
// メイン処理 --------------------------------------------------------
void loop() {
  M5.update();  // ボタン状態更新
  // A/D変換、角度換算処理
  x_data = analogRead(32);                     // アナログ電圧をデジタル値に変換して取得（0〜4095）
  x_angle = 180 - (x_data * (180.0 / 4095.0)); //角度へ換算（動作反転）
  y_data = analogRead(33);                     // アナログ電圧をデジタル値に変換して取得（0〜4095）
  y_angle = y_data * (180.0 / 4095.0);         //角度へ換算

  // サーボ動作指定（戻り値として角度を取得）
  read_x_angle = servo(1, x_angle); // ﾁｬﾝﾈﾙ1：サーボ動作実行関数呼び出し（ﾁｬﾝﾈﾙ, 角度値）
  read_y_angle = servo(2, y_angle); // ﾁｬﾝﾈﾙ2：サーボ動作実行関数呼び出し（ﾁｬﾝﾈﾙ, 角度値）
  // スティック押し込みボタン検出
  if (digitalRead(0)) { // スティックが押されたら
    press = 0;          // pressを1
  } else {              // 押されてなければ
    press = 1;          // pressを2
  }
  // 液晶表示
  if (cnt == 30) {  // カウント30ごとに液晶表示更新
    M5.Lcd.setCursor(0, 0);                     // 座標指定
    M5.Lcd.println(" JoyStick");                // 項目表示
    M5.Lcd.printf("X : %3.0f      \n", x_data); // X軸アナログ値
    M5.Lcd.printf("Y : %3.0f      \n", y_data); // Y軸アナログ値
    M5.Lcd.printf("Press : %d   \n\n", press);  // 押し込みボタン状態表示
    M5.Lcd.printf("Xr : %3.1f'     \n", read_x_angle); // x軸角度
    M5.Lcd.printf("Yr : %3.1f'     \n", read_y_angle); // y軸角度
    cnt = 0;  // カウントリセット
  }
  cnt++;      // カウント +1
  delay(10);  // 遅延時間
}

#include <M5StickCPlus.h>     // ヘッダーファイル
// 変数宣言
float x_data;   // ジョイスティックX軸
float y_data;   // ジョイスティックY軸
int press;      // ジョイスティック押し込みボタン
float setting[16][5]; // チャンネル[0〜15]ごとの[周波数, bit数, 0゜パルス時間ms, 最大角度パルス時間ms, 最大動作角度]格納配列
float x_angle;        // X軸角度指示値
float y_angle;        // Y軸角度指示値
float duty_angle;     // X軸角度初期値
float duty_y_angle;   // Y軸角度初期値
float read_x_angle;   // X軸角度現在値
float read_y_angle;   // Y軸角度現在値
int cnt = 0;    // カウント用
/******************* PWM出力、サーボ仕様設定関数 *******************/
void servo_set(int pin, int channel, float freq, float bit_num, float time_min, float time_max, float angle_max) {
  // サーボ設定値をチャンネルごとの配列に格納
  setting[channel][0] = freq;       // 周波数
  setting[channel][1] = bit_num;    // bit数
  setting[channel][2] = time_min;   // 0゜パルス時間ms
  setting[channel][3] = time_max;   // 最大角度パルス時間ms
  setting[channel][4] = angle_max;  // 最大動作角度
  // PWM設定
  pinMode(pin, OUTPUT);               // PWM用ピンを出力設定
  ledcSetup(channel, freq, bit_num);  // PWM設定（ﾁｬﾝﾈﾙ, 周波数, ビット数）
  ledcAttachPin(pin, channel);        // PWMﾁｬﾝﾈﾙ割り当て（ピン番号, ﾁｬﾝﾈﾙ）
}
/********************** サーボ動作実行関数 **********************/
float servo(int channel, float angle) {
  float resolution;   // 分解能
  float period;       // 周期ms
  float duty_min;     // 0゜Duty計算値
  float duty_max;     // 最大角度Duty計算値
  float duty_active;  // 動作範囲のDuty計算値
  int duty_value;     // PWM出力Duty値（High状態）※整数型として小数点以下切り捨て
  float read_angle;   // PWM出力Duty値からの角度換算

  // サーボ定数算出
  resolution = pow(2, setting[channel][1]);                 // 分解能（2のbit数乗）
  period = 1000 / setting[channel][0];                      // 周期（1000ms / 周波数） 
  duty_min = (resolution / period) * (setting[channel][2]); // 0゜Duty計算値（(分解能/周期)*0゜パルス時間μs）
  duty_max = (resolution / period) * (setting[channel][3]); // 最大角度Duty計算値（(分解能/周期)*最大角度パルス時間μs）
  duty_active = duty_max - duty_min;                        // 動作範囲のDuty計算値
  duty_value = (angle * (duty_active / setting[channel][4])) + duty_min;  // 角度指定値（浮動小数点数） → PWM出力Duty値（整数）換算

  if (duty_value <= duty_min) { // PWM出力Duty値が0゜Duty計算値以下なら
    duty_value = duty_min + 1;  // PWM出力Duty値＋1
  }
  // PWM出力実行
  ledcWrite(channel, duty_value); // 指定したﾁｬﾝﾈﾙにDuty値を指定してPWM出力実行
  read_angle = (ledcRead(channel) - duty_min) * setting[channel][4] / duty_active;  // PWM出力Duty値を取得して角度に換算
  return read_angle;  // 角度を返す
}
// 初期設定 ----------------------------------------------------------
void setup(){
  M5.begin();         // 本体初期化
  Wire.begin(32, 33); // Grove端子をI2C設定（SDA, SCL）

  // PWM出力、サーボ仕様設定（サーボごとに使用する端子、ﾁｬﾝﾈﾙ等を設定）
  // PWM出力のﾁｬﾝﾈﾙは 0,1/ 2,3/ 4,5/ 6,7/ 8,9/ 10,11 /12,13 /14,15でペア ※周波数と分解能はペアで同じにする必要があります。
  // (出力端子, ﾁｬﾝﾈﾙ, 周波数, bit数, 0゜パルス時間ms, 最大角度動作時間ms, 最大動作角度)
  servo_set(26, 1, 50, 12, 0.5, 2.4, 180); // ﾁｬﾝﾈﾙ1（X軸）：PWM出力、サーボ仕様設定関数呼び出し
  servo_set(25, 2, 50, 12, 0.5, 2.4, 180); // ﾁｬﾝﾈﾙ2（Y軸）：PWM出力、サーボ仕様設定関数呼び出し

  // LCD表示設定
  M5.Axp.ScreenBreath(9); // 液晶画面明るさレベル（標準12）
  M5.Lcd.setTextFont(4);  // フォント設定
  M5.Lcd.fillScreen(BLACK);  M5.Lcd.setTextColor(WHITE, BLACK); // 背景、文字色
}
// メイン処理 --------------------------------------------------------
void loop() {
  // ジョイスティックI2Cデータ取得
  Wire.requestFrom(0x52, 3);  // I2Cデータ取得（アドレス、バイト数）
  while (Wire.available()) {  // 受信データがあれば
    x_data = Wire.read();     // X軸アナログ値取得（0〜255）
    y_data = Wire.read();     // Y軸アナログ値取得（0〜255）
    press = Wire.read();      // 押し込み時ボタン状態取得（true/false）
  }
  //  ジョイスティック座標-角度換算
  x_angle = map(x_data, 0, 255, 0, 180);  // X軸 - 角度換算
  y_angle = map(y_data, 0, 255, 0, 180);  // Y軸 - 角度換算

  // サーボ動作指定（戻り値として角度を取得）
  read_x_angle = servo(1, x_angle); // ﾁｬﾝﾈﾙ1：サーボ動作実行関数呼び出し（ﾁｬﾝﾈﾙ, 角度値）
  read_y_angle = servo(2, y_angle); // ﾁｬﾝﾈﾙ2：サーボ動作実行関数呼び出し（ﾁｬﾝﾈﾙ, 角度値）
  // 液晶表示
  if (cnt == 30) {  // カウント30ごとに液晶表示更新
    M5.Lcd.setCursor(0, 0);                     // 座標指定
    M5.Lcd.println(" JoyStick");                // 項目表示
    M5.Lcd.printf("X : %3.0f      \n", x_data); // X軸アナログ値
    M5.Lcd.printf("Y : %3.0f      \n", y_data); // Y軸アナログ値
    M5.Lcd.printf("Press : %d   \n\n", press);  // 押し込みボタン状態
    M5.Lcd.printf("Xr : %3.0f'     \n", read_x_angle); // x軸角度
    M5.Lcd.printf("Yr : %3.0f'     \n", read_y_angle); // y軸角度
    cnt = 0;  // カウント0リセット
  }
  cnt++;      // カウント +1
  delay(10);  // 遅延時間
}

  // ジョイスティックI2Cデータ取得
  Wire.requestFrom(0x52, 3);  // I2Cデータ取得（アドレス、バイト数）
  while (Wire.available()) {  // 受信データがあれば
    x_data = Wire.read();     // X軸アナログ値取得（0〜255）
    y_data = Wire.read();     // Y軸アナログ値取得（0〜255）
    press = Wire.read();      // 押し込み時ボタン状態取得（true/false）
  }