GPSモジュールの使い方、簡単位置情報取得Arduinoコマンド(M5Stack使用)

#include <M5Stack.h>

int y;  // カーソル「y座標」格納用

void setup() {  // 初期設定
  M5.begin();                   // 本体初期化
  M5.Power.begin();             // 電源管理を初期化
  Serial.begin(9600);           // USBシリアル通信を初期化（USBポートはRX=G3, TX=G1と共有）
  Serial2.begin(9600);          // シリアル通信2（GPSユニット用）を初期化（RX=16, TX=17）
  // 液晶タイトル表示
  M5.Lcd.setTextFont(4);        // フォントを設定
  M5.Lcd.drawCentreString("GPS Data Monitor", 160, 100, 4);  // テキスト中央表示(文字列, x座標, y座標, フォント番号)
  delay(2000);                  // タイトル表示時間
  M5.Lcd.fillScreen(BLACK);     // 背景色
  M5.Lcd.setCursor(0, 0, 2);    // LCDのカーソル位置をリセット
}

void loop() { // メイン処理
  M5.update();                  // 本体ボタン状態更新
  // GPSからの受信データ表示
  if (Serial2.available()) {    // GPSシリアルでデータが利用可能かチェック
    int ch = Serial2.read();    // GPSシリアルから文字を読み取る
    Serial.write(ch);           // 読み取った文字をUSBシリアルに書き込む
    M5.Lcd.print((char)ch);     // 液晶表示器にデータ表示
  }
  // 液晶表示更新
  y = M5.Lcd.getCursorY();        // 現在のカーソルの「y座標」取得
  if (y >= M5.Lcd.height() - 1) { // カーソルが画面の最下部に達した場合
    M5.Lcd.fillScreen(BLACK);     // 背景色
    M5.Lcd.setCursor(0, 0);       // LCDのカーソル位置をリセット
  }
  // データ出力一時停止
  if (M5.BtnA.wasPressed()) {         // Aボタンを押すと一時停止
    while (!M5.BtnB.wasPressed()) {M5.update();}  // Bボタンが押されるまで待機
  }
}

#include <M5Stack.h>
#include <TinyGPSPlus.h>  // GPS制御ライブラリ

static const uint32_t GPSBaud = 9600; // GPSモジュールのボーレートを9600に設定
TinyGPSPlus gps;  // TinyGPS++クラスのインスタンスを作成して、GPSデータを処理

// シリアルポート2に接続されたGPSモジュールとの通信のために、HardwareSerialオブジェクトであるssを作成
HardwareSerial ss(2);

// このカスタムバージョンのdelay()は、GPSオブジェクトが正しく機能することを保証します。
// 指定した時間（ミリ秒）だけ待機する
static void smartDelay(unsigned long ms) {
    unsigned long start = millis(); // 現在の時間をミリ秒単位で取得
    do {
      while (ss.available()) gps.encode(ss.read()); // シリアルポートからデータが読み込まれ、GPSオブジェクトにエンコードされる間、繰り返し処理を実行
    }
    while (millis() - start < ms);  // 経過時間が指定したミリ秒数未満である場合は、繰り返し処理を続ける（指定した時間が経過するまで待機）
}
// 初期設定 ----------------------------------------------------------------------
void setup() {
  M5.begin();           // 本体初期化
  M5.Power.begin();     // 電源管理を初期化
  ss.begin(GPSBaud);    // GPS受信データ通信シリアル初期化
}
// メイン ------------------------------------------------------------------------
void loop() {
  // 液晶表示初期化
  M5.Lcd.setCursor(0, 0);           // 表示座標指定
  M5.Lcd.setTextFont(4);            // 文字サイズ指定
  M5.Lcd.setTextColor(CYAN, BLACK); // 文字色, 背景色
  M5.Lcd.drawCentreString("< TinyGPSPlus TEST >\n", 160, 0, 4); // テキスト中央表示(文字列, x座標, y座標, フォント番号)

  // GPSデータ表示
  M5.Lcd.setCursor(0, 26);          // 表示座標指定
  M5.Lcd.setTextColor(WHITE, BLACK);                            // 文字色, 背景色
  M5.Lcd.printf("Satelites : %02d\n", gps.satellites.value());  // 衛星の数を表示する
  M5.Lcd.printf("HDOP      : %d \n", gps.hdop.value());         // HDOP値（水平方向の測定の正確さ）を表示する
  M5.Lcd.setTextColor(RED, BLACK);                              // 文字色, 背景色
  M5.Lcd.printf("N : %f  \n", gps.location.lat());              // 緯度を表示する
  M5.Lcd.setTextColor(GREEN, BLACK);                            // 文字色, 背景色
  M5.Lcd.printf("E : %f  \n", gps.location.lng());              // 経度を表示する
  M5.Lcd.setTextColor(WHITE, BLACK);                            // 文字色, 背景色
  M5.Lcd.printf("Location : %.3f  \n", gps.location.age());     // GPS位置情報の更新からの経過時間を表示する
  M5.Lcd.printf("Altitude   : %.1fm  \n", gps.altitude.meters()); // 高度をメートル単位で表示する
  M5.Lcd.printf("Course    : %.1f'  \n", gps.course.deg());       // 方位角を度数法で表示する
  M5.Lcd.printf("Speed     : %.1fkm  \n", gps.speed.kmph());      // 速度をキロメートル/時単位で表示する

  smartDelay(1000); // 遅延時間（カスタムディレイ）

  // 5秒以上経過してもGPSデータが受信されない場合はワイヤリングを確認するように表示する
  if (millis() > 5000 && gps.charsProcessed() < 10)
      M5.Lcd.println(F("No GPS data received: check wiring"));
}

