Modbus 交流電力測定器PZEM-004Tの使い方

#include <M5Stack.h>
#include <ModbusMaster.h> // Modbus通信用ライブラリ
#include <M5GFX.h>        // 液晶表示用ライブラリのインクルード

M5GFX lcd;              // 直接表示のインスタンスを作成（M5GFXクラスを使ってlcdコマンドでいろいろできるようにする）
M5Canvas canvas(&lcd);  // メモリ描画領域表示（スプライト）のインスタンスを作成(必要に応じて複数作成)
ModbusMaster node1;     // ModbusMasterオブジェクトのインスタンス化

// グローバル変数宣言 *****************************************************
bool err = false;       // エラー確認用
uint16_t get_data[5];   // 取得データ格納用配列
double volt;            // 電圧（V）
double current;         // 電流値（A）
double watt;            // 電力値（W）

/******************* タイトル、単位、設定情報表示関数 *******************/
void displayHeader() {
  canvas.fillScreen(BLACK);      // 背景色（黒）
  canvas.setFont(&fonts::Font4); // フォント
  canvas.setTextSize(1);         // テキストサイズ
  canvas.setTextColor(WHITE);    // 文字色
  
  // タイトル表示
  canvas.drawFastHLine(0, 0, 320, WHITE);           // タイトルエリア境界線（上）
  canvas.fillRect(0, 1, 320, 27, (uint16_t)0x2c4a); // タイトルエリア背景
  canvas.drawFastHLine(0, 29, 320, WHITE);          // タイトルエリア境界線（下）
  canvas.setCursor(25, 5);           // 座標
  canvas.print("1PH POWER MONITOR"); // タイトル
  
   // 単位表示
  canvas.setTextSize(1.4);           // テキストサイズ
  canvas.setCursor(250, 65); canvas.print("V");  // 電圧V
  canvas.setCursor(250, 135); canvas.print("A"); // 電流A
  canvas.setCursor(245, 205); canvas.print("W"); // 電力W

  // 境界線表示
  canvas.drawFastHLine(10, 100, 300, WHITE); // 境界線1
  canvas.drawFastHLine(10, 170, 300, WHITE); // 境界線2
}

/******************* 測定データ表示関数 *******************/
void drawData() {
  canvas.setFont(&fonts::Font7); // フォント（7セグ）
  canvas.setTextSize(1.3);       // テキストサイズ

  canvas.setTextColor((uint16_t)0xaf7d);  // 電圧(V)
  canvas.setCursor(45, 35);
  canvas.printf("%05.1f", volt);

  canvas.setTextColor((uint16_t)0x07ef);  // 電流(A)
  canvas.setCursor(45, 105);
  canvas.printf(current < 10 ? "%05.3f" : "%05.2f", current); // 10より小さければ0.000、10以上なら00.00

  canvas.setTextColor((uint16_t)0xfea0);  // 電力(W)
  canvas.setCursor(45, 175);
  canvas.printf(watt < 1000 ? "%05.1f" : "%04.0f", watt); // 1000より小さければ000.0、1000以上なら0000

  canvas.pushSprite(&lcd, 0, 0); // 画面表示実行
}

/******************* データ変換関数 *******************/
void convertData() {
  volt = get_data[0] * 0.1; // 電圧 (0.1W単位)
  current = ((uint32_t)get_data[2] << 16 | get_data[1]) * 0.001;   // 電流 (0.001A単位)
  watt = ((uint32_t)get_data[4] << 16 | get_data[3]) * 0.1;        // 電力 (0.1W単位)
}

/******************* データ取得、エラーチェック関数 *******************/
void fetchModbusData() {
  err = false; // エラーフラグ初期化
  uint8_t result = node1.readInputRegisters(0x0000, 0x05); // Modbus通信実行（開始レジスタ, レジスタ数）

  if (result == node1.ku8MBSuccess) { // データ受信成功なら
      for (int i = 0; i < 5; i++) { // 受信データ5個分繰り返し
        get_data[i] = node1.getResponseBuffer(i); // 受信データバッファをget_data配列に格納
        Serial.print(get_data[i]);                // 格納データシリアル表示
        Serial.print(" ");                        // スペース
      }
      Serial.print("\n"); // 改行
  } else {                   // データ受信失敗なら
    err = true;              // エラーフラグtrue
    Serial.println("Error"); // エラー表示
  }
}

