CORE S3の使い方、基本仕様、端子配列、カメラの使用方法等を詳しく紹介

M5.Power.setExtOutput(true); // trueで外部(Grove)電源出力設定、falseで入力設定
M5.Power.setUsbOutput(true); // trueでUSB電源出力設定、falseで入力設定

[env:m5stack-cores3]
platform = espressif32
board = m5stack-cores3
framework = arduino
board_build.arduino.memory_type = qio_qspi ; フラッシュメモリのタイプを指定
board_build.arduino.partitions = app3M_fat9M_16MB.csv ; フラッシュメモリのパーティション設定
lib_deps = 
	m5stack/M5CoreS3@^1.0.0
	m5stack/M5Unified@^0.1.12

#include <M5CoreS3.h>

M5Canvas canvas(&M5.Lcd); // メモリ描画領域表示（スプライト）のインスタンスを作成

// 変数宣言
int cnt = 0;    // タッチポイント数格納用
int x = 0;      // タッチx座標格納用
int y = 0;      // タッチy座標格納用
int status = 0; // タッチ状態詳細格納用

static constexpr const char* state_name[16] = {
        "none", "touch", "touch_end", "touch_begin",
        "___",  "hold",  "hold_end",  "hold_begin",
        "___",  "flick", "flick_end", "flick_begin",
        "___",  "drag",  "drag_end",  "drag_begin"};  // タッチ状態詳細リスト

// 初期設定 -----------------------------------------
void setup() {
  auto cfg = M5.config(); // 初期設定
  CoreS3.begin(cfg);

  // 画面の初期設定
  canvas.setTextColor(WHITE);         // 文字色
  // canvas.setTextDatum(middle_center); // テキストの座標基準指定
  canvas.setTextSize(1);              // テキストサイズ
  canvas.setFont(&fonts::Font4);      // フォント
  canvas.createSprite(M5.Lcd.width(), M5.Lcd.height());  // canvasサイズ（メモリ描画領域）設定（画面サイズに設定）
}

// メイン -----------------------------------------
void loop() {
  CoreS3.update(); // 本体状態更新
  canvas.fillScreen(BLACK); // 背景初期化

  // タッチ処理
  cnt = CoreS3.Touch.getCount(); // タッチポイント数を取得
  if (cnt) { // タッチが押されていれば（タッチ数が0以外なら）
    canvas.fillScreen(RED); // 背景変更
    auto t = CoreS3.Touch.getDetail(0); // タッチ部の状態を格納(ID:0)
    x = t.x;          // タッチ部のx座標を取得
    y = t.y;          // タッチ部のy座標を取得
    status = t.state; // タッチ状態を格納（番号）
  }
  canvas.setCursor(0, 0); // 座標設定(x, y)
  canvas.printf("cnt : %d , x : %3d , y : %3d\n", cnt, x, y);     // タッチ座標情報表示
  canvas.printf("state : %d , %s\n", status, state_name[status]); // タッチ状態詳細表示

  // メモリ描画領域を座標を指定して一括表示（スプライト）
  canvas.pushSprite(&M5.Lcd, 0, 0); // (10, 0)座標に一括表示実行
  delay(500); // 遅延時間（ms）※タッチ状態確認のため長めに設定
}

#include <M5CoreS3.h>
M5Canvas canvas(&M5.Lcd); // メモリ描画領域表示（スプライト）のインスタンスを作成

// 変数宣言
int lcd_w; // 画面幅格納用
int lcd_h; // 画面高さ格納用

static constexpr const char* state_name[16] = {
        "none", "touch", "touch_end", "touch_begin",
        "___",  "hold",  "hold_end",  "hold_begin",
        "___",  "flick", "flick_end", "flick_begin",
        "___",  "drag",  "drag_end",  "drag_begin"};  // タッチ状態詳細リスト

