RP2040-GEEK ラズパイPicoでSDカードと液晶使うならこれ1台でOK！

// 登録色一覧（16bit指定値）
ST77XX_BLACK    // 黒(0x0000)
ST77XX_WHITE    // 白(0xFFFF)
ST77XX_RED      // 赤(0xF800)
ST77XX_GREEN    // 緑(0x07E0)
ST77XX_BLUE     // 青(0x001F)
ST77XX_CYAN     // 水色(0x07FF)
ST77XX_MAGENTA  // 紫(0xF81F)
ST77XX_YELLOW   // 黄(0xFFE0)
ST77XX_ORANGE   // 橙(0xFC00)

#include <Adafruit_GFX.h>    // Adafruitのグラフィックスライブラリ
#include <Adafruit_ST7789.h> // ST7789液晶ディスプレイ用のライブラリ
#include <SPI.h>             // SPI通信を行うためのライブラリ

#define TFT_CS   9  // TFT液晶のCSピン
#define TFT_DC   8  // TFT液晶のDCピン 
#define TFT_MOSI 11 // TFT液晶のMOSIピン
#define TFT_SCK  10 // TFT液晶のSCKピン
#define TFT_RST  12 // TFT液晶のRSTピン

// Adafruit_GFXのフォント読み込み（必要なものだけ有効にする。他にもたくさんあります）
// #include <Fonts/FreeMono12pt7b.h>
#include <Fonts/FreeSans12pt7b.h>
// #include <Fonts/FreeSerif12pt7b.h>
// #include <Fonts/FreeMonoBold12pt7b.h>
// #include <Fonts/FreeSansBold12pt7b.h>
// #include <Fonts/FreeSerifBold12pt7b.h>
#include <Fonts/FreeSansBold18pt7b.h>

Adafruit_ST7789 tft = Adafruit_ST7789(&SPI1, TFT_CS, TFT_DC, TFT_RST);  // TFT液晶のインスタンス設定

// 初期設定 -----------------------------------------
void setup(void) {
  Serial.begin(9600); // シリアル通信初期化

  // SPI1初期設定（TFT液晶用）
  SPI1.setSCK(TFT_SCK); // TFTのSCK (GP10)
  SPI1.setTX(TFT_MOSI); // TFTのMOSI (GP11)

  // 出力端子初期設定
  pinMode(25, OUTPUT);    // TFTバックライト用端子
  digitalWrite(25, HIGH); // TFTバックライト点灯

  // TFT液晶の初期設定
  tft.init(135, 240);     // TFT初期化（画面サイズ指定）
  tft.fillScreen(0x2102); // 背景の塗りつぶし(16bitカラーで指定)
  tft.setRotation(3);     // 画面回転(0-3)
}

// メイン -----------------------------------------
void loop() {

  // タイトル表示
  tft.setTextSize(1);     // 文字サイズ（1）
  tft.setFont(&FreeSans12pt7b);   // フォント
  tft.setTextColor(ST77XX_GREEN); // 文字色(登録色で指定)

  tft.setCursor(6, 20);   // 表示開始位置左上角（X,Y）
  tft.println("LCD");     // 表示内容
  tft.setCursor(0, 45);   // 表示開始位置左上角（X,Y）
  tft.println("TEST");    // 表示内容

  tft.setTextSize(2);     // 文字サイズ（2）
  tft.setTextColor(ST77XX_ORANGE);  // 文字色
  tft.setCursor(75, 40);  // 表示開始位置左上角（X,Y）
  tft.println("ST7789");  // 表示内容
  
  tft.setTextSize(1);               // 文字サイズ（1）
  tft.setFont(&FreeSansBold18pt7b); // フォント
  tft.setTextColor(0x02DF);         // 文字色(16bitカラーで指定)
  tft.setCursor(5, 83);             // 表示開始位置左上角（X,Y）
  tft.println("RP2040-GEEK");       // 表示内容

  // 図形表示
  tft.drawLine(0, 50, 240, 50, ST77XX_WHITE);  // 線（始点終点指定）
  tft.drawFastVLine(68, 0, 45, ST77XX_CYAN);   // 線（指定座標から垂線）
  tft.drawFastHLine(0, 90, 240, ST77XX_WHITE); // 線（指定座標から平行線）

  tft.drawCircle(16, 113, 16, ST77XX_YELLOW);  // 円
  tft.fillCircle(52, 113, 16, ST77XX_RED);     // 円（塗り潰し）

  tft.drawTriangle(69, 130, 89, 95, 109, 130, ST77XX_BLUE);    // 三角
  tft.fillTriangle(114, 130, 134, 95, 154, 130, ST77XX_CYAN);  // 三角（塗り潰し）

  tft.drawRect(159, 95, 36, 36, ST77XX_GREEN);    // 四角
  tft.fillRect(200, 95, 36, 36, ST77XX_MAGENTA);  // 四角（塗り潰し）

  delay(500); // 遅延時間
}

