AWS IoTの使い方③ Arduinoコマンドで簡単MQTT通信 遠隔操作 監視の方法

#include <PubSubClient.h>  // ① MQTT通信用ライブラリ

// ② AWS IoT 接続情報
#define DEVICE_NAME "core2_01"              // AWS IoT 登録デバイス名
#define AWS_IOT_ENDPOINT "xxxxxxxxxx.amazonaws.com" // AWSエンドポイント（接続先アドレス）
#define AWS_IOT_PORT 8883                   // AWS接続ポート番号（固定）
#define QOS 0                               // 通信品質設定（0:送信完了の確認をしない,高速）

// ③ 外部ファイル（certs.cpp）から認証情報を取得（この後詳しく紹介しています。）
extern const char *root_ca;       // ルート証明書
extern const char *certificate;   // クライアント証明書
extern const char *private_key;   // プライベートキー

// ④ インスタンス
WiFiClientSecure https_client;          // https通信用
PubSubClient mqtt_client(https_client); // MQTT通信用

// ⑤ AWS IoT初期設定関数 ******************************************
void connect_aws(){
  https_client.setCACert(root_ca);                        // ルート証明書を設定
  https_client.setCertificate(certificate);               // クライアント証明書を設定
  https_client.setPrivateKey(private_key);                // プライベートキーを設定
  mqtt_client.setServer(AWS_IOT_ENDPOINT, AWS_IOT_PORT);  // エンドポイントとポート番号設定
  mqtt_client.setCallback(subscribe);                     // サブスクライブ（受信）した時に呼び出す関数設定
  // ⑥ MQTT接続開始
  while (!mqtt_client.connected())  {                     // MQTT接続完了までループ
    delay(1000);
    if (mqtt_client.connect(DEVICE_NAME)) {               // DEVICE_NAMEに接続完了なら
      mqtt_client.subscribe("topic1", QOS);               // サブスクライブ（受信）するトピックを設定
      // mqtt_client.subscribe("topic2", QOS);            // トピックが複数ある場合は続けて設定
      delay(1000);                                        // 接続完了表示時間
    } else {                                              // 接続失敗なら
      // エラー処理
    }
  }
}

#include <ArduinoJson.h>      // ① JSONライブラリ

// ② インスタンス
StaticJsonDocument<200> doc;  // JSONファイル変換用

// ③ 変数宣言
String temp = "0";   // 温度データ文字列格納用
String hum = "0";    // 湿度データ文字列格納用

// ④ AWS IoTサブスクライブ（受信）処理関数 ************************************
void subscribe(char* topic, byte* payload, unsigned int length) {
  Serial.println(topic);                  // 受信したtopicを表示
  deserializeJson(doc, payload, length);  // 受信したjsonデータをdoc（StaticJsonDocument）に変換
  String val1 = doc["temp"];              // docのキー"temp"の値を取り出す
  String val2 = doc["hum"];               // docのキー"hum"の値を取り出す
  temp = val1;
  hum = val2;
  Serial.printf("%s, %s\n", temp, hum);
}

// ⑤ メイン *****************************************
void loop() {
  mqtt_client.loop(); // サブスクライブ（受信）するために必要
  delay(200);         // 遅延時間
}

// ① AWS IoTパブリッシュ（送信）処理関数
void publish() {
  // ② 送信データを文字列として準備
  dtostrf(s_tmp, 4, 1, temp);     // 温度データを文字列に変換（値, 文字桁数, 小数点桁数, 格納先文字配列）
  dtostrf(s_hum, 4, 1, hum);      // 湿度データを文字列に変換

  // ③ 送信データをJSON形式に変換
  char json_str[100];             // 送信するjsonデータ格納用文字列
  doc.clear();                    // JSONデータをクリア
  doc["temp"] = temp;             // 温度データをjsonデータのキーと値（バリュー）でセット
  doc["hum"] = hum;               // 温度データをjsonデータのキーと値（バリュー）でセット
  serializeJson(doc, json_str);   // doc（StaticJsonDocument）をjsonデータに変換

  // ④ トピックを指定して送信
  mqtt_client.publish("topic1", json_str); // jsonデータをトピック"topic1"に送信
  Serial.println(json_str);       // JSONデータ確認用に表示
}

