M5StickC Plus2の使い方、初期設定、旧モデルとの違い等サンプルプログラムで詳しく紹介

#include <M5StickCPlus.h>   // 旧モデル M5StickC Plusの場合

#include <M5StickCPlus2.h>  // 新モデル M5StickC Plus2の場合

auto cfg = M5.config();  // 本体初期化
StickCP2.begin(cfg);

// 電源ボタン状態取得（1秒以下のONで「2」1秒以上で「1」すぐに「0」に戻る）
btn_c = M5.Axp.GetBtnPress();  // これを書くとエラーになる。

// M5GFXのフォントが指定可能
M5.Lcd.setFont(&fonts::lgfxJapanGothicP_32);  // M5GFXのフォントが指定可能（メモリ消費注意）

lgfxJapanMincho_8   // 明朝体 固定幅フォント
lgfxJapanMinchoP_8  // 明朝体 プロポーショナルフォント
lgfxJapanGothic_8   // ゴシック体 固定幅フォント
lgfxJapanGothicP_8  // ゴシック体 プロポーショナルフォント

// 推奨
canvas.setFont(&fonts::Font2)

// 非推奨
canvas.setTextFont(2);

Font0  // 8px ASCII文字
Font2  // 16px ASCII文字
Font4  // 26px ASCII文字
Font6  // 36(48)px 数字と時計用文字のみ（1234567890apm.:-）
Font7  // 48px 7セグ風数字と記号のみ（1234567890.:-）
Font8  // 75px 数字と記号のみ（1234567890.:-）

// 旧モデルの場合
M5.Beep.update();        //ブザー状態更新(M5.Beep.toneで指定した発音時間が経過していたらOFFする)

M5.Beep.tone(4400, 100);  //ブザーを鳴らす(周波数Hz, 発音時間ms)

// 新モデルの場合
StickCP2.Speaker.tone(4400, 100);  // ブザーを鳴らす（周波数Hz, 発音時間ms)

// 旧モデルの場合
M5.Axp.GetBatVoltage()  // バッテリー電圧取得(Max 4.2[V])

// 新モデルの場合
StickCP2.Power.getBatteryVoltage();  // バッテリー電圧の取得（Max4200[mA]）
StickCP2.Power.getBatteryLevel()  // バッテリーの状態を 0〜100％ で取得

#include <M5StickCPlus2.h>
/* M5StickC Plus端子仕様
  G0 :入力／出力／アナログ入力（無線使用時無効、内部で10kΩでプルアップ）
  G36:入力／ ―  ／アナログ入力
  G25:入力／出力／アナログ入力（無線使用時無効）／デジタル出力
  G26:入力／出力／アナログ入力（無線使用時無効）／デジタル出力
  G32:入力／出力／アナログ入力／Groveコネクタ(SDA）
  G33:入力／出力／アナログ入力／Groveコネクタ(SCL）
  　※G25/36はポートを共有しているため同時使用不可（使用しない方はフローティング入力にする）
  G37:本体ボタンA
  G39:本体ボタンB
  G35:本体ボタンC（6秒長押しで電源OFF）
  G19:本体LED（赤外線LEDと共用）
*/

// 端子割り付け
#define LED 19  // 本体LED