#include <M5Stack.h>

#define MAX_GPS_DATA_LEN 200  // GPS受信データ最大文字数
#define MAX_GPS_INFO 20       // GPS受信情報最大数

// 変数宣言
char gps_data_str[MAX_GPS_DATA_LEN] = ""; // GPS受信データ文字列格納配列
char *gps_info[MAX_GPS_INFO];             // GPS情報を格納する文字ポインタ配列

// 座標処理関数 ***********************************************************************
void getCoordinates(int num, int* degree, int* minute, int* second) {
  double coodinate = atof(gps_info[num]);                     // 受信データ文字列を浮動小数点数に変換して格納
  // 取得した座標をポインタで処理
  *degree = static_cast<int>(coodinate / 100);                // 「度」部分は整数部分を100で割った値を取得
  *minute = static_cast<int>((fmod(coodinate, 100.0)));  // 「分」部分は100で割った余りを60倍して取得
  *second = static_cast<int>((fmod(coodinate, 1.0)) * 60);    // 「秒」部分は小数点以下の部分を60倍した値を取得
}
// 方角マーカー表示関数 ****************************************************************
void drawTriangle(int x, int y, int angle) {
  // 三角形の頂点座標を計算します
  int x1 = x + cos((angle + 30) * PI / 180.0) * 20;
  int y1 = y + sin((angle + 30) * PI / 180.0) * 20;
  int x2 = x + cos((angle - 90) * PI / 180.0) * 35;
  int y2 = y + sin((angle - 90) * PI / 180.0) * 35;
  int x3 = x + cos((angle - 210) * PI / 180.0) * 20;
  int y3 = y + sin((angle - 210) * PI / 180.0) * 20;

  // 三角形を描画します
  M5.Lcd.fillTriangle(x1, y1, x2, y2, x3, y3, RED);
}