// ボタン表示用の関数
void drawButton(const char *label, int x, int y, int w, int h, bool touch, int TouchColor, int notTouchColor) {
  canvas.fillRect(x, y, w, h, touch ? TouchColor : notTouchColor); // 条件に応じた色でボタンを塗りつぶす
  canvas.drawString(label, x + w / 2, y + h / 2);                  // ボタンのラベルを中央に描画
}

// 初期設定 -----------------------------------------
void setup() {
  auto cfg = M5.config(); // 初期設定
  CoreS3.begin(cfg);

  // 画面の初期設定
  canvas.setTextColor(WHITE);         // 文字色
  canvas.setTextDatum(middle_center); // テキストの座標基準指定
  canvas.setTextSize(1);              // テキストサイズ
  canvas.setFont(&fonts::Font4);      // フォント
  lcd_w = M5.Lcd.width();             // 画面幅取得
  lcd_h = M5.Lcd.height();            // 画面高さ取得
  canvas.createSprite(lcd_w, lcd_h);  // canvasサイズ（メモリ描画領域）設定（画面サイズに設定）
}

// メイン -----------------------------------------
void loop() {
  CoreS3.update(); // 本体状態更新

  // タッチパネルのタッチエリア判定
  bool btn_A = false; // タッチボタンA状態格納用
  bool btn_B = false; // タッチボタンB状態格納用
  bool btn_C = false; // タッチボタンC状態格納用
  bool btn_D = false; // タッチボタンC状態格納用
  int w = lcd_w / 2;        // タッチエリア幅算出用
  int h = (lcd_h - 40) / 2; // タッチエリア高さ算出用
  auto t = CoreS3.Touch.getDetail(0); // タッチ部の状態を格納(ID:0)
  u_int cnt = 0, x = 0, y = 0, id = 0, state = 0; // タッチ部の情報格納用

  if (t.isPressed()) {  // タッチID0が押されていれば
    cnt = CoreS3.Touch.getCount(); // タッチ数を取得
    canvas.fillScreen(BLACK);      // 背景初期化
    canvas.setCursor(0, 8);        // 座標設定(x, y)
    canvas.setFont(&fonts::Font2); // フォント
    for (int i =0; i < cnt; i++) { // タッチ数分繰り返す
      auto t = CoreS3.Touch.getDetail(i); // タッチ状態を格納
      x = t.x;   // タッチ部のx座標を取得
      y = t.y;   // タッチ部のy座標を取得
      id = t.id; // タッチID
      state = t.state; // タッチ状態を格納（番号）

      canvas.printf("id : %d , x : %3d , y : %3d , state : %d ", id, x, y, state);  // タッチ座標情報表示
      canvas.printf("%s\n", state_name[state]); // タッチ状態詳細表示

      if ((x >= 1 && x < w) && (y >= 40 && y <= 40+w)) {         // ボタンAの範囲に触れていたら
        btn_A = true;
      }
      if ((x >= 1 && x <= w) && (y >= 40+h && y <= lcd_h)) {     // ボタンBの範囲に触れていたら
        btn_B = true;
      }
      if ((x >= w && x <= lcd_w) && (y >= 40 && y <= 40+w)) {    // ボタンCの範囲に触れていたら
        btn_C = true;
      }
      if ((x >= w && x <= lcd_w) && (y >= 40+h && y <= lcd_h)) { // ボタンDの範囲に触れていたら
        btn_D = true;
      }
    }
  }
  canvas.drawFastHLine (0, 40, 360, WHITE);  // 指定座標から水平線（x, y, 長さ, 色）
  // ボタン表示（A〜D）
  canvas.setFont(&fonts::Font4);  // フォント
  drawButton("A", 0,   40, w, h, btn_A, DARKGREY, RED);
  drawButton("B", 0, 40+h, w, h, btn_B, DARKGREY, BLUE);
  drawButton("C", w,   40, w, h, btn_C, DARKGREY, GREEN);
  drawButton("D", w, 40+h, w, h, btn_D, DARKGREY, ORANGE);

  // メモリ描画領域を座標を指定して一括表示（スプライト）
  canvas.pushSprite(&M5.Lcd, 0, 0); // (0, 0)座標に一括表示実行
  delay(50); // 遅延時間（ms）
}