// 初期設定 -----------------------------------------
void setup() {
  auto cfg = M5.config();  // 本体初期化
  StickCP2.begin(cfg);

  // 出力端子設定
  pinMode(LED, OUTPUT);    // 本体LED赤
  digitalWrite(LED, LOW);  // 本体LED初期値OFF（LOW）

  // ベース画面の初期設定
  M5.Lcd.fillScreen(BLACK); // 背景色
  M5.Lcd.setRotation(1);  // 画面向き設定（USB位置基準 0：下/ 1：右/ 2：上/ 3：左）
  M5.Lcd.setTextSize(1);  // 文字サイズ（整数倍率）
}
// メイン -----------------------------------------
void loop() {
  M5.update();  //本体ボタン状態更新

  M5.Lcd.fillScreen(BLACK);  // 画面初期化
  // タイトル表示処理
  M5.Lcd.setFont(&fonts::Font4);        // M5GFXのフォントが指定可能（メモリ消費注意）
  M5.Lcd.setCursor(10, 5);              // 座標設定(x, y)
  M5.Lcd.setTextColor(WHITE, BLACK);    // 文字色指定(文字色, 背景)
  M5.Lcd.print("M5StickC Plus2 test");  // 表示内容

  // ライン表示
  M5.Lcd.drawFastHLine (0, 30, 240, WHITE);  // 指定座標から水平線（x, y, 長さ, 色）

  // 本体ボタンA処理
  M5.Lcd.setFont(&fonts::lgfxJapanGothicP_32);  // M5GFXのフォントが指定可能（メモリ消費注意）
  M5.Lcd.setCursor(15, 60);  // 座標設定(x, y)

  if (M5.BtnA.isPressed()) {  // ボタンAがONなら
    M5.Lcd.setTextColor(ORANGE, BLACK); // 文字色指定(文字色, 背景)
    M5.Lcd.print("ボタンA：ON");         // 表示内容
    digitalWrite(LED, HIGH);            // 本体LED点灯
  } else {                    // ボタンAがOFFなら
    M5.Lcd.setTextColor(CYAN, BLACK);   // 文字色指定(文字色, 背景)
    M5.Lcd.print("ボタンA：OFF");        // 表示内容
    digitalWrite(LED, LOW);             // 本体LED消灯
  }

  delay(100);  // 遅延時間（ms）
}

#include <M5StickCPlus2.h>

// メモリ描画領域表示（スプライト）のインスタンスを作成(必要に応じて複数作成)
M5Canvas canvas(&M5.Lcd);  // &M5.Lcd を &StickCP2.Display と書いても同じ

// 端子割り付け
#define LED 19  // 本体LED

// 初期設定 -----------------------------------------
void setup() {
  auto cfg = M5.config();  // 本体初期化
  StickCP2.begin(cfg);

  // 出力設定
  pinMode(LED, OUTPUT);    // 本体LED赤
  digitalWrite(LED, LOW);  // 本体LED初期値OFF（LOW）

  // G36とG25は同時使用不可。使っていない方は以下のようにフローティング入力にする
  gpio_pulldown_dis(GPIO_NUM_25);
  gpio_pullup_dis(GPIO_NUM_25);

  // ベース画面の初期設定
  M5.Lcd.fillScreen(BLACK); // 背景色
  M5.Lcd.setRotation(1);  // 画面向き設定（USB位置基準 0：下/ 1：右/ 2：上/ 3：左）
  M5.Lcd.setTextSize(1);  // 文字サイズ（整数倍率）

  canvas.setTextWrap(false);  // 改行をしない（画面をはみ出す時自動改行する場合はtrue。書かないとtrue）
  canvas.createSprite(M5.Lcd.width(), M5.Lcd.height()); // canvasサイズ（メモリ描画領域）設定（画面サイズに設定）
}
// メイン -----------------------------------------
void loop() {
  M5.update();  //本体ボタン状態更新

  canvas.fillScreen(BLACK);  // 画面初期化
  // タイトル表示処理
  canvas.setFont(&fonts::Font4);        // M5GFXのフォントが指定可能（メモリ消費注意）
  canvas.setCursor(10, 5);              // 座標設定(x, y)
  canvas.setTextColor(WHITE, BLACK);    // 文字色指定(文字色, 背景)
  canvas.print("M5StickC Plus2 test");  // 表示内容

  // ライン表示
  canvas.drawFastHLine (0, 30, 240, WHITE);  // 指定座標から水平線（x, y, 長さ, 色）

  // 本体ボタンA処理
  canvas.setFont(&fonts::lgfxJapanGothicP_32);  // M5GFXのフォントが指定可能（メモリ消費注意）
  canvas.setCursor(15, 60);  // 座標設定(x, y)
  
  if (M5.BtnA.isPressed()) {  // ボタンAがONなら
    canvas.setTextColor(ORANGE, BLACK); // 文字色指定(文字色, 背景)
    canvas.print("ボタンA：ON");         // 表示内容
    digitalWrite(LED, HIGH);            // 本体LED点灯
  } else {                    // ボタンAがOFFなら
    canvas.setTextColor(CYAN, BLACK);   // 文字色指定(文字色, 背景)
    canvas.print("ボタンA：OFF");        // 表示内容
    digitalWrite(LED, LOW);             // 本体LED消灯
  }

  // メモリ描画領域を座標を指定して一括表示（スプライト）
  canvas.pushSprite(&M5.Lcd, 0, 0);  // (0, 0)座標に一括表示実行

  delay(100);  // 遅延時間（ms）
}