// 初期設定 --------------------------------------------------------------
void setup() {
  M5.begin();           // 本体初期化
  M5.Power.begin();     // 電源管理を初期化
  Serial.begin(9600);   // USBシリアル通信を初期化（USBポートはRX=3, TX=1と共有）
  Serial2.begin(9600);  // シリアル通信2（GPSユニット用）を初期化（RX=16, TX=17）

  // 初期画面表示
  M5.Lcd.setTextFont(4);                                  // フォント
  M5.Lcd.fillRect(0, 0, 320, 56, DARKGREEN);              // タイトル背景
  M5.Lcd.setTextColor(WHITE, DARKGREEN);                  // 文字色, 背景色
  M5.Lcd.drawCentreString("GPS Simple Test", 160, 4, 4);  // テキスト中央表示(文字列, x座標, y座標, フォント番号)
  M5.Lcd.drawCentreString("M5Stack  - RFID2 UNIT -", 160, 32, 4); // テキスト中央表示(文字列, x座標, y座標, フォント番号)
  M5.Lcd.fillRect(0, 57, 320, 2, WHITE);                  // 横線
  M5.Lcd.fillRect(0, 133, 320, 2, WHITE);                 // 横線
}
// メイン ----------------------------------------------------------------
void loop() {
  // GPS受信データ処理
  if (Serial2.available()) {  // GPSシリアルでデータが受信されたら
    int ch = Serial2.read();  // GPSシリアルから文字を読み取る
    Serial.write(ch);         // 読み取った文字をUSBシリアルに書き込む

    // GPS受信データ文字が「$」なら文字列から各情報を配列に分割して処理
    if ((char)ch == '$') {
      // GPSからの受信データ文字列をカンマで分割
      int i = 0;                                  // gps_info配列のインデックス変数
      char *token = strtok(gps_data_str, ",");    // カンマを区切り文字としてgps_data_strをトークンに分割
      while (token != NULL && i < MAX_GPS_INFO) { // トークンが存在する限りループ
        gps_info[i++] = token;                    // 現在のトークンをgps_info配列のインデックスiに代入し、iを+1
        token = strtok(NULL, ",");                // カンマを区切り文字として次のトークンを取得
      }
      // GPS受信データの識別子を指定して必要な情報を表示
      if (strcmp(gps_info[0], "$GNZDA") == 0) {         // 識別子が「GNZDA」なら
        // 年月日表示
        M5.Lcd.setCursor(0, 70);                                        // 表示座標指定
        M5.Lcd.setTextColor(DARKGREY, BLACK);                           // 文字色, 背景色
        M5.Lcd.printf("%s/%s/%s", gps_info[4], gps_info[3], gps_info[2]); // 年月日を表示
        // UTC時間から時刻表示
        double utc = atof(gps_info[1]);                                 // 受信データ文字列を浮動小数点数に変換して格納
        int hour = (int)(utc / 10000) + 9;                              // 時間を取得
        int minute = ((int)utc % 10000) / 100;                          // 分を取得
        int second = (int)utc % 100;                                    // 秒を取得
        M5.Lcd.setCursor(140, 70);                                      // 表示座標指定
        M5.Lcd.printf("%02d:%02d [%02d]\n", hour, minute, second);      // 時刻表示

      } else if (strcmp(gps_info[0], "$GNGGA") == 0) {  // 識別子が「GNGGA」なら
        // 北緯表示
        int degree, minute, second; // 座標の度分秒格納用変数
        getCoordinates(2, °ree, &minute, &second);                   // 座標処理関数を呼び出し
        M5.Lcd.setCursor(0, 100);                                       // 表示座標指定
        M5.Lcd.setTextColor(RED, BLACK);                                // 文字色, 背景色
        M5.Lcd.printf("N %02d' %02d' %02d\" ", degree, minute, second); // 北緯を表示
        // 東経表示
        getCoordinates(4, °ree, &minute, &second);                   // 座標処理関数を呼び出し
        M5.Lcd.setCursor(160, 100);                                     // 表示座標指定
        M5.Lcd.setTextColor(GREEN, BLACK);                              // 文字色, 背景色
        M5.Lcd.printf("E %03d' %02d' %02d\" ", degree, minute, second); // 東経を表示
        // 標高表示
        M5.Lcd.setCursor(0, 145);                                       // 表示座標指定
        M5.Lcd.setTextColor(WHITE, BLACK);                              // 文字色, 背景色
        M5.Lcd.printf("Elevation : %sm ", gps_info[9]);                 // 標高を表示

      } else if (strcmp(gps_info[0], "$GNVTG") == 0) {  // 識別子が「GNVTG」なら
        // 進行方向（真北からの右回り角度）
        static int angle = 360 - atoi(gps_info[1]);                     // 方向情報を整数に変換して左回り角度へ換算
        M5.Lcd.setCursor(0, 175);                                       // 表示座標指定
        M5.Lcd.printf("Direction : %d'    \n", angle);                  // 進行方向を表示
        // 方角マーカー表示クリア
        M5.Lcd.fillCircle(260, 185, 40, LIGHTGREY);                     // 方向マーカー表示円
        // 三角形を描画します
        drawTriangle(260, 185, angle);                                  // 方角マーカー表示関数呼び出し
        // 移動速度
        M5.Lcd.setCursor(0, 205);                                       // 表示座標指定
        M5.Lcd.printf("Speed :       %.1fkm\n", atof(gps_info[6]));     // 移動速度を表示
      }
      // GPS受信データ文字列リセット
      memset(gps_data_str, 0, sizeof(gps_data_str));
    }
    // GPS受信データ文字を文字列として結合
    int len = strlen(gps_data_str); // 文字列の長さを計算してlen変数に格納
    gps_data_str[len] = (char)ch;   // chをgps_data_str配列の末尾に追加
    gps_data_str[len + 1] = '\0';   // 文字列の終端にヌル文字を設定
  } 
}