/******************* エラー画面表示関数 *******************/
void displayError() {
  canvas.fillScreen(RED);        // 背景色
  canvas.setFont(&fonts::Font4); // フォント
  canvas.setTextSize(1);         // テキストサイズ
  canvas.setTextColor(WHITE);    // 文字色
  
  // エラー表示
  canvas.setCursor(120, 100);
  canvas.print("ERROR!");        // エラー表示

  canvas.pushSprite(&lcd, 0, 0); // 画面表示実行
}

// 初期設定 *********************************************************************
void setup() {
  M5.begin();
  M5.Power.begin();

  lcd.begin();             // 画面初期化
  // メモリ描画領域の初期設定（スプライト）
  canvas.setColorDepth(8); // カラーモード設定（初期値16bit）Basic はメモリ描画領域サイズを大きく（320x173以上?）すると16bit以上で表示されないため8bit推奨
  canvas.createSprite(lcd.width(), lcd.height()); // メモリ描画領域を準備

  // シリアル通信設定
  Serial.begin(9600); // 標準のUSB通信ポート設定 3, 1 (RX, TX)
  Serial2.begin(9600, SERIAL_8N1, 16, 17); // Modbus通信ポート設定
  node1.begin(1, Serial2); // Serialポートを介してスレーブ1とMosbus通信開始 (スレーブアドレス, 通信ポート)
}

// メイン **************************************************************************
void loop() {
  M5.update();

  // 測定データ取得表示
  displayHeader();   // タイトル、単位、設定情報表示関数
  fetchModbusData(); // データ取得、エラーチェック関数
  if (err != true) {
    convertData();   // データ変換関数
    drawData();      // 測定データ表示関数
  } else {
    displayError();  // エラー表示関数
  }
  delay(500);
}

#include <M5GFX.h> // 液晶表示用ライブラリのインクルード

ModbusMaster node1; // ModbusMasterオブジェクトのインスタンス化

Serial2.begin(9600, SERIAL_8N1, 16, 17); // Modbus通信ポート設定
node1.begin(1, Serial2); // Serialポートを介してスレーブ1とMosbus通信開始 (スレーブアドレス, 通信ポート)

void fetchModbusData() {
  err = false; // エラーフラグ初期化
  uint8_t result = node1.readInputRegisters(0x0000, 0x05); // Modbus通信実行（開始レジスタ, レジスタ数）

  if (result == node1.ku8MBSuccess) { // データ受信成功なら
      for (int i = 0; i < 5; i++) { // 受信データ5個分繰り返し
        get_data[i] = node1.getResponseBuffer(i); // 受信データバッファをget_data配列に格納
        Serial.print(get_data[i]);                // 格納データシリアル表示
        Serial.print(" ");                        // スペース
      }
      Serial.print("\n"); // 改行
  } else {                   // データ受信失敗なら
    err = true;              // エラーフラグtrue
    Serial.println("Error"); // エラー表示
  }
}

void convertData() {
  volt = get_data[0] * 0.1; // 電圧 (0.1W単位)
  current = ((uint32_t)get_data[2] << 16 | get_data[1]) * 0.001;   // 電流 (0.001A単位)
  watt = ((uint32_t)get_data[4] << 16 | get_data[3]) * 0.1;        // 電力 (0.1W単位)
}

void displayError() {
  canvas.fillScreen(RED);        // 背景色
  canvas.setFont(&fonts::Font4); // フォント
  canvas.setTextSize(1);         // テキストサイズ
  canvas.setTextColor(WHITE);    // 文字色
  
  // エラー表示
  canvas.setCursor(120, 100);
  canvas.print("ERROR!");        // エラー表示

  canvas.pushSprite(&lcd, 0, 0); // 画面表示実行
}

#include <M5Stack.h>
#include <ModbusMaster.h> // Modbus通信用ライブラリ
#include <M5GFX.h>        // 液晶表示用ライブラリのインクルード

M5GFX lcd;              // 直接表示のインスタンスを作成（M5GFXクラスを使ってlcdコマンドでいろいろできるようにする）
M5Canvas canvas(&lcd);  // メモリ描画領域表示（スプライト）のインスタンスを作成(必要に応じて複数作成)
ModbusMaster node1;     // ModbusMasterオブジェクトのインスタンス化

#define ARARM_OUT 5  // 出力端子

// グローバル変数宣言 *****************************************************
bool err = false;       // エラー確認用
uint8_t result;         // 通信結果格納用
uint16_t get_data[10];  // 取得データ格納用配列
double volt;            // 電圧（V）
double current;         // 電流値（A）
double watt;            // 電力値（W）
double wattHour;        // 積算電力値（W）
float freq;             // 周波数（Hz）
uint16_t pf;            // 力率（%）
bool alarmSignal;       // アラーム出力
uint16_t alarmLevel;    // アラームレベル設定値(W)
uint16_t slaveAddress;  // スレーブアドレス
bool settingModeFlag = false;   // 設定モードフラグ

