M5NanoC6の使い方、初期設定、サンプルプログラムで詳しく紹介

/*
  各端子の指定はカッコ内のように指定して使用できます。
  本体青色LED：7（M5NANO_C6_BLUE_LED_PIN）
  本体ボタン：9（M5NANO_C6_BTN_PIN）※Input設定済み
  赤外線（IR）送信：3（M5NANO_C6_IR_TX_PIN）
  フルカラーLED（NeoPixel）電源：19（M5NANO_C6_RGB_LED_PWR_PIN）
  フルカラーLED（NeoPixel）信号：20（M5NANO_C6_RGB_LED_DATA_PIN）
*/

#include "M5NanoC6.h"　// ヘッダーファイルを指定

// 初期設定 ---------------------------------------------------
void setup() {
  NanoC6.begin();  // 本体初期化
  // 以下、他の初期設定
}

// メイン -----------------------------------------------------
void loop() {
  NanoC6.update();  // 本体ボタン状態更新
  
　// Arduinoのボタン関数が使用できます。
  if (NanoC6.BtnA.wasPressed()) {   // 本体ボタンが押されたら
    // 処理を記入
  }
  if (NanoC6.BtnA.wasReleased()) {  // 本体ボタンが離されたら
    // 処理を記入
  }
}

an_val = analogRead(ADC_PIN);

// 変更前（バージョン2.x）-----------------------------------------------------
pinMode(PWM_PIN, OUTPUT);                   // PWM用ピンを出力設定
ledcSetup(CHANNEL, FREQUENCY, RESOLUTION);  // PWM設定（ﾁｬﾝﾈﾙ, 周波数, 分解能）
ledcAttachPin(PWM_PIN, CHANNEL);            // PWMﾁｬﾝﾈﾙ割り当て（ピン番号, ﾁｬﾝﾈﾙ）

ledcWrite(CHANNEL, DUTY);                   // DUTY比を指定して、チャンネルに対して実行

// 変更後（バージョン3.0）-----------------------------------------------------
pinMode(PWM_PIN, OUTPUT);                   // PWM用ピンを出力設定
ledcAttach(PWM_PIN, FREQUENCY, RESOLUTION); // PWM設定（ピン番号, 周波数, 分解能）

ledcWrite(PWM_PIN, DUTY);                   // DUTY比を指定して、ピン番号に対して実行

/*
  M5NanoC6端子番号
  本体青色LED：7
  本体ボタン：9
  赤外線（IR）送信：3
  フルカラーLED（NeoPixel）電源：19
  フルカラーLED（NeoPixel）信号：20
  Groveコネクタ信号（I／O, ADC, Touch）：1, 2
*/
#include "Arduino.h"

#define BLUE_LED_PIN 7  // 青色LED端子番号
#define BTN_PIN 9       // 本体ボタン端子番号

bool old_state = true;  // 前回のボタン状態を格納

// 初期設定 ---------------------------------------------------
void setup() {
  Serial.begin(9600);  // シリアル通信初期化(ArduinoIDEの「USB CDC On Boot:」設定は"Enable"にしておく)
  // 入力設定
  pinMode(BTN_PIN, INPUT);  // 本体ボタン
  // 出力設定
  pinMode(BLUE_LED_PIN, OUTPUT); // 本体LED青
}

// メイン -----------------------------------------------------
void loop() {
  bool btn_state = digitalRead(BTN_PIN); // 現在のボタン状態を取得
  if (old_state != btn_state) {  // ボタンの状態に変化があれば
    old_state = btn_state;  // 前回のボタン状態を更新
    if (btn_state) {  // ボタンが離された（HIGH）なら
      digitalWrite(BLUE_LED_PIN, LOW);  // 本体LED消灯
      Serial.println("Button A OFF!");  // シリアル出力
    } else {          // ボタンが押された（LOW）なら
      digitalWrite(BLUE_LED_PIN, HIGH); // 本体LED点灯
      Serial.println("Button A ON!");   // シリアル出力
    }
  }
}

#include "Arduino.h"
#include <Adafruit_NeoPixel.h>  // NeoPixel（フルカラーLED）制御用

#define BTN_PIN 9           // 本体ボタン端子
#define RGB_LED_PWR_PIN 19  // NeoPixel電源端子
#define RGB_LED_DATA_PIN 20 // NeoPixel信号端子
#define NUM_LEDS 1  // NeoPixel使用数