#include <Adafruit_GFX.h>    // Adafruitのグラフィックスライブラリ
#include <Adafruit_ST7789.h> // ST7789液晶ディスプレイ用のライブラリ
#include <SPI.h>             // SPI通信を行うためのライブラリ

#define TFT_CS   9  // TFT液晶のCSピン
#define TFT_DC   8  // TFT液晶のDCピン 
#define TFT_MOSI 11 // TFT液晶のMOSIピン
#define TFT_SCK  10 // TFT液晶のSCKピン
#define TFT_RST  12 // TFT液晶のRSTピン

// Adafruit_GFXのフォント読み込み
#include <Fonts/FreeSans12pt7b.h>

Adafruit_ST7789 tft = Adafruit_ST7789(&SPI1, TFT_CS, TFT_DC, TFT_RST);  // TFT液晶表示用のインスタンス設定

// 初期設定 -----------------------------------------
void setup(void) {
  Serial.begin(9600); // シリアル通信初期化

  // SPI1初期設定（TFT液晶用）
  SPI1.setSCK(TFT_SCK);   // TFTのSCK (GP10)
  SPI1.setTX(TFT_MOSI);   // TFTのMOSI (GP11)

  // 出力端子初期設定
  pinMode(25, OUTPUT);    // TFTバックライト用端子
  digitalWrite(25, HIGH); // TFTバックライト点灯

  pinMode(2, OUTPUT);   // LED1用端子
  pinMode(3, OUTPUT);   // LED2用端子
  digitalWrite(2, LOW); // LED1消灯
  digitalWrite(3, LOW); // LED2消灯

  // 入力端子初期設定
  pinMode(4, INPUT_PULLUP); // スイッチ1用端子
  pinMode(5, INPUT_PULLUP); // スイッチ2用端子

  // アナログ入力初期設定
  analogReadResolution(12); // 分解能12bit（0〜4095）

  // TFT液晶の初期設定
  tft.init(135, 240);           // TFT初期化（画面サイズ指定）
  tft.fillScreen(ST77XX_BLACK); // 背景の塗りつぶし
  tft.setRotation(3);           // 画面回転
  tft.setFont(&FreeSans12pt7b); // フォント
}

// メイン -----------------------------------------
void loop() {
  // スイッチ状態確認、LED点灯／消灯、画面色変更
  if (digitalRead(4) == false) {  // スイッチ1がONなら
    tft.fillScreen(ST77XX_RED);   // 背景の塗りつぶし
    digitalWrite(2, HIGH);        // LED1点灯
  } else if (digitalRead(5) == false) { // スイッチ2がONなら
    tft.fillScreen(ST77XX_YELLOW);// 背景の塗りつぶし
    digitalWrite(3, HIGH);        // LED2点灯
  } else {  // スイッチが押されてなければ
    tft.fillScreen(ST77XX_BLACK); // 背景の塗りつぶし
    digitalWrite(2, LOW);         // LED1消灯
    digitalWrite(3, LOW);         // LED2消灯
  }
  // アナログ入力処理
  float ad_val1;       //アナログ入力2変換値（0～4095）格納用
  float ad_volt1;      //アナログ入力2電圧（0～3.3V）格納用
  float ad_val2;       //アナログ入力3変換値（0～4095）格納用
  float ad_volt2;      //アナログ入力3電圧（0～3.3V）格納用
  ad_val1 = analogRead(28);           //アナログ入力2変換値（0～4095）取得
  ad_volt1 = (3.3 / 4096) * ad_val1;  //アナログ入力2電圧（0～3.3V）換算
  ad_val2 = analogRead(29);           //アナログ入力3変換値（0～4095）取得
  ad_volt2 = (3.3 / 4096) * ad_val2;  //アナログ入力3電圧（0～3.3V）換算

  // 液晶画面表示
  tft.setCursor(0, 17);             // カーソル位置
  tft.setTextColor(ST77XX_WHITE);   // 文字色
  tft.println("I/O, ANALOG TEST");  // 文字表示
  tft.setTextColor(ST77XX_GREEN);   // 文字色
  tft.printf("Value1 : %.0f\n",ad_val1);      // 文字表示
  tft.printf("Volt1    : %3.2fV\n",ad_volt1);
  tft.setTextColor(ST77XX_ORANGE);            // 文字色
  tft.printf("Value2 : %.0f\n",ad_val2);      // 文字表示
  tft.printf("Volt2    : %3.2fV",ad_volt2);

  delay(300);
}