#include <M5CoreS3.h>

#define ADC 1   // アナログ入力 PORT A: 2, 1 (SDA, SCL)
#define IN0 8   // Lチカ入力スイッチ PORT B: 8, 9 (I, O)
#define IN1 9
#define OUT0 18 // Lチカ出力 PORT C: 18, 17 (R, T)
#define OUT1 17
#define IN2 6   // PWM ON/OFFスイッチ PORT E: 6, 7(E1, E2) ※I2C使用不可
#define IN3 7
#define PWM0 10 // PWM出力 PORT D: 14, 10 (D1, D2)
// #define PWM1 14 // ※マイクのデータ入力用端子のため使用は非推奨

M5Canvas canvas(&M5.Lcd);  // メモリ描画領域表示（スプライト）のインスタンスを作成

// 変数宣言
float ad_val;   // アナログ入力値格納用
float v_in = 0; // アナログ入力電圧換算値
bool in_state0 = false, in_state1 = false, in_state2 = false, in_state3 = false; // 入力状態格納用
bool toggle0 = true, toggle1 = true; // トグル動作状態格納用
int count = 0;  // 電源スイッチONカウント数格納用

// 状態に応じて円を描画する関数
void drawStatusCircle(bool condition, int x, int y, int color) {
  if (condition) {
    canvas.drawCircle(x, y, 12);        // 塗り潰し無し円
  } else {
    canvas.fillCircle(x, y, 12, color); // 塗り潰し円
  }
}

// 初期設定 -----------------------------------------
void setup() {
  auto cfg = M5.config(); // 初期設定
  CoreS3.begin(cfg);

  Serial.begin(9600); // シリアル通信初期化
  delay(1000);        // シリアル通信準備待ち
  Serial.print("M5CORE S3 I/O Test"); // シリアルモニタ出力

  // 入力端子設定
  pinMode(IN0, INPUT_PULLUP); // 入力設定（プルアップ）
  pinMode(IN1, INPUT_PULLUP);
  pinMode(IN2, INPUT_PULLUP);
  pinMode(IN3, INPUT_PULLUP);

  // 出力端子設定
  pinMode(OUT0, OUTPUT);   // 出力設定
  pinMode(OUT1, OUTPUT);
  digitalWrite(OUT0, LOW); // 出力初期化（LOW）
  digitalWrite(OUT1, LOW);

  // PWM出力端子設定
  pinMode(PWM0, OUTPUT ); // PWM0出力を行う端子を出力端子として設定
  ledcSetup (1, 500, 12); // PWM0出力波形の初期設定（チャンネル、周波数、分解能bit）
  ledcAttachPin(PWM0 ,1); // チャンネルに対する出力端子を設定

  // 以下、端子14でも使用可能ですが非推奨のため無効としています。
  // pinMode(PWM1, OUTPUT ); // PWM1出力を行う端子を出力端子として設定
  // ledcSetup (2, 500, 12); // PWM1出力波形の初期設定（チャンネル、周波数、分解能bit）
  // ledcAttachPin(PWM1 ,2); // チャンネルに対する出力端子を設定

  // アナログ入力端子設定
  pinMode(ADC, ANALOG); // アナログ入力

  // 画面の初期設定
  canvas.setTextColor(WHITE);    // 文字色
  canvas.setTextSize(1);         // テキストサイズ
  canvas.createSprite(M5.Lcd.width(), M5.Lcd.height()); // canvasサイズ（メモリ描画領域）設定（画面サイズに設定）
}