// 外部ファイル（certs.cpp）から認証情報を取得
extern const char *root_ca;       // ルート証明書
extern const char *certificate;   // クライアント証明書
extern const char *private_key;   // プライベートキー

const char *root_ca = R"(-----BEGIN CERTIFICATE-----
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
-----END CERTIFICATE-----
)";

const char *certificate = R"(-----BEGIN CERTIFICATE-----
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
-----END CERTIFICATE-----
)";

const char *private_key = R"(-----BEGIN RSA PRIVATE KEY-----
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
-----END RSA PRIVATE KEY-----
)";

#include <M5Core2.h>
#include <ArduinoJson.h>      // JSONライブラリ
#include <WiFiClient.h>
#include <WiFiClientSecure.h>
#include <PubSubClient.h>     // MQTTライブラリ

#define WIFI_SSID "xxxxxxxxxxxx"            // WiFi接続SSID（自分の環境に合わせてください）
#define WIFI_PASSWORD "xxxxxxxxxxxxx"       // WiFi接続パスワード（自分の環境に合わせてください）
#define DEVICE_NAME "core2_01"              // デバイス名
#define AWS_IOT_ENDPOINT "xxxxxxxxxxxx.amazonaws.com" // AWSエンドポイント（接続先アドレス）を設定
#define AWS_IOT_PORT 8883                   // AWS接続ポート番号（固定）
#define QOS 0                               // 通信品質設定（0:送信完了の確認をしない,高速）
// 外部ファイル（certs.cpp）から認証情報を取得
extern const char *root_ca;       // ルート証明書
extern const char *certificate;   // クライアント証明書
extern const char *private_key;   // プライベートキー
// インスタンス
WiFiClientSecure https_client;          // https通信用
PubSubClient mqtt_client(https_client); // MQTT通信用
StaticJsonDocument<200> doc;            // JSONファイル変換用
// 変数宣言
String temp = "0";   // 温度データ文字列格納用
String hum = "0";    // 湿度データ文字列格納用
String press = "0";  // 気圧データ文字列格納用
// 関数 *****************************************
// 液晶タイトル表示
void lcdTitle(uint32_t color) {
  M5.Lcd.fillScreen(color); // 背景色
  M5.Lcd.setTextFont(4);    // フォント 1(8px), 2(16px), 4(26px)
                            // 6(36px数字-.:apm), 7(7セグ-.:), 8(75px数字-.:)
  M5.Lcd.drawFastHLine(0, 0, 320, WHITE);           // 指定座標から平行線
  M5.Lcd.fillRect(0, 1, 320, 27, (uint16_t)0x098a); // タイトルエリア背景
  M5.Lcd.drawFastHLine(0, 29, 320, WHITE);          // 指定座標から平行線
  M5.Lcd.setTextColor(WHITE);                       // 文字色
  M5.Lcd.drawCentreString("AWS IoT MQTT HOST", 160, 4, 4);  //　指定座標を中心に文字表示（x, y, font）
}
// WiFi接続
void connect_wifi() {
  M5.Lcd.setTextFont(4);                  // フォント設定
  M5.Lcd.println("WiFi Connecting to ");
  M5.Lcd.println(WIFI_SSID);              // SSID表示
  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);   // Wi-Fi接続開始
  while (WiFi.status() != WL_CONNECTED) { // Wi-Fi接続完了するまでループ
    M5.Lcd.print(".");
    delay(2000);
  }
  M5.Lcd.println("Connected");
  M5.Lcd.printf("IP: %s\n\n", WiFi.localIP().toString().c_str()); // IPアドレス表示
}
// AWS IoTパブリッシュ（送信）関数
void publish() {
  char json_string[100];            // 送信するjsonデータ格納用文字列
  doc.clear();
  doc[""] = "";                     // 空のjsonデータのキーと値（バリュー）
  serializeJson(doc, json_string);  // doc（StaticJsonDocument）をjsonデータに変換
  mqtt_client.publish("device/01/local", json_string); // jsonデータをトピック"device/01/local"に送信
}
// AWS IoTサブスクライブ（受信）した時のJsonを処理して表示
void subscribe(char* topic, byte* payload, unsigned int length) {
  Serial.println(topic);                  // 受信したtopicを表示
  deserializeJson(doc, payload, length);  // 受信したjsonデータをdoc（StaticJsonDocument）に変換
  String val1 = doc["temp"];              // docのキー"temp"の値を取り出す
  String val2 = doc["hum"];               // docのキー"hum"の値を取り出す
  String val3 = doc["press"];             // docのキー"press"の値を取り出す
  temp = val1;
  hum = val2;
  press = val3;
  Serial.printf("%s, %s, %s\n", temp, hum, press);
  lcdTitle(DARKCYAN); // 液晶表示タイトル表示関数（背景色渡し）
  delay(500);  
  lcdTitle(BLACK);    // 液晶表示タイトル表示関数（背景色渡し）
}
// AWS IoT初期設定関数
void connect_aws(){
  https_client.setCACert(root_ca);                        // ルート証明書を設定
  https_client.setCertificate(certificate);               // クライアント証明書を設定
  https_client.setPrivateKey(private_key);                // プライベートキーを設定
  mqtt_client.setServer(AWS_IOT_ENDPOINT, AWS_IOT_PORT);  // エンドポイントとポート番号設定
  mqtt_client.setCallback(subscribe);                     // サブスクライブ（受信）した時に呼び出す関数設定
  // MQTT接続開始
  M5.Lcd.println("MQTT Connection");
  while (!mqtt_client.connected())  {                     // MQTT接続完了までループ
    M5.Lcd.print(".");
    delay(1000);
    if (mqtt_client.connect(DEVICE_NAME)) {               // DEVICE_NAMEに接続完了なら
      M5.Lcd.println("Connected!!");
      mqtt_client.subscribe("device/host", QOS);          // サブスクライブ（受信）するトピックを設定
      // mqtt_client.subscribe("topic", QOS);             // トピックが複数ある場合は続けて設定
      delay(1000);                                        // 接続完了表示時間
    } else {                                              // 接続失敗なら
      M5.Lcd.printf("Failed!!, rc=%d\n", mqtt_client.state());
    }
  }
}
// 初期設定 *****************************************
void setup() {
  M5.begin();           // 本体初期化
  Serial.begin(9600);   // シリアル通信開始

  connect_wifi();   // Wi-Fi接続関数呼び出し
  connect_aws();    // AWS IoT初期設定関数呼び出し
  lcdTitle(BLACK);  // 液晶表示タイトル表示関数（背景色渡し）
}
// メイン *****************************************
void loop() {
  M5.update();        // ボタン状態更新
  mqtt_client.loop(); // サブスクライブ（受信）するために必要
  // 本体ボタン処理
  if (M5.BtnA.wasPressed()) {
    Serial.println("BTN_A ON!");  // 標準のシリアル出力
    lcdTitle(DARKCYAN);           // 液晶表示タイトル表示関数（背景色渡し）
    publish();                    // publish処理関数呼び出し
  }
  // 取得データ表示
  M5.Lcd.setTextFont(4);                  // フォント
  M5.Lcd.setCursor(10, 50); M5.Lcd.setTextColor(WHITE, BLACK);  // 座標指定(x, y) // 文字色、背景
  M5.Lcd.printf("Temp : %s C'", temp);    // 温度表示
  M5.Lcd.setCursor(10, 110);              // 座標指定(x, y)
  M5.Lcd.printf("Hum : %s %%", hum);      // 湿度表示
  M5.Lcd.setCursor(10, 170);              // 座標指定(x, y)
  M5.Lcd.printf("Press : %s hPa", press); // 湿度表示
  delay(200); // 遅延時間
}