#include <Adafruit_GFX.h>    // Adafruitのグラフィックスライブラリ
#include <Adafruit_ST7789.h> // ST7789液晶ディスプレイ用のライブラリ
#include <SPI.h>             // SPI通信を行うためのライブラリ
#include <SD.h>              // SDカード操作用のライブラリ

#define TFT_CS   9  // TFT液晶のCSピン
#define TFT_DC   8  // TFT液晶のDCピン 
#define TFT_MOSI 11 // TFT液晶のMOSIピン
#define TFT_SCK  10 // TFT液晶のSCKピン
#define TFT_RST  12 // TFT液晶のRSTピン

#define SD_CS   23  // SD(TF)カードリーダのCSピン
#define SD_MISO 20  // SD(TF)カードリーダのMISOピン
#define SD_MOSI 19  // SD(TF)カードリーダのMOSIピン
#define SD_SCK  18  // SD(TF)カードリーダのSCKピン

#include <Fonts/FreeSans12pt7b.h> // Adafruit_GFXのフォント読み込み
#define SWITCH_PRESS_TIME 2000 // スイッチ2長押し時間(ms)
#define SD_FILENAME "/test.txt" // SD(TF)カードに保存するファイル名

Adafruit_ST7789 tft = Adafruit_ST7789(&SPI1, TFT_CS, TFT_DC, TFT_RST);  // TFT液晶表示用のインスタンス設定

// 変数宣言
unsigned long lastPressedTime = 0; // スイッチ2の最後に押された時間保持用
bool swState1 = false; // スイッチ1状態保持用
bool swState2 = false; // スイッチ2状態保持用

// 初期設定 -----------------------------------------
void setup(void) {
  Serial.begin(9600); // シリアル通信初期化

  // SPI0初期設定（SDカード用）
  SPI.setTX(SD_MOSI); // SD(TF)カードリーダのMOSI（GP19）
  SPI.setRX(SD_MISO); // SD(TF)カードリーダのMISO（GP20）
  SPI.setSCK(SD_SCK); // SD(TF)カードリーダのSCK（GP18）

  // SPI1初期設定（TFT液晶用）
  SPI1.setSCK(TFT_SCK);   // TFTのSCK (GP10)
  SPI1.setTX(TFT_MOSI);   // TFTのMOSI (GP11)

  // 出力端子初期設定
  pinMode(25, OUTPUT);    // TFTバックライト用端子
  digitalWrite(25, HIGH); // TFTバックライト点灯
  pinMode(2, OUTPUT);     // LED1用端子
  digitalWrite(2, LOW);   // LED1消灯
  pinMode(3, OUTPUT);     // LED2用端子
  digitalWrite(3, LOW);   // LED2消灯

  // 入力端子初期設定
  pinMode(4, INPUT_PULLUP); // スイッチ1用端子
  pinMode(5, INPUT_PULLUP); // スイッチ2用端子

  // TFT液晶の初期設定
  tft.init(135, 240);           // TFT初期化（画面サイズ指定）
  tft.fillScreen(ST77XX_BLACK); // 背景の塗りつぶし
  tft.setRotation(3);           // 画面回転
  tft.setFont(&FreeSans12pt7b); // フォント
  tft.setCursor(0, 18);         // カーソル位置
  // 初期表示画面
  tft.println("- SD STRAGE TEST -");  // メッセージ表示
  tft.drawFastHLine(0, 22, 240, ST77XX_WHITE); // 線（指定座標から平行線）
  tft.println("SW1(GP4) : SAVE");     // スイッチ1をONでデータ保存
  tft.println("SW2(GP5) : READ");     // スイッチ2をONでデータ読み出し
  tft.println("SW2 Longpress");       // スイッチ2長押しでデータ（ファイル）削除
  tft.println("                    : DELETE");

  // SDカードの初期化
  if (!SD.begin(SD_CS)) {
    Serial.println("SDカードの初期化に失敗しました");
    dispMessage("SD card not found!", ST77XX_RED);  // 液晶画面メッセージ表示関数呼び出し
    return;
  } else {
    Serial.println("SDカードが初期化されました");
  }
}