// NeoPixel初期化
Adafruit_NeoPixel strip(NUM_LEDS, RGB_LED_DATA_PIN, NEO_GRB + NEO_KHZ800);

// 変数宣言
bool old_state = true;  // 前回のボタン状態を格納
int8_t cnt = 0;         // ボタンON回数カウント

// 初期設定 ---------------------------------------------------
void setup() {
  Serial.begin(9600);  // シリアル通信初期化(ArduinoIDEの「USB CDC On Boot:」設定は"Enable"にしておく)
  // 入力設定
  pinMode(BTN_PIN, INPUT_PULLUP);  // 本体ボタン
  // 出力設定
  pinMode(RGB_LED_PWR_PIN, OUTPUT);    // NeoPixel電源(19)
  digitalWrite(RGB_LED_PWR_PIN, HIGH); // NeoPixel電源をHigh設定

  // NeoPixel初期設定
  strip.begin();  // NeoPixel初期化
}

// メイン -----------------------------------------------------
void loop() {
  // 本体ボタン押した時だけ実行
  bool btn_state = digitalRead(BTN_PIN);  // 現在のボタン状態を取得
  if (old_state != btn_state) {  // ボタンの状態に変化があれば
    old_state = btn_state;  // 前回のボタン状態を更新
    if (!btn_state) {  // ボタンが押された（LOW）なら
      cnt++;           // ボタンON回数カウント+1
      Serial.println("Collor Change!");  // シリアル出力
    }
  }

  // NeoPixel点灯処理 (R, G, B)
  switch (cnt) {  // ボタンON回数により分岐
  case 0:
    strip.setPixelColor(0, strip.Color(100, 100, 100)); // NeoPixel色指定（白）
    break;
  case 1:
    strip.setPixelColor(0, strip.Color(255, 0, 0)); // NeoPixel色指定（赤）
    break;
  case 2:
    strip.setPixelColor(0, strip.Color(0, 255, 0)); // NeoPixel色指定（緑）
    break;
  case 3:
    strip.setPixelColor(0, strip.Color(0, 0, 255)); // NeoPixel色指定（青）
    break;
  default:
    cnt = 0; // ボタンON回数0リセット
    break;
  }
  strip.show();   // NeoPixel点灯実行
}

#include "Arduino.h"

#define BLUE_LED_PIN 7 // 青色LED端子番号
#define BTN_PIN 9      // 本体ボタン端子番号
#define LED_PIN 1      // Grove出力端子（LED）
#define SW_PIN  2      // Grove入力端子（スイッチ）

// 初期設定 ---------------------------------------------------
void setup() {
  Serial.begin(9600);  // シリアル通信初期化(ArduinoIDEの「USB CDC On Boot:」設定は"Enable"にしておく)
  // 入力設定
  pinMode(SW_PIN, INPUT_PULLUP);  // スイッチ
  // 出力設定
  pinMode(BLUE_LED_PIN, OUTPUT);    // 本体LED青
  digitalWrite(BLUE_LED_PIN, HIGH); // 本体LED点灯
  pinMode(LED_PIN, OUTPUT);         // 外部LED
}

// メイン -----------------------------------------------------
void loop() {
  if (digitalRead(SW_PIN)) {  // 外部スイッチがOFFなら
    digitalWrite(LED_PIN, LOW);    // 外部LED消灯
    Serial.println("Switch OFF!"); // シリアル出力
  } else {                    // 外部スイッチがONなら
    digitalWrite(LED_PIN, HIGH);   // 外部LED点灯
    Serial.println("Switch ON!");  // シリアル出力
  }
}

#include "Arduino.h"
#include <Adafruit_NeoPixel.h>  // NeoPixel制御用

#define BTN_PIN 9  // 本体ボタン端子
#define ADC_PIN 1  // アナログ入力端子番号
#define RGB_LED_PWR_PIN 19  // NeoPixel電源端子
#define RGB_LED_DATA_PIN 20 // NeoPixel信号端子
#define NUM_LEDS 1          // NeoPixel使用数

// NeoPixel初期化
Adafruit_NeoPixel strip(NUM_LEDS, RGB_LED_DATA_PIN, NEO_GRB + NEO_KHZ800);

// 変数宣言
float an_val;  // アナログ値（0～4095）格納用　※なぜかmV（0〜3300）で取得されるので換算して使用します・・・
float new_val; // 正しいアナログ値（0～4095）に換算用
float r,g,b;   // LED明るさ指定用（赤、緑、青）
int cnt;       // シリアル出力タイミングカウント用