// メイン -----------------------------------------
void loop() {
  CoreS3.update(); // 本体更新

  // Lチカ動作（入力ボタンON/OFFでLEDがON/OFF）
  bool input0 = digitalRead(IN0);   // 入力状態取得
  if (input0 != in_state0) {        // 入力状態に変化があれば
    in_state0 = input0;             // 入力状態を更新
    digitalWrite(OUT0, !in_state0); // 出力状態更新
  }
  bool input1 = digitalRead(IN1);   // 入力状態取得
  if (input1 != in_state1) {        // 入力状態に変化があれば
    in_state1 = input1;             // 入力状態を更新
    digitalWrite(OUT1, !in_state1); // 出力状態更新
  }

  // アナログ入力処理
  ad_val = analogRead(ADC);     // アナログ入力値を取得
  v_in = ad_val * (3.3 / 4095); // 3.3Vへ換算

  // PWM動作（入力ボタン押すごとに、出力ON/OFF切り換え）
  bool input2 = digitalRead(IN2); // 入力状態取得
  if (input2 != in_state2) {      // 入力状態に変化があれば
    in_state2 = input2;           // 入力状態を更新
    if (input2 == LOW) {          // 入力ボタンが押されていれば
      toggle0 = !toggle0;         // 出力ON/OFF切り換え
    }
  }
  if (toggle0) {          // 出力ON（true）なら
    ledcWrite(1, ad_val); // アナログ入力値をDuty比に指定してPWM出力(チャンネル, Duty比)
  } else {                // 出力OFF（false）なら
    ledcWrite(1, 0);      // PWM出力OFF
  }
  bool input3 = digitalRead(IN3); // 入力状態取得
  if (input3 != in_state3) {      // 入力状態に変化があれば
    in_state3 = input3;           // 入力状態を更新
    if (input3 == LOW) {          // 入力ボタンが押されていれば
      toggle1 = !toggle1;         // 出力ON/OFF切り換え
    }
  }
  // 以下、端子14でも使用可能ですが非推奨のため無効としています。
  // if (toggle1) {          // 出力ON（true）なら
  //   ledcWrite(2, ad_val); // アナログ入力値をDuty比に指定してPWM出力(チャンネル, Duty比)
  // } else {                // 出力OFF（false）なら
  //   ledcWrite(2, 0);      // PWM出力OFF
  // }

  // 電源ボタンON処理
  if (M5.BtnPWR.wasClicked()) { // クリックなら
    count++;                    // カウント+1
  } else if (M5.BtnPWR.wasHold()) { // 長押し（1秒以上）※6秒押しで電源OFF
    count = 0;                      // カウントリセット
  }

  // 液晶表示
  canvas.fillScreen(BLACK);   // 背景設定
  canvas.setFont(&fonts::lgfxJapanGothicP_32); // フォント
  canvas.setTextColor(WHITE); // 文字色設定(文字色, 背景)
  canvas.drawCentreString("CORE S3 I/O Test", 160, 2); // タイトル表示処理

  canvas.drawFastHLine (0, 40, 360, WHITE); // 指定座標から水平線（x, y, 長さ, 色）

  // 出力状態(円を描画)表示
  canvas.drawString("出力0:", 5, 45);          // 項目表示
  drawStatusCircle(in_state0, 130, 65, BLUE); // 円描画関数呼び出し

  canvas.drawString("出力1:", 5, 80);
  drawStatusCircle(in_state1, 130, 100, RED);

  canvas.drawString("PWM0:", 165, 45);
  drawStatusCircle(!toggle0, 290, 65, BLUE);

  canvas.drawString("PWM1:", 165, 80);
  drawStatusCircle(!toggle1, 290, 100, RED);

  canvas.drawFastHLine (0, 125, 360, WHITE); // 指定座標から水平線（x, y, 長さ, 色）

  // アナログ入力値表示
  canvas.setCursor(0, 130); // 座標設定(x, y)
  canvas.printf("AD= %4.0f, V= %4.2fv\n", ad_val, v_in); // 表示内容

  canvas.drawFastHLine (0, 170, 360, WHITE); // 指定座標から水平線（x, y, 長さ, 色）

  // 電源ボタンクリックカウント数表示
  canvas.setCursor(0, 180); // 座標設定(x, y)
  canvas.printf("電源ﾎﾞﾀﾝON回数= %d\n", count); // 表示内容

  // バッテリー容量表示
  canvas.setFont(&fonts::Font2); // フォント
  canvas.setCursor(275, 225);    // 座標設定(x, y)
  canvas.printf("%4d%%", M5.Power.getBatteryLevel()); // バッテリー容量表示（0〜100%）

  // メモリ描画領域を座標を指定して一括表示（スプライト）
  canvas.pushSprite(&M5.Lcd, 0, 0); // (0, 0)座標に一括表示実行
  delay(50);  // 遅延時間（ms）
}