#include <M5StickCPlus.h>     // ヘッダーファイル
#include <ArduinoJson.h>      // JSONライブラリ
#include <WiFiClient.h>
#include <WiFiClientSecure.h>
#include <PubSubClient.h>     // MQTTライブラリ
#include "M5_ENV.h"           // ENVⅢ用ライブラリ

// MQTT通信設定
#define WIFI_SSID "xxxxxxxxxxxx"            // WiFi接続SSID（自分の環境に合わせてください）
#define WIFI_PASSWORD "xxxxxxxxxxxxx"       // WiFi接続パスワード（自分の環境に合わせてください）
#define DEVICE_NAME "m5stickc_plus_01"      // デバイス名
#define AWS_IOT_ENDPOINT "xxxxxxxxxxx.amazonaws.com" // AWSエンドポイント（接続先アドレス）を設定
#define AWS_IOT_PORT 8883                   // AWS接続ポート番号（固定）
#define QOS 0                               // 通信品質設定（0:送信完了の確認をしない,高速）
// 外部ファイル（certs.cpp）から認証情報を取得
extern const char *root_ca;       // ルート証明書
extern const char *certificate;   // クライアント証明書
extern const char *private_key;   // プライベートキー
// インスタンス
WiFiClientSecure https_client;          // https通信用
PubSubClient mqtt_client(https_client); // MQTT通信用
StaticJsonDocument<200> doc;            // JSONファイル変換用