// 初期設定 ---------------------------------------------------
void setup() {
  Serial.begin(9600);  // シリアル通信初期化(ArduinoIDEの「USB CDC On Boot:」設定は"Enable"にしておく)
  // 出力設定
  pinMode(RGB_LED_PWR_PIN, OUTPUT);    // NeoPixel電源(19)
  digitalWrite(RGB_LED_PWR_PIN, HIGH); // NeoPixel電源をHigh設定

  // アナログ入力設定
  pinMode(ADC_PIN, ANALOG); //アナログ入力

  // NeoPixel初期設定
  strip.begin();  // NeoPixel初期化
}

// メイン -----------------------------------------------------
void loop() {
  r = 0;  //LED赤色0リセット
  g = 0;  //LED緑色0リセット
  b = 0;  //LED青色0リセット

  // アナログ入力処理
  an_val = analogRead(ADC_PIN);     //アナログ換算値（0～4095）取得

  // なぜかmVで取得される？ため12bit値へ換算・・・
  new_val = an_val * (4095.0 / 3300.0);        // Max4095になるよう換算
  new_val = (new_val > 4095) ? 4095 : new_val; // 4095を超えるなら4095固定

  //LED色可変
  if(new_val < 1365) {   //アナログ値が1365より小さいなら赤、緑指定
    g = (new_val / 5.353);             //緑を指定（0～255へ換算）
    r = 255 - g;                      //緑が明るくなったら赤を暗く
  } else if(new_val >= 1365 && new_val < 2730) {
                //アナログ値が1365以上2730より小さいなら赤、緑指定
    b = ((new_val - 1365) / 5.353);    //青を指定（0～255へ換算）
    g = 255 - b;                      //青が明るくなったら緑を暗く
  } else if(new_val >= 2730) { //アナログ値が1365以上なら青、赤指定
    r = ((new_val -2730) / 5.353);     //赤を指定（0～255へ換算）
    b = 255 - r;                      //赤が明るくなったら青を暗く
  }
  strip.setPixelColor(0, strip.Color((int)r, (int)g, (int)b));  // NeoPixel色指定（R,G,B）
  strip.show();                                                 // NeoPixel点灯実行

  // シリアル出力表示
  if (cnt == 10) {
    Serial.printf("an_val:%4.0f, new_val:%4.0f\n", an_val, new_val);
    cnt = 0;  // カウント0リセット
  }
  cnt++;      // カウント+1
  delay(100); // 待機時間
}

#include "Arduino.h"

#define BLUE_LED_PIN 7  // 青色LED端子番号
#define BTN_PIN 9       // 本体ボタン端子番号
#define ADC_PIN 1       // アナログ入力端子番号

// 変数宣言
float an_val;  // アナログ値（0～4095）格納用　※なぜかmV（0〜3300）で取得されるので換算して使用します・・・
float new_val; // 正しいアナログ値（0～4095）に換算用
int cnt;       // シリアル出力タイミングカウント用

// 初期設定 ---------------------------------------------------
void setup() {
  Serial.begin(9600);  // シリアル通信初期化(ArduinoIDEの「USB CDC on Boot:」設定は"Enable"にしておく)
  // 入力設定
  pinMode(BTN_PIN, INPUT);  // 本体ボタン
  // PWM出力設定（チャンネル自動割付）※ESP32バージョン2.xとは指定方法が異なる
  pinMode(BLUE_LED_PIN, OUTPUT);      // 本体LED青を出力設定
  ledcAttach(BLUE_LED_PIN, 1000, 12); // PWM設定（ピン番号, 周波数, 分解能）
  // アナログ入力設定
  pinMode(ADC_PIN, ANALOG); //アナログ入力
}

// メイン -----------------------------------------------------
void loop() {
  // アナログ入力処理
  an_val = analogRead(ADC_PIN);  //アナログ換算値（0～4095）取得

  // なぜかmVで取得される？ため12bit値へ換算・・・
  new_val = an_val * (4095.0 / 3300.0);        // Max4095になるよう換算
  new_val = (new_val > 4095) ? 4095 : new_val; // 4095を超えるなら4095固定

  // シリアル出力表示
  if (cnt == 10) {
    Serial.printf("an_val:%4.0f, new_val:%4.0f\n", an_val, new_val);
    cnt = 0;  // カウント0リセット
  }
  cnt++;  // カウント+1

  // PWM出力実行（ピン番号を指定）※ESP32バージョン2.xとは指定方法が異なる
  ledcWrite(BLUE_LED_PIN, (int)new_val);  // 青色LEDの明るさをアナログ値で調整

  delay(100);  // 待機時間
}