#include <M5CoreS3.h>
#include <Wire.h>

#define SHT3X_ADDR 0x44 // SHT3X（温度、湿度センサ）I2C通信アドレス

M5Canvas canvas(&M5.Lcd);  // メモリ描画領域表示（スプライト）のインスタンスを作成

// 変数宣言
unsigned int data[6]; // 温度、湿度受信データ格納用
float t_degC = 0.0;   // 温度換算データ格納用
float rh_pRH = 0.0;   // 湿度換算データ格納用

// 初期設定 -----------------------------------------
void setup() {
  auto cfg = M5.config(); // 初期設定
  CoreS3.begin(cfg);

  // I2C通信設定
  Wire.begin(CoreS3.Ex_I2C.getSDA(), CoreS3.Ex_I2C.getSCL()); // PORT A の場合　SDA=2, SCL=1
  // Wire.begin(9, 8);   // PORT B の場合 SDA=9(O), SCL=8(I)
  // Wire.begin(17, 18); // PORT C の場合 SDA=17(T), SCL=18(R)
  // Wire.begin(10, 14); // PORT D の場合 SDA=10(D2), SCL=14(D1) ※端子14は非推奨ですが使えました。
                         // PORT E ではI2Cは機能しません。

  Serial.begin(9600); // シリアル通信初期化
  delay(1000);        // シリアル通信準備待ち
  Serial.print("M5CORE S3 I2C Test"); // シリアルモニタ出力

  // 画面の初期設定
  canvas.setTextColor(WHITE);    // 文字色
  canvas.setTextSize(1);         // テキストサイズ
  canvas.createSprite(M5.Lcd.width(), M5.Lcd.height()); // canvasサイズ（メモリ描画領域）設定（画面サイズに設定）
}
// メイン -----------------------------------------
void loop() {
  CoreS3.update(); // 本体更新

  // I2Cデータ送信
  Wire.beginTransmission(SHT3X_ADDR); // デバイスアドレスを指定して I2C通信開始
  Wire.write(0xFD);                // 要求コマンド送信（高精度測定を指定）
  Wire.endTransmission(true);      // 書き込み完了
  delay(10);                       // データ受信待ち（時間はSHT40のデータシートによる:0.01s）

  // I2Cデータ受信（温度、湿度それぞれ 測定データ:8bit ×2 + CRC:8bit で合計6byte）
  Wire.requestFrom(SHT3X_ADDR, 6); // 受信データリクエスト（6byte）
  for (int i = 0; i < 6; i++) {    // 6byte分繰り返し
    data[i] = Wire.read();         // 受信データ格納
  }

  // 受信データを温度、湿度に換算（SHT40のデータシートより抜粋）
  t_degC = -45 + 175 * (data[0] * 256 + data[1])/65535;
  rh_pRH = -6 + 125 * (data[3] * 256 + data[4])/65535;
  if (rh_pRH > 100) {
    rh_pRH = 100;
  }
  if (rh_pRH < 0) {
    rh_pRH = 0;
  }

  // 液晶表示処理
  canvas.fillScreen(BLACK); // 画面初期化
  canvas.setFont(&fonts::lgfxJapanGothicP_32);         // フォント
  canvas.drawCentreString("CORE S3 I2C Test", 160, 2); // タイトル表示処理

  canvas.drawFastHLine (0, 40, 360, WHITE); // 指定座標から水平線（x, y, 長さ, 色）

  // I2C通信データ表示
  canvas.setCursor(0, 45);                     // 座標設定(x, y)
  canvas.setFont(&fonts::lgfxJapanGothicP_40); // フォント
  canvas.printf(" 温度： %.1f℃\n", t_degC);     // 温度表示
  canvas.printf(" 湿度： %.1f%%\n", rh_pRH);    // 湿度表示

  // メモリ描画領域を座標を指定して一括表示（スプライト）
  canvas.pushSprite(&M5.Lcd, 0, 0); // (0, 0)座標に一括表示実行
  delay(500);  // 遅延時間（ms）
}