/*********************** 液晶画面メッセージ表示関数 **********************/
void dispMessage(const char* text, uint16_t collor) {
  tft.fillScreen(collor); // 背景の塗りつぶし
  tft.setCursor(0, 70);   // カーソル位置
  tft.print(text);        // メッセージ表示
}

/************************* CSVデータ書き込み関数 ************************/
void writeSdData(const char* text) {
  // SDカードのファイルを開く
  File myFile = SD.open(SD_FILENAME, FILE_WRITE);
  // データ書き込み
  if (myFile) { // ファイルが開けたら
    myFile.printf("%s : %d\n", text, millis()); // テキストとミリ秒をファイルに書き込み
    myFile.close(); // ファイルを閉じる
  } else { // ファイルが開けなければ
    Serial.println("ファイルを開けませんでした");
    dispMessage("Can't open file!", ST77XX_RED);  // 液晶画面メッセージ表示関数呼び出し
  }
  // 書き込みデータ表示
  tft.fillScreen(ST77XX_BLACK); // 背景の塗りつぶし
  tft.setCursor(0, 70); // カーソル位置
  
  tft.printf("%s : %lums\n", text, millis()); // テキストとミリ秒を画面に表示
  Serial.printf("%s : %lums\n", text, millis());  // シリアル出力
}

/********************* SDカード データ読み込み関数 ********************/
void readSdData(const char* fileName) {
  // SDカードのファイルを開く
  File myFile = SD.open(fileName);

  if (myFile) { // ファイルが開けたら
    tft.fillScreen(ST77XX_BLACK); // 背景の塗りつぶし
    tft.setCursor(0, 18);         // カーソル位置
    // データ読み込み表示
    while (myFile.available()) {  // ファイルにデータがあれば繰り返し
      char data = myFile.read();  // データを1文字づつ読み込む
      tft.print(data);            // TFT出力
      Serial.print(data);         // シリアル出力
    }
    myFile.close(); // ファイルを閉じる
  } else {  // ファイルが開けなければ
    Serial.println("ファイルが読み込めませんでした"); // シリアル出力
    dispMessage("Can't read file!", ST77XX_RED); // 液晶画面メッセージ表示関数呼び出し
  }
}
/********************* SDカード データ削除関数 ********************/
void deleteSdData(const char* fileName) {
  if (SD.exists(fileName)) {  // ファイルが存在すれば
    // ファイルを削除
    if (SD.remove(fileName)) {  // ファイル削除が成功すれば
      Serial.println("ファイルを削除しました");
    } else {  // ファイル削除に失敗したら
      Serial.println("ファイルの削除に失敗しました");
      dispMessage("Delete Failed!", ST77XX_RED);  // 液晶画面メッセージ表示関数呼び出し
    }
  } else {  // ファイルがなければ
    Serial.println("ファイルが見つかりません");
    dispMessage("file not found!", ST77XX_RED);  // 液晶画面メッセージ表示関数呼び出し
  }
}