// 環境センサENVⅢ設定
SHT3X sht30;          // 温湿度センサ インスタンス化
QMP6988 qmp6988;      // 気圧センサ インスタンス化
float s_tmp   = 0.0;  // 温度測定データ格納用
float s_hum   = 0.0;  // 湿度測定データ格納用
float s_press = 0.0;  // 気圧測定データ格納用
// 変数宣言
char temp[20];   // 温度データ文字列格納用
char hum[20];    // 湿度データ文字列格納用
char press[20];  // 気圧データ文字列格納用
// 関数 *****************************************
// WiFi接続
void connect_wifi() {
  M5.Lcd.setTextFont(2);                  // テキストフォント指定
  M5.Lcd.println("WiFi Connecting to ");
  M5.Lcd.println(WIFI_SSID);
  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);   // Wi-Fi接続開始
  while (WiFi.status() != WL_CONNECTED) { // Wi-Fi接続完了するまでループ
    M5.Lcd.print(".");
    delay(2000);
  }
  M5.Lcd.println("Connected");
  M5.Lcd.printf("IP: %s\n\n", WiFi.localIP().toString().c_str()); // IPアドレス表示
}
// AWS IoTパブリッシュ（送信）関数
void publish() {
  dtostrf(s_tmp, 4, 1, temp);     // 温度データを文字列に変換（値, 文字桁数, 小数点桁数, 格納先文字配列）
  dtostrf(s_hum, 4, 1, hum);      // 湿度データを文字列に変換
  s_press = s_press / 100;        // PaをhPaに変換
  dtostrf(s_press, 6, 1, press);  // 気圧データを文字列に変換
  // JSONパブリッシュ処理
  char json_str[100];             // 送信するjsonデータ格納用文字列
  doc.clear();                    // JSONデータをクリア
  doc["temp"] = temp;             // 温度データをjsonデータのキーと値（バリュー）でセット
  doc["hum"] = hum;               // 温度データをjsonデータのキーと値（バリュー）でセット
  doc["press"] = press;           // 温度データをjsonデータのキーと値（バリュー）でセット
  serializeJson(doc, json_str);   // doc（StaticJsonDocument）をjsonデータに変換
  mqtt_client.publish("device/host", json_str); // jsonデータをトピック"device/01/local"に送信
  Serial.println(json_str);       // JSONデータを表示
  delay(500);
  digitalWrite(10, HIGH);         // 本体LED赤消灯
}
// AWS IoTサブスクライブ（受信）した時のJsonを処理して表示
void subscribe(char* topic, byte* payload, unsigned int length) {
  digitalWrite(10, LOW);                  // 本体LED赤点灯
  Serial.println(topic);                  // 受信したtopicを表示
  deserializeJson(doc, payload, length);  // 受信したjsonデータをdoc（StaticJsonDocument）に変換
  Serial.printf("%s\n", payload);         // 受信データを表示
  publish();  // publish処理関数呼び出し
}
// AWS IoT初期設定関数
void connect_aws(){
  https_client.setCACert(root_ca);                        // ルート証明書を設定
  https_client.setCertificate(certificate);               // クライアント証明書を設定
  https_client.setPrivateKey(private_key);                // プライベートキーを設定
  mqtt_client.setServer(AWS_IOT_ENDPOINT, AWS_IOT_PORT);  // エンドポイントとポート番号設定
  mqtt_client.setCallback(subscribe);                     // サブスクライブ（受信）した時に呼び出す関数設定

  M5.Lcd.println("MQTT Connection");
  while (!mqtt_client.connected())  {                     // MQTT接続完了までループ
    M5.Lcd.print(".");
    delay(1000);
    if (mqtt_client.connect(DEVICE_NAME)) {               // DEVICE_NAMEに接続完了なら
      M5.Lcd.println("Connected!!");
      mqtt_client.subscribe("device/01/local", QOS);      // サブスクライブ（受信）するトピックを設定
      // mqtt_client.subscribe("topic", QOS);             // トピックが複数ある場合は続けて設定
      delay(1000);                                        // 接続完了表示時間
    } else {                                              // 接続失敗なら
      M5.Lcd.printf("Failed!!, rc=%d\n", mqtt_client.state());
    }
  }
}
// 初期設定 *****************************************
void setup() {
  M5.begin();             // 本体初期化
  Serial.begin(9600);     // シリアル通信開始
  Wire.begin(32, 33);     // Wire init, adding the I2C bus.  Wire初始化, 加入i2c总线
  qmp6988.init();         // 気圧センサの初期化

  M5.Lcd.setRotation(3);  // 画面表示回転
  connect_wifi();         // Wi-Fi接続関数呼び出し
  connect_aws();          // AWS IoT初期設定関数呼び出し

  pinMode(10, OUTPUT);    //本体LED赤
  digitalWrite(10, HIGH); //本体LED初期値OFF（HIGH）

  //LCD表示
  M5.Lcd.fillScreen(BLACK);   // 背景色
  M5.Lcd.setTextFont(2);      // テキストフォント指定
  M5.Lcd.drawFastHLine(0, 0, 240, WHITE);           // 指定座標から平行線
  M5.Lcd.fillRect(0, 1, 240, 17, (uint16_t)0x098a); // タイトルエリア背景
  M5.Lcd.drawFastHLine(0, 19, 240, WHITE);          // 指定座標から平行線
  M5.Lcd.setTextColor(WHITE);                       // 文字色
  M5.Lcd.drawCentreString("AWS IoT MQTT LOCAL ENV3", 120, 2, 2);  //　指定座標を中心に文字表示（x, y, font）
}
// メイン *****************************************
void loop() {
  M5.update();        // ボタン状態更新
  mqtt_client.loop(); // サブスクライブ（受信）するために必要

  // 環境センサENVⅢ測定データ取得
  if (sht30.get() == 0) {   // 温湿度センサからデータ取得したら
    s_tmp = sht30.cTemp;    // 温度データを取得
    s_hum = sht30.humidity; // 湿度データを取得
  } else {                  // データが取得できなければ
    s_tmp = 0, s_hum = 0;   // 温湿度を0セット
  }
  s_press = qmp6988.calcPressure(); // 気圧データ取得

  // 本体ボタン処理
  if (M5.BtnA.wasPressed()) {
    digitalWrite(10, LOW);        // 本体LED赤点灯
    Serial.println("BTN_A ON!");  // 標準のシリアル出力
    publish();                    // publish処理関数呼び出し
  }
  // アナログ入出力電圧（アナログ入出力値）表示
  M5.Lcd.setTextFont(4);                        // フォント設定
  M5.Lcd.setCursor(10, 32); M5.Lcd.setTextColor(WHITE, BLACK);  // 座標指定(x, y) // 文字色、背景
  M5.Lcd.printf("Temp : %2.1f C'", s_tmp);      // 温度表示
  M5.Lcd.setCursor(10, 64);                     // 座標指定(x, y)
  M5.Lcd.printf("Hum : %2.1f %%", s_hum);       // 湿度表示
  M5.Lcd.setCursor(10, 96);                     // 座標指定(x, y)
  M5.Lcd.printf("Press : %2.1f hPa", s_press/100);  // 気圧表示
  delay(200); // 遅延時間
}