#include "M5CoreS3.h"

int disp_w; // 画面幅格納用
int disp_h; // 画面高さ格納用

// 初期設定 ------------------------------------------------------------------
void setup() {
  auto cfg = M5.config(); // 本体初期化
  CoreS3.begin(cfg);

  disp_w = CoreS3.Display.width();  // 画面幅取得
  disp_h = CoreS3.Display.height(); // 画面高さ取得

  CoreS3.Camera.begin(); // カメラ初期化
}

// メイン --------------------------------------------------------------------
void loop() {
  // カメラからフレームを取得して表示
  if (CoreS3.Camera.get()) {
    CoreS3.Display.pushImage(0, 0, disp_w, disp_h, (uint16_t *)CoreS3.Camera.fb->buf); // QVGA表示 (x, y, w, h, *data)
    CoreS3.Camera.free(); // 取得したフレームを解放
  }
}

#include "M5CoreS3.h"

// 変数宣言
int disp_w; // 画面幅格納用
int disp_h; // 画面高さ格納用

// 初期設定 ------------------------------------------------------------------
void setup() {
  auto cfg = M5.config(); // 本体初期化
  CoreS3.begin(cfg);

  CoreS3.Display.setTextColor(CYAN);                 // 文字色
  CoreS3.Display.setFont(&fonts::Orbitron_Light_24); // フォント
  CoreS3.Display.setTextSize(1);                     // テキストサイズ

  // 画面サイズを取得
  disp_w = CoreS3.Display.width();  // 画面幅
  disp_h = CoreS3.Display.height(); // 画面高さ

  if (!CoreS3.Camera.begin()) { // カメラの初期化に失敗したら
    CoreS3.Display.drawCentreString("Camera Init Fail", disp_w / 2, 185); // エラー表示
  }
  CoreS3.Display.drawCentreString("Camera", 80, 125); // 文字表示
  CoreS3.Display.drawCentreString("jpeg", 240, 125);
  CoreS3.Display.drawFastHLine (0, 175, 360, WHITE);  // 指定座標から水平線（x, y, 長さ, 色）
  CoreS3.Display.drawCentreString("Please touch display!", disp_w / 2, 185);
}

// メイン --------------------------------------------------------------------
void loop() {
  CoreS3.update();  // 本体状態更新
  // カメラからフレームを取得して処理
  if (CoreS3.Camera.get()) {
    if (CoreS3.Touch.getDetail(0).wasPressed()) { // 画面のタッチが検出されたら
      uint8_t *out_jpg   = NULL;  // JPEG画像データ用のポインタと長さを初期化
      size_t out_jpg_len = 0;
      frame2jpg(CoreS3.Camera.fb, 255, &out_jpg, &out_jpg_len); // カメラのフレームバッファをjpegに変換
      CoreS3.Display.drawJpg(out_jpg, out_jpg_len, 160, 0, disp_w, disp_h, 0, 0, 0.5, 0.5); // 座標を指定して半分のサイズで表示
      free(out_jpg);  // メモリ解放
    }
    // CoreS3.Display.pushImage(0, 0, disp_w, disp_h, (uint16_t *)CoreS3.Camera.fb->buf); // オリジナルサイズ（QVGA）表示
    CoreS3.Display.pushImageRotateZoom(0, 0, 0, 0, 0, 0.5, 0.5, disp_w, disp_h, (uint16_t *)CoreS3.Camera.fb->buf); // 半分サイズで表示
    CoreS3.Camera.free(); // 取得したフレームを解放
  }
}