/******************* タイトル、単位、設定情報表示関数 *******************/
void displayHeader() {
  if (alarmSignal == false) { // 電力アラーム状態でなければ
    canvas.fillScreen(BLACK);      // 背景色（黒）
    digitalWrite(ARARM_OUT, HIGH); // 外部出力OFF
  } else {                    // 電力アラーム状態でなければ
    canvas.fillScreen(RED);        // 背景色（赤）
    digitalWrite(ARARM_OUT, LOW);  // 外部出力ON
  }
  canvas.setFont(&fonts::Font4); // フォント
  canvas.setTextSize(1);         // テキストサイズ
  canvas.setTextColor(WHITE);    // 文字色
  
  // タイトル表示
  canvas.drawFastHLine(0, 0, 320, WHITE);           // タイトルエリア境界線（上）
  canvas.fillRect(0, 1, 320, 27, (uint16_t)0x2c4a); // タイトルエリア背景
  canvas.drawFastHLine(0, 29, 320, WHITE);          // タイトルエリア境界線（下）
  canvas.setCursor(25, 5);           // 座標
  canvas.print("1PH POWER MONITOR"); // タイトル
  
   // 単位表示
  canvas.setCursor(135, 60);  // 座標
  canvas.print("V");          // 表示内容
  canvas.setCursor(135, 120);
  canvas.print("A");
  canvas.setCursor(135, 180);
  canvas.print("W");
  canvas.setCursor(282, 60);
  canvas.print("Hz");
  canvas.setCursor(282, 120);
  canvas.print("%");
  canvas.setCursor(282, 180);
  canvas.print("kW");

  // 境界線表示
  canvas.drawFastHLine(5, 90, 310, WHITE); // 境界線1
  canvas.drawFastHLine(5, 150, 310, WHITE); // 境界線2
  canvas.drawFastHLine(5, 210, 310, WHITE); // 境界線3

  // 設定情報表示
  canvas.setCursor(20, 215);    // 座標
  canvas.setFont(&fonts::Font2); // フォント
  canvas.printf("Slave Address : %d", slaveAddress); // スレーブアドレス
  canvas.setCursor(170, 215);
  canvas.setFont(&fonts::Font2);
  canvas.printf("Alarm Level : %dW", alarmLevel); // 電力アラームレベル設定値

}

/******************* 測定データ表示関数 *******************/
void drawData() {
  canvas.setFont(&fonts::Font7); // フォント（7セグ）
  canvas.setTextSize(0.9);       // テキストサイズ

  canvas.setTextColor((uint16_t)0xaf7d);  // 電圧(V)
  canvas.setCursor(3, 40);
  canvas.printf("%05.1f", volt);

  canvas.setTextColor((uint16_t)0x07ef);  // 電流(A)
  canvas.setCursor(3, 100);
  canvas.printf(current < 10 ? "%05.3f" : "%05.2f", current); // 10より小さければ0.000、10以上なら00.00

  canvas.setTextColor((uint16_t)0xfea0);  // 電力(W)
  canvas.setCursor(3, 160);
  canvas.printf(watt < 1000 ? "%05.1f" : "%04.0f", watt); // 1000より小さければ000.0、1000以上なら0000

  canvas.setTextColor((uint16_t)0xaf7d);  // 周波数(Hz)
  canvas.setCursor(180, 40);
  canvas.printf("%04.1f", freq);

  canvas.setTextColor((uint16_t)0x07ef);  // 力率(%)
  canvas.setCursor(200, 100);
  canvas.printf("%2d", pf);

  canvas.setTextColor((uint16_t)0xfea0);  // 積算電力量(kW)
  canvas.setCursor(180, 160);
  canvas.printf(wattHour < 100 ? "%04.1f" : "%04.0f", wattHour); // 100より小さければ00.0、100以上なら000
  
  canvas.pushSprite(&lcd, 0, 0); // 画面表示実行
}

/******************* データ変換関数 *******************/
void convertData() {
  volt = get_data[0] * 0.1; // 電圧 (0.1W単位)
  current = ((uint32_t)get_data[2] << 16 | get_data[1]) * 0.001;   // 電流 (0.001A単位)
  watt = ((uint32_t)get_data[4] << 16 | get_data[3]) * 0.1;        // 電力 (0.1W単位)
  wattHour = ((uint32_t)get_data[6] << 16 | get_data[5]) * 0.001;  // 電力量 (1kW単位)
  freq = get_data[7] * 0.1; // 周波数 (0.1W単位)
  pf = get_data[8];         // 力率
  if (get_data[9] == 0) {
    alarmSignal = false;
  } else {
    alarmSignal = true;
  }
}