#include "Arduino.h"
#include <U8g2lib.h>  // miniOLED制御用
#include <Wire.h>     // I2C通信制御用

#define BLUE_LED_PIN 7  // 青色LED端子番号
#define SHT3X_ADDR 0x44 // SHT3X（温度、湿度センサ）I2C通信アドレス

// OLED表示用のインスタンスを作成
U8G2_SSD1306_72X40_ER_F_HW_I2C u8g2(U8G2_R0, /* reset=*/U8X8_PIN_NONE); // MiniOLED 0.42" 72x40

// 変数宣言
float data[6]; // 温度、湿度受信データ格納用
float t_degC = 0.0;   // 温度換算データ格納用
float rh_pRH = 0.0;   // 湿度換算データ格納用
char t_str[20];       // 温度表示文字列格納用
char rh_str[20];      // 湿度表示文字列格納用

// 初期設定 ---------------------------------------------------
void setup() {
  Serial.begin(9600); // シリアル通信初期化(ArduinoIDEの「USB CDC On Boot:」設定は"Enable"にしておく)
  Wire.begin(2, 1);   // I2C通信初期化(SDA, SCL)、グローブコネクタの端子番号を指定
  u8g2.begin();       // OLED初期化

  // 出力設定
  pinMode(BLUE_LED_PIN, OUTPUT);    // 本体LED青
  digitalWrite(BLUE_LED_PIN, HIGH); // 本体LED点灯
}

// メイン -----------------------------------------------------
void loop() {
  // I2Cデータ送信
  Wire.beginTransmission(SHT3X_ADDR); // デバイスアドレスを指定して I2C通信開始
  Wire.write(0xFD);           // 要求コマンド送信（高精度測定を指定）
  Wire.endTransmission(true); // 書き込み完了
  delay(10);                  // データ受信待ち（時間はデータシートによる:0.01s）

  // I2Cデータ受信（温度、湿度それぞれ 測定データ:8bit ×2 + CRC:8bit で合計6byte）
  Wire.requestFrom(SHT3X_ADDR, 6); // 受信データリクエスト（6byte）
  for (int i = 0; i < 6; i++) {    // 6byte分繰り返し
    data[i] = Wire.read();         // 受信データ格納
  }
  // I2C受信データを温度、湿度に換算（計算方法はデータシート確認）
  t_degC = -45 + 175 * (data[0] * 256 + data[1])/65535; // 温度データ換算
  rh_pRH = -6 + 125 * (data[3] * 256 + data[4])/65535;  // 湿度データ換算

  // データをOLEDに表示するために文字列として結合
  sprintf(t_str, "T:%.1f'c", t_degC);  // 温度データ表示用文字列結合
  sprintf(rh_str, "H:%.1f%%", rh_pRH); // 湿度データ表示用文字列結合
  
  // 各データシリアル出力
  Serial.printf("%.1f, %.1f\n", t_degC, rh_pRH);

  // OLED表示
  u8g2.clearBuffer();           // OLED表示初期化
  u8g2.setFont(u8g2_font_helvR14_tr); // フォント設定
  u8g2.drawStr(2, 18, t_str);   // 温度文字列表示
  u8g2.drawStr(2, 38, rh_str);  // 湿度文字列表示
  u8g2.sendBuffer();            // OLED表示出力
  delay(1000);  // 遅延時間
}

#include "Arduino.h"
#include <WiFi.h>       // Wi-Fi接続用
#include <WebServer.h>  // サーバー設定用
#include <ESPmDNS.h>    // ドメインネームでIPアドレス取得用

#define BLUE_LED_PIN 7  // 青色LED端子番号
#define BTN_PIN 9       // 本体ボタン端子番号
#define OUT_PIN 2       // 外部出力端子番号

// 変数宣言
bool state = false; // ボタン状態保持用

// Wi-Fiローカル接続先設定
const char ssid[] = "自宅のWi-FiルーターのSSIDを設定";  // 接続先SSID
const char pass[] = "自宅のWi-Fiルーターのパスワードを設定"; // 接続先パスワード
const char mdnsName[] = "nano1";  // mDNS Name（mdnsName.localで接続可能）