// メイン -----------------------------------------
void loop() {
  unsigned long nowTime = millis(); // 経過時間を現在時間として取得(ms)
  // SDデータ書き込み処理
  if (digitalRead(4) == false && swState1 == false) {  // スイッチ1がONでスイッチ1状態がfalseなら
    digitalWrite(2, HIGH); // LED1点灯
    writeSdData("Time");   // 文字表示
    swState1 = true;       // スイッチ1状態をtrueへ
  }
  if (digitalRead(4) == true) {  // スイッチ1がOFFなら
    swState1 = false;      // スイッチ1状態をfalseへ
    digitalWrite(2, LOW);  // LED2消灯
    delay(50);             // スイッチOFF待ち（チャタリング防止）
  }
  // SDデータ読み込み処理
  if (digitalRead(5) == false && swState2 == false) {  // スイッチ2がONでスイッチ2状態がfalseなら
    // SDをデータ読み込んで内容を液晶画面に表示
    readSdData(SD_FILENAME);  // ファイル名を指定してSDデータ読み出し関数呼び出し
    digitalWrite(3, HIGH); // LED2点灯
    swState2 = true;       // スイッチ2状態をtrueへ
  }
  // SDデータ削除処理
  if (digitalRead(5) == false) { // スイッチ2がONなら
    if (nowTime - lastPressedTime >= SWITCH_PRESS_TIME) { // スイッチ2が2秒以上長押しなら
      lastPressedTime = nowTime; // 最後に押された時間を更新
      // SDデータ削除
      deleteSdData(SD_FILENAME);    // ファイル名を指定してSDデータ削除関数呼び出し
      dispMessage("Delete file!", ST77XX_BLUE);  // 液晶画面メッセージ表示関数呼び出し
    }
  } else {  // スイッチ2がOFFなら
    swState2 = false;     // スイッチ2状態をfalseへ
    lastPressedTime = nowTime;  // 最後に押された時間を更新
    digitalWrite(3, LOW); // LED2消灯
    delay(50);            // スイッチOFF待ち（チャタリング防止）
  }
}

#include <Adafruit_GFX.h>    // Adafruitのグラフィックスライブラリ
#include <Adafruit_ST7789.h> // ST7789液晶ディスプレイ用のライブラリ
#include <JPEGDecoder.h>     // JPEG画像デコーダー用のライブラリ
#include <SPI.h>             // SPI通信を行うためのライブラリ
#include <SD.h>              // SDカード操作用のライブラリ

#define TFT_CS   9  // TFT液晶のCSピン
#define TFT_DC   8  // TFT液晶のDCピン 
#define TFT_MOSI 11 // TFT液晶のMOSIピン
#define TFT_SCK  10 // TFT液晶のSCKピン
#define TFT_RST  12 // TFT液晶のRSTピン

#define SD_CS   23  // SD(TF)カードリーダのCSピン
#define SD_MISO 20  // SD(TF)カードリーダのMISOピン
#define SD_MOSI 19  // SD(TF)カードリーダのMOSIピン
#define SD_SCK  18  // SD(TF)カードリーダのSCKピン

#define FILENAME "/GEEK.jpg"      // JPEG画像ファイル名
#include <Fonts/FreeSans12pt7b.h> // Adafruit_GFXのフォント読み込み

Adafruit_ST7789 tft = Adafruit_ST7789(&SPI1, TFT_CS, TFT_DC, TFT_RST); // 液晶表示処理のインスタンス初期化
JPEGDecoder jpegDec;  // JPEGデコーダのインスタンス