#include <M5StickCPlus2.h>

// メモリ描画領域表示（スプライト）のインスタンスを作成(必要に応じて複数作成)
M5Canvas canvas(&M5.Lcd);  // &M5.Lcd を &StickCP2.Display と書いても同じ

// 端子割り付け
#define IN0 33  // GROVEコネクタ入力端子(外付けボタンA)
#define IN1 32  // GROVEコネクタ入力端子(外付けボタンB)
#define OUT 0   // 出力端子(外付けLED)
#define ADC 36  // アナログ入力端子
#define DAC 26  // アナログ出力端子
#define LED 19  // 本体LED
#define HOLD 4  // ホールド端子

// 変数設定
float ad_val;   // アナログ入力値格納用
float da_val;   // アナログ出力値指定用
float v_in = 0; // アナログ入力電圧換算値
float v_out = 0;// アナログ出力電圧換算用
float battery;  // バッテリー残量表示用
bool state;     // ボタン状態確認用

// 初期設定 -----------------------------------------
void setup() {
  auto cfg = M5.config();  // 本体初期設定
  StickCP2.begin(cfg);

  // 入力端子設定
  pinMode(IN0, INPUT_PULLUP);  // 入力設定（プルアップ）
  pinMode(IN1, INPUT_PULLUP);

  // 出力端子設定
  pinMode(OUT, OUTPUT);    // 出力設定（外部LED青）
  pinMode(LED, OUTPUT);    // 本体LED赤
  pinMode(HOLD, OUTPUT);   // ホールド端子
  digitalWrite(OUT, HIGH); // 出力（外部LED青）初期値
  digitalWrite(LED, LOW);  // 本体LED初期値OFF（LOW）
  digitalWrite(HOLD, HIGH); // ホールド端子初期化（HIGH）

  // アナログ入力端子設定
  pinMode(ADC, ANALOG);  // アナログ入力

  // アナログ出力端子設定
  pinMode(DAC, OUTPUT);  // 出力に設定
  dacWrite(DAC, 0);      // 初期値0設定

  // PWM出力端子設定
  pinMode(OUT, OUTPUT );  // PWM出力を行う端子を出力端子として設定
  ledcSetup (1, 500, 12); // PWM出力波形の初期設定（チャンネル、周波数、分解能bit）
  ledcAttachPin(OUT ,1);  // チャンネルに対する出力端子を設定

  // G36とG25は同時使用不可。使っていない方は以下のようにフローティング入力にする
  gpio_pulldown_dis(GPIO_NUM_25);
  gpio_pullup_dis(GPIO_NUM_25);

  // ベース画面の初期設定
  M5.Lcd.fillScreen(BLACK); // 背景色
  M5.Lcd.setRotation(1);    // 画面向き設定（USB位置基準 0：下/ 1：右/ 2：上/ 3：左）
  M5.Lcd.setTextSize(1);    // 文字サイズ（整数倍率）
  M5.Lcd.setFont(&fonts::lgfxJapanGothicP_20);  // M5GFXのフォントが指定可能

  canvas.setTextWrap(false);  // 改行をしない（画面をはみ出す時自動改行する場合はtrue。書かないとtrue）
  canvas.createSprite(M5.Lcd.width(), M5.Lcd.height()); // canvasサイズ（メモリ描画領域）設定（画面サイズに設定）
}
// メイン -----------------------------------------
void loop() {
  M5.update();  //本体ボタン状態更新

  // 本体ボタン、外部ボタン入力処理
  // ボタンA または 外部スイッチ赤が押されている かつ アナログ出力255より小さいなら
  if ((M5.BtnA.isPressed() || digitalRead(IN0) == 0) && da_val < 255) {
    da_val++;  // アナログ出力 +1
    if (state == false) {  // ボタン状態がOFFなら
      state = true;                      // ボタン状態ON
      StickCP2.Speaker.tone(4000, 100);  // ブザーON（周波数 Hz, 発音時間 ms)
    }
  }
  // ボタンB または 外部スイッチ青が押されてる かつ アナログ出力0より大きいなら
  if ((M5.BtnB.isPressed() || digitalRead(IN1) == 0) && da_val > 0) {
    da_val--;  // アナログ出力 -1
    if (state == false) {  // ボタン状態がOFFなら
      state = true;                      // ボタン状態ON
      StickCP2.Speaker.tone(2000, 200);  // ブザーON（周波数 Hz, 発音時間 ms)
    }
  }
  // ボタンC（電源ボタン）USB未接続時に即時電源OFF
  if (digitalRead(35) == (LOW)) {  // 電源が押されていれば
    digitalWrite(HOLD, LOW);  // ホールド端子LOWで電源OFF（USB未接続時）
  } else {  // 電源が押されてなければ
    digitalWrite(HOLD, HIGH); // ホールド端子をHIGHに戻す
  }

  // 本体LED点灯処理（いずれかのボタンが押されていれば）
  if (M5.BtnA.isPressed() || M5.BtnB.isPressed() ||  not digitalRead(35) ||  not digitalRead(32) || not digitalRead(33)) {  // ボタンA または ボタンB がONなら
    digitalWrite(LED, HIGH);  // 本体LED赤点灯
  } else {                    // どのボタンも押されてなければ
    digitalWrite(LED, LOW);   // 本体LED赤消灯
    state = false;            // ボタン状態OFF
  }

  // アナログ入力処理
  ad_val = analogRead(ADC);     // アナログ入力値を取得
  v_in = ad_val * (3.3 / 4095); // 3.3Vへ換算

  // アナログ出力処理
  dacWrite(DAC, da_val);        // アナログ出力実行
  v_out = da_val * (3.3 / 255); // 3.3Vへ換算

  // PWM出力
  ledcWrite(1, ad_val);  // アナログ入力値をDuty比に指定してPWM出力(チャンネル, Duty比)

  // バッテリー残量取得（パーセント）
  battery = StickCP2.Power.getBatteryLevel();  // 0〜100％ で取得

  // LCD表示処理
  canvas.fillScreen(BLACK); // 画面初期化

  canvas.setFont(&fonts::lgfxJapanGothicP_24);  // フォント
  canvas.setCursor(5, 0);            //座標設定(x, y)
  canvas.setTextColor(BLUE, BLACK);  //(文字色, 背景)
  canvas.printf("ボタンA : %d", not digitalRead(37) || not digitalRead(33));  // 本体と外部ボタンAの状態表示

  canvas.setCursor(5, 25);
  canvas.setTextColor(RED, BLACK);
  canvas.printf("ボタンB : %d", not digitalRead(39) || not digitalRead(32));    // 本体と外部ボタンBの状態表示

  canvas.setCursor(5, 50);
  canvas.setTextColor(WHITE, BLACK);
  canvas.printf("ADC : %01.2fv  ( %04.0f )", v_in, ad_val);  // アナログ入力値表示

  canvas.setCursor(5, 75);
  canvas.printf("DAC : %01.2fv  ( %04.0f )", v_out, da_val);  // アナログ出力値表示

  canvas.setCursor(5, 100);
  canvas.setTextColor(ORANGE, BLACK);
  canvas.printf("電源ボタン(C) : %d", not digitalRead(35));  // 電源ボタン（ボタンC）の状態取得

  canvas.setTextFont(2);  // フォント（基本フォントの設定はこの書き方で可）
  canvas.setCursor(202, 120);
  canvas.setTextColor(GREENYELLOW, BLACK);
  canvas.printf("%.0f%%", battery);  // バッテリー残量パーセント表示

  // メモリ描画領域を座標を指定して一括表示（スプライト）
  canvas.pushSprite(&M5.Lcd, 0, 0);  // (0, 0)座標に一括表示実行

  delay(10);  // 遅延時間（ms）
}