// サーバー設定ポート80で接続
WebServer server(80);

// htmlメイン画面データ　※R"この中の文字列は改行は無視され連続した文字列として扱われる"
char html[] = R"(
  <!DOCTYPE html>
  <html lang="jp">
  <head>
    <meta charset="UTF-8">
    <meta name="viewport" content="width=device-width, initial-scale=1.0">
    <title>REMOTE-SWITCH</title>
    <style>
      body { display: flex; justify-content: center; height: 100vh; }
      .container { margin-top: 20px;text-align: center; }
      button { height:50px }
    </style>
  </head>
  <body>
    <div class="container">
      <h1>REMOTE-SWITCH</h1>
      <div>
        <button onclick="location.href='/get/btn_on'">　ON　</button>
        <button onclick="location.href='/get/btn_off'">　OFF　</button>
      </div>
    </div>
  </body>
  </html>
)";

/******************サーバーリクエスト時処理関数 ******************/
// ルートアクセス時の応答関数
void handleRoot() {
  server.send(200, "text/html", html);  //レスポンス200を返しhtml送信
}
// エラー（Webページが見つからない）時の応答関数
void handleNotFound() {
  server.send(404, "text/plain", "404 Not Found!");  //text送信
}
// ブラウザONボタン処理
void btnOn() {
  digitalWrite(BLUE_LED_PIN, HIGH); // 本体LED点灯
  digitalWrite(OUT_PIN, HIGH);      // 外部出力ON
  Serial.println("get:/get/btn_on");
  server.send(200, "text/html", html);  //レスポンス200を返しhtml送信
}
// ブラウザOFFボタン処理
void btnOff() {
  digitalWrite(BLUE_LED_PIN, LOW);  // 本体LED消灯
  digitalWrite(OUT_PIN, LOW);       // 外部出力OFF
  Serial.println("get:/get/btn_off");
  server.send(200, "text/html", html);  //レスポンス200を返しhtml送信
}

// 初期設定 ---------------------------------------------------
void setup() {
  Serial.begin(9600); // シリアル通信初期化(ArduinoIDEの「USB CDC On Boot:」設定は"Enable"にしておく)
  // Wi-Fi接続開始
  while (WiFi.localIP()[0] == 0) { // IPアドレスが取得されるまで繰り返し
    WiFi.begin(ssid, pass);        //ローカル Wi-Fi接続実行
    delay(3000); // 再接続待ち
  }

  // mDNS設定（mdnsName.localでアクセス）
  MDNS.begin(mdnsName);

  // 接続情報シリアル出力表示
  Serial.print("IP:");
  Serial.println(WiFi.localIP());       // IPアドレス（配列）表示
  Serial.printf("mDNS:%S\n", mdnsName); // mDNS名表示

  // サーバー設定
  server.on("/", handleRoot);         //ルートアクセス時の応答関数を設定
  server.onNotFound(handleNotFound);  //Webページが見つからない時の応答関数を設定
  server.on("/get/btn_on", btnOn);    //ボタンオン受信処理
  server.on("/get/btn_off", btnOff);  //ボタンオフ受信処理
  server.begin();                     //Webサーバー開始

  // 入力設定
  pinMode(BTN_PIN, INPUT_PULLUP);  // 本体ボタン

  // 出力設定
  pinMode(BLUE_LED_PIN, OUTPUT); // 本体LED青
  pinMode(OUT_PIN, OUTPUT);      // 外部出力
}

// メイン -----------------------------------------------------
void loop() {
  if (digitalRead(BTN_PIN) == LOW && state == false) { // 本体ボタンがON で stateがfalseなら
    digitalWrite(BLUE_LED_PIN, HIGH); // 本体LED点灯
    digitalWrite(OUT_PIN, HIGH);      // 外部出力ON
    state = true;   // stateをtrueへ
  }
  if (digitalRead(BTN_PIN) == HIGH && state == true) {  // 本体ボタンがOFFなら
    digitalWrite(BLUE_LED_PIN, LOW);  // 本体LED消灯
    digitalWrite(OUT_PIN, LOW);       // 外部出力OFF
    state = false;  // stateをfalseへ
  }
  server.handleClient();  //クライアントからのアクセス確認
  delay(100);             //遅延時間（ms）
}