//********************* JPEGデコード画面表示処理関数 *********************//
void jpegDraw(char* filename) {
  uint16_t *pImg;   // ピクセルデータ用のポインタ
  int x, y, bx, by; // 位置座標格納用

  // JPEGファイルをSDカードからデコード実行
  JpegDec.decodeSdFile(filename);
  uint16_t bitmap[JpegDec.width * JpegDec.height];  // デコード画像サイズを取得してビットマップデータ格納用バッファを準備

  // 液晶表示、デコード画像情報(MCU [Minimum Coded Unit]：JPEG画像データの最小処理単位、ここでは16x16ピクセル)
  tft.printf("Size : %d x %d\nMCU : %d x %d\n", JpegDec.width, JpegDec.height, JpegDec.MCUWidth, JpegDec.MCUHeight);
  delay(3000);  // 液晶画面への画像情報表示時間

  // シリアル出力、その他のデコード画像情報
  Serial.printf("Components: %d\nMCU / row: %d\nMCU / col: %d\nScan type: %d\n\n",
                JpegDec.comps,      // コンポーネント数、16ビットカラーRGB565のため1（24ビットカラーなら3）
                JpegDec.MCUSPerRow, // x方向のMCU数（240 / 16 = 15）
                JpegDec.MCUSPerCol, // y方向のMCUの数（135 / 16 = 8.4375 → 9）
                JpegDec.scanType);  // サンプリングやエンコーディング方式

  // 画像データをピクセル単位で描画
  while (JpegDec.read()) { // JPEGデータを読み込む
    pImg = JpegDec.pImage; // 現在のピクセルデータのポインタを取得

    // MCU高さ分ループ
    for (by = 0; by < JpegDec.MCUHeight; by++) {
      // MCU幅分ループ
      for (bx = 0; bx < JpegDec.MCUWidth; bx++) {

        // 現在のピクセルのx, y座標を計算
        x = JpegDec.MCUx * JpegDec.MCUWidth + bx; // x座標
        y = JpegDec.MCUy * JpegDec.MCUHeight + by; // y座標

        // ピクセルが画像範囲内にあるかチェック
        if (x < JpegDec.width && y < JpegDec.height) {
          // tft.drawPixel(x, y, pImg[0]); // 有効にすると、MCU単位で液晶画面に描画されていく
          bitmap[y * JpegDec.width + x] = pImg[0];  // 座標ごとにピクセルカラーを取得してビットマップ画像生成
        }
        // ポインタを次のピクセルデータへ進める
        pImg += JpegDec.comps; 
      }
    }
  }
  // 描画位置を指定してビットマップを描画
  tft.drawRGBBitmap(0, 0, bitmap, JpegDec.width, JpegDec.height);
}

// 初期設定 -----------------------------------------
void setup(void) {
  Serial.begin(9600); // シリアル通信初期化

  // SPI0初期設定（SDカード用）
  SPI.setTX(SD_MOSI); // SDカードリーダーのMOSI
  SPI.setRX(SD_MISO); // SDカードリーダーのMISO
  SPI.setSCK(SD_SCK); // SDカードリーダーのSCK

  // SPI1初期設定（TFT液晶用）
  SPI1.setSCK(TFT_SCK); // TFTのSCK (GP10)
  SPI1.setTX(TFT_MOSI); // TFTのMOSI (GP11)

  // 出力端子初期設定
  pinMode(25, OUTPUT);    // TFTバックライト用端子
  digitalWrite(25, HIGH); // TFTバックライト点灯

  // TFT液晶の初期設定
  tft.init(135, 240);           // TFT初期化（画面サイズ指定）
  tft.fillScreen(ST77XX_BLACK); // 背景の塗りつぶし
  tft.setRotation(3);           // 画面回転(0-3)
  tft.setTextSize(1);           // 文字サイズ
  tft.setFont(&FreeSans12pt7b); // フォント

  // SDカードの初期化
  if (!SD.begin(SD_CS)) {
    Serial.println("SDカードの初期化に失敗しました");
    return;
  } else {
    Serial.println("SDカードが初期化されました");
  }
  // SDカードからJPEG画像を開く
  File jpegFile = SD.open(FILENAME); // ファイル名を指定して開く

  // ファイルが開けたか確認
  if (!jpegFile) {  // ファイルが開けなければエラー処理
    Serial.println("JPEGファイルを開けませんでした");
    tft.fillScreen(ST77XX_RED); // 背景の塗りつぶし（赤）
    tft.setCursor(40, 70);      // カーソル位置
    tft.print("Can't open file!");      // エラー表示
    return;
  }
  // 開いたJPEG画像のデータ容量を取得
  unsigned long fileSize = jpegFile.size();

  // 処理前のJPEG画像情報表示
  tft.setCursor(0, 30); // カーソル位置
  tft.printf("%s\n%lu bytes\n", FILENAME, fileSize);  // JPEG画像ファイル名とデータ容量表示

  // JPEG画像デコード実行
  jpegDraw(FILENAME); // JPEGデコード画面表示処理関数呼び出し
  jpegFile.close();   // JPEGファイルを閉じる
}

// メイン ---------------------------------------------
void loop() {
    // メインループでは何もしない
}