/******************* データ取得、エラーチェック関数 *******************/
void fetchModbusData() {
  err = false; // エラーフラグ初期化
  result = node1.readInputRegisters(0x0000, 0x0A); // Modbus通信実行（開始レジスタ, レジスタ数）

  if (result == node1.ku8MBSuccess) { // データ受信成功なら
      for (int i = 0; i < 10; i++) { // 受信データ10個分繰り返し
        get_data[i] = node1.getResponseBuffer(i); // 受信データバッファをget_data配列に格納
        Serial.print(get_data[i]);                // 格納データシリアル表示
        Serial.print(" ");                        // スペース
      }
      Serial.print("\n"); // 改行
  } else { // 
    err = true;              // エラーフラグtrue
    Serial.println("Error"); // エラー表示
  }
}

/******************* エラー画面表示関数 *******************/
void displayError() {
  canvas.fillScreen(RED);      // 背景色
  canvas.setFont(&fonts::Font4); // フォント
  canvas.setTextSize(1);         // テキストサイズ
  canvas.setTextColor(WHITE);    // 文字色
  
  // エラー表示
  canvas.setCursor(120, 100);
  canvas.print("ERROR!"); // タイトル

  canvas.pushSprite(&lcd, 0, 0); // 画面表示実行
}

/******************* スレーブアドレス読み出し関数 *******************/
void readAddress() {
  result = node1.readHoldingRegisters(0x0002, 0x0001); // (アドレス, 読取レジスタ数n)
  slaveAddress = node1.getResponseBuffer(0); // 受信データバッファ取得
  Serial.println(slaveAddress);
}

/******************* 電力アラームレベル読み出し関数 *******************/
void readAlarmLevel() {
  result = node1.readHoldingRegisters(0x0001, 0x0001); // (アドレス, 読取レジスタ数n)
  alarmLevel = node1.getResponseBuffer(0); // 受信データバッファ取得
  Serial.println(alarmLevel);
}

/******************* アラーム電力値書き込み関数 *******************/
void writeAlarmLevel() {
  result = node1.writeSingleRegister(0x0001, alarmLevel);  // (アドレス, 書き込む値)
  readAlarmLevel(); // 電力アラームレベル読み出し関数
}

/******************* 設定モード画面表示 *******************/
void displaySettingMode() {
  canvas.fillScreen(BLACK);      // 背景色
  canvas.setFont(&fonts::Font4); // フォント
  canvas.setTextSize(1);         // テキストサイズ
  canvas.setTextColor(WHITE);    // 文字色

  // タイトル表示
  canvas.drawFastHLine(0, 0, 320, WHITE);  // タイトルエリア境界線（上）
  canvas.fillRect(0, 1, 320, 27, MAROON);  // タイトルエリア背景
  canvas.drawFastHLine(0, 29, 320, WHITE); // タイトルエリア境界線（下）
  canvas.setCursor(25, 5);           // 座標
  canvas.print("1PH POWER MONITOR"); // タイトル
  
  if (M5.BtnB.isPressed()) { // BボタンONなら
    alarmLevel = alarmLevel - 10;
  }

  if (M5.BtnC.isPressed()) { // CボタンONなら
    alarmLevel = alarmLevel + 10;
  }

  canvas.setCursor(10, 50);           // 座標
  canvas.setFont(&fonts::Font4);      // フォント
  canvas.println(" Setting Mode");    // 表示内容
  canvas.println("   AlarmPowerLevel");
  canvas.setCursor(0, 115);           // 座標
  canvas.setFont(&fonts::Font7);
  canvas.setTextSize(2);              // テキストサイズ
  canvas.printf(" %d", alarmLevel);   // 電力アラームレベル設定値
  canvas.setCursor(285, 195);
  canvas.setFont(&fonts::Font4);
  canvas.setTextSize(1);              // テキストサイズ
  canvas.print(" W");

  // 境界線表示
  canvas.drawFastHLine(5, 105, 310, WHITE); // 境界線1
  canvas.drawFastHLine(5, 220, 310, WHITE); // 境界線2

  canvas.pushSprite(&lcd, 0, 0); // 画面表示実行
}

/******************* 積算電力値リセット関数 *******************/
void resetWatt() {
  // ファンクションコード0x42は一般的なModbusプロトコル（ライブラリにも）に存在しないため直接送信
  Serial2.write(0x01); // スレーブアドレス
  Serial2.write(0x42); // ファンクションコード0x42（積算電力リセット用）
  Serial2.write(0x80); // CRC
  Serial2.write(0x11); // CRC

  delay(100); // 受信データ待ち時間(50ms以上)

  while (Serial2.available()) { // 受信データがなくなるまで繰り返し（送信データと同じものが受信される）
    uint16_t data = Serial2.read();  // データ受信
    Serial.printf("%0X", data);      // 受信データシリアル表示
    Serial.print(" ");               // スペース
  }
  Serial.print("\n"); // 改行
}

// 初期設定 *********************************************************************
void setup() {
  M5.begin();
  M5.Power.begin();

  lcd.begin();             // 画面初期化
  // メモリ描画領域の初期設定（スプライト）
  canvas.setColorDepth(8); // カラーモード設定（初期値16bit）Basic はメモリ描画領域サイズを大きく（320x173以上?）すると16bit以上で表示されないため8bit推奨
  canvas.createSprite(lcd.width(), lcd.height()); // メモリ描画領域を準備

  // シリアル通信設定
  Serial.begin(9600); // 標準のUSB通信ポート設定 3, 1 (RX, TX)
  Serial2.begin(9600, SERIAL_8N1, 16, 17); // Modbus通信ポート設定
  node1.begin(1, Serial2); // Serialポートを介してスレーブ1とMosbus通信開始 (スレーブアドレス, 通信ポート)

  // 出力設定
  pinMode(ARARM_OUT, OUTPUT);      // 出力設定
  digitalWrite(ARARM_OUT, HIGH);   // 出力初期値

  readAlarmLevel(); // 電力アラームレベル読み出し関数
  readAddress();    // スレーブアドレス読み出し関数
}

// メイン **************************************************************************
void loop() {
  M5.update();

  // 測定データ取得表示
  if (settingModeFlag == false) {
    displayHeader();   // タイトル、単位、設定情報表示関数
    fetchModbusData(); // データ取得、エラーチェック関数
    if (err != true) {
      convertData();   // データ変換関数
      drawData();      // 測定データ表示関数
    } else {
      displayError();  // エラー表示関数
    }
  } else {
    displaySettingMode(); // 設定モード画面表示
  }
  
  // 設定モード（電力アラームレベル設定）
  if (M5.BtnA.wasPressed()) { // AボタンONなら
    settingModeFlag = !settingModeFlag;
    if (settingModeFlag == true) {
      readAlarmLevel();  // 電力アラームレベル読み出し関数
    } else {
      writeAlarmLevel(); // アラーム電力値書き込み関数
    }
  }

  // 積算電力値リセット
  if (M5.BtnC.pressedFor(3000) && settingModeFlag == false) { // Cボタン3秒以上ONで設定モードでなければ
    resetWatt(); // 積算電力値リセット関数
  }

  delay(500);
}

result = node1.readInputRegisters(0x0000, 0x0A); // Modbus通信実行（開始レジスタ, レジスタ数）

void readAddress() {
  result = node1.readHoldingRegisters(0x0002, 0x0001); // (アドレス, 読取レジスタ数n)
  slaveAddress = node1.getResponseBuffer(0); // 受信データバッファ取得
  Serial.println(slaveAddress);
}

void readAlarmLevel() {
  result = node1.readHoldingRegisters(0x0001, 0x0001); // (アドレス, 読取レジスタ数n)
  alarmLevel = node1.getResponseBuffer(0); // 受信データバッファをget_data配列に格納
  Serial.println(alarmLevel);
}

void writeAlarmLevel() {
  result = node1.writeSingleRegister(0x0001, alarmLevel);  // (アドレス, 書き込む値)
  readAlarmLevel(); // 電力アラームレベル読み出し関数
}

void resetWatt() {
  // ファンクションコード0x42は一般的なModbusプロトコル（ライブラリにも）に存在しないため直接送信
  Serial2.write(0x01); // スレーブアドレス
  Serial2.write(0x42); // ファンクションコード0x42（積算電力リセット用）
  Serial2.write(0x80); // CRC
  Serial2.write(0x11); // CRC

  delay(100); // 受信データ待ち時間(50ms以上)

  while (Serial2.available()) { // 受信データがなくなるまで繰り返し（送信データと同じものが受信される）
    uint16_t data = Serial2.read();  // データ受信
    Serial.printf("%0X", data);      // 受信データシリアル表示
    Serial.print(" ");               // スペース
  }
  Serial.print("\n"); // 改行
}