M5Stack Basicの使い方、端子配列、サンプルプログラムで詳しく紹介

#include <M5Stack.h>
/*
  M5Stack Basic V2.6端子仕様
  G3／G1  ：UART0通信用（RX／TX）　※標準のシリアル通信未使用なら入力／出力使用可、書き込み時は未接続にする
  G16／G17：UART2通信用（RX／TX）　※シリアル通信2未使用ならG16は入力／出力、G17は出力のみ使用可
  G2／G5  ：入力／出力／G2のみアナログ入力可
  G25／G26：G25はスピーカー専用、G26は入力／出力／アナログ入力／アナログ出力
  G35／G36：アナログ入力（入力としても使用できるがプルアップ不可）
  G21／G22：I2C通信用 Groveコネクタと共通(SDA／SCL）　※入出力使用可だが電源ICと繋がっているため非推奨
  G23／G19／G18：SPI通信用（MOSI／MISO／SCK）　※G19のみ入出力使用可だがTF(SD)Cardと繋がっているため非推奨
  G39／G38／G37：本体ボタン（左からボタンA,B,C、内部で接続）
*/

// 端子割り付け
#define IN0 2   // 入力端子
#define OUT0 5  // 出力端子
#define ADC0 35 // アナログ入力端子
#define DAC0 26 // アナログ出力端子

// 変数宣言
float ad_val;         // アナログ入力値格納用
float da_val;         // アナログ出力値指定用
float v_in = 0;       // アナログ入力電圧換算値
float v_out = 0;      // アナログ出力電圧換算用
bool state = false;   // ボタン状態確認用
bool output0 = LOW;   // 出力状態指示用
int cnt = 0;          // 表示回数カウント用
String data = "";     // シリアル通信の受信データ格納用

// 関数 ************************************************************************
// シリアルモニタ出力処理
void serial_mon(String data) {
    M5.Lcd.fillRect(205, 52, 115, 18, WHITE);
    M5.Lcd.setTextFont(2);                // フォント
    M5.Lcd.setCursor(210, 53); M5.Lcd.setTextColor(BLACK);  // 座標指定(x, y) // 文字色、背景
    M5.Lcd.print(data);                   // 受信データ液晶表示
    Serial.println(data);                 // 受信データ標準シリアル出力
}
// 初期設定 ************************************************************************
void setup(){
  M5.begin();                 // 本体初期化(LCD, SD, Serial, I2C)
  M5.Power.begin();           // 電源初期化
  Serial.begin(9600);         // 標準のシリアル通信初期化（初期値はG3（RX）,G1（TX））
  Serial2.begin(9600);        // シリアル通信2初期化 (初期値は G16（RX）, G17（TX）)

  // 入出力ピン設定
  // 入力設定
  pinMode(IN0, INPUT_PULLUP); // 入力設定（プルアップ）
  // 出力設定
  pinMode(OUT0, OUTPUT);      // 出力設定
  digitalWrite(OUT0, LOW);    // 出力初期値
  // アナログ入力設定
  pinMode(ADC0, ANALOG);      // アナログ入力
  // アナログ出力設定
  pinMode(DAC0, OUTPUT);      // 出力端子に設定
  dacWrite(DAC0, 0);          // 初期値0設定
  
  //LCD表示
  M5.Lcd.fillScreen(BLACK); // 背景色
  M5.Lcd.setTextSize(1);    // 文字サイズ（整数倍率）
  M5.Lcd.setTextFont(4);    // フォント 1(8px), 2(16px), 4(26px)
                                    // 6(36px数字-.:apm), 7(7セグ-.:), 8(75px数字-.:)

  M5.Lcd.drawFastHLine(0, 0, 320, WHITE);           // 指定座標から平行線
  M5.Lcd.fillRect(0, 1, 320, 27, (uint16_t)0x098a); // タイトルエリア背景
  M5.Lcd.drawFastHLine(0, 29, 320, WHITE);          // 指定座標から平行線
  M5.Lcd.setTextColor(WHITE);                       // 文字色
  M5.Lcd.drawCentreString("M5Stack Basic V2.6 TEST", 160, 4, 4);  //　指定座標を中心に文字表示（x, y, font）

  M5.Lcd.drawFastVLine(202, 29, 43, WHITE);   // 指定座標から垂直線（x, y, l, 色）
  M5.Lcd.drawFastHLine(0, 72, 320, WHITE);    // 指定座標から平行線（x, y, l, 色）
  M5.Lcd.drawFastHLine(0, 132, 320, WHITE);
  M5.Lcd.drawFastHLine(0, 192, 320, WHITE);
  M5.Lcd.drawCircle(10, 51, 9, WHITE);        // 指定座標で半径を指定して円描画（x, y, r, 色）

  M5.Lcd.setTextFont(2);                      // フォント
  M5.Lcd.setCursor(212, 34);    M5.Lcd.print("SERIAL MONITOR");   // シリアルモニタ項目表示
  M5.Lcd.fillRect(205, 52, 115, 18, WHITE);   // 塗りつぶし四角

  //本体ボタン項目表示
  M5.Lcd.drawRect(37, 216, 66, 23, WHITE);    // 本体ボタン表示枠用四角
  M5.Lcd.drawRect(127, 216, 66, 23, WHITE);
  M5.Lcd.drawRect(217, 216, 66, 23, WHITE);

  M5.Lcd.setTextFont(2);                                // フォント
  M5.Lcd.setCursor(55, 221);    M5.Lcd.print("V_UP");   // アナログ出力電圧アップボタン
  M5.Lcd.setCursor(135, 221);   M5.Lcd.print("V_DOWN"); // アナログ出力電圧ダウンボタン
  M5.Lcd.setCursor(225, 221);   M5.Lcd.print("ON/OFF"); // ON/OFFボタン
}

// メイン処理 ************************************************************************
void loop() {
  M5.update();  // ボタン状態更新

  // 本体ボタン、外部ボタン入力処理
  // ボタンA または 外部スイッチ赤が押されている かつ アナログ出力255より小さいなら
  if (M5.BtnA.isPressed() && da_val < 255) {
    Serial.println("V_UP!");    // 標準のシリアル出力
    Serial2.println("V_UP!");   // シリアル2出力
    da_val++;                   // アナログ出力 +1
  }
  // ボタンB または 外部スイッチ青が押されてる かつ アナログ出力0より大きいなら
  if (M5.BtnB.isPressed() && da_val > 0) {
    Serial.println("V_DOWN!");  // 標準のシリアル出力
    Serial2.println("V_DOWN!"); // シリアル2出力
    da_val--;                   // アナログ出力 -1
  }
  // ボタンCを押すか外部入力がONするごとに出力をON／OFF
  // ボタンCまたは外部入力がONでstateがfalseなら
  if ((M5.BtnC.isPressed() == true || digitalRead(IN0) == LOW) && state == false) {
    state = true;                 // ボタン状態stateをtrue
    output0 = !output0;           // 出力指示値反転
    digitalWrite(OUT0, output0);  // 外部出力実行
    if (output0 == HIGH) {        // 出力指示値がHIGHならON出力
      Serial.println("ON!");      // 標準のシリアル出力
      Serial2.println("ON!");     // シリアル2出力
    } else {                      // 出力指示値がHIGHでなければOFF出力
      Serial.println("OFF!");     // 標準のシリアル出力
      Serial2.println("OFF!");    // シリアル2出力
    }
  }
  if (M5.BtnC.isReleased() == true && digitalRead(IN0) == HIGH) { // ボタンCと外部入力がOFFなら
    state = false;                // ボタン状態stateをfalse
  }

  // 液晶表示上のシリアルモニタ表示処理
  if (Serial.available()) {               // 標準のシリアルデータ受信で
    data = Serial.readStringUntil('\n');  // 区切り文字「LF」の手前までデータ取得
    serial_mon(data);                     // シリアルモニタ出力処理関数呼び出し
  }
  if (Serial2.available()) {              // シリアル2のデータ受信で
    data = Serial2.readStringUntil('\n'); // 区切り文字「LF」の手前までデータ取得
    serial_mon(data);                     //  シリアルモニタ出力処理関数呼び出し
  }

  // アナログ入出力、電圧換算処理
  // アナログ入力処理
  ad_val = analogRead(ADC0);    // アナログ入力値を取得(0〜4095、12bit)
  v_in = ad_val * (3.3 / 4095); // 3.3Vへ換算
  // アナログ出力処理
  dacWrite(DAC0, da_val);       // アナログ出力実行(0〜255、8bit)
  v_out = da_val * (3.3 / 255); // 3.3Vへ換算

  // LCD表示処理
  // ON／OFFボタン出力状態表示
  M5.Lcd.setTextFont(4);                  // フォント
  M5.Lcd.setCursor(26, 42);               // 座標指定(x, y)
  if (output0 == LOW) {
    M5.Lcd.setTextColor(CYAN, BLACK);     // (文字色, 背景)
    M5.Lcd.printf("OUTPUT : OFF");        //　出力端子の状態表示
    M5.Lcd.fillCircle(10, 51, 8, BLACK);  //　指定座標に半径を指定して塗り潰し円描画（x, y, r, 色）
  } else {
    M5.Lcd.setTextColor(ORANGE, BLACK);   // (文字色, 背景)
    M5.Lcd.printf("OUTPUT : ON   ");      //　出力端子の状態表示
    M5.Lcd.fillCircle(10, 51, 8, ORANGE); //　指定座標に半径を指定して塗り潰し円描画（x, y, r, 色）
  }

  // アナログ入出力電圧（アナログ入出力値）表示
  M5.Lcd.setTextFont(4);                  // フォント
  M5.Lcd.setCursor(5, 105); M5.Lcd.setTextColor(WHITE, BLACK);  // 座標指定(x, y) // 文字色、背景
  M5.Lcd.printf("ADC : ");                // アナログ入力項目表示
  M5.Lcd.setCursor(5, 165);               // 座標指定(x, y)
  M5.Lcd.printf("DAC : ");                // アナログ出力項目表示

  M5.Lcd.setTextFont(7);                  // フォント
  M5.Lcd.setCursor(85, 80); M5.Lcd.setTextColor(WHITE, BLACK);  // 座標指定(x, y) // 文字色、背景
  M5.Lcd.printf("%01.2fv", v_in);         // アナログ入力電圧表示
  M5.Lcd.setCursor(85, 140);              // 座標指定(x, y)
  M5.Lcd.printf("%01.2fv", v_out);        // アナログ出力電圧表示

  M5.Lcd.setTextFont(4);                  // フォント
  M5.Lcd.setCursor(200, 105); M5.Lcd.setTextColor(WHITE, BLACK);// 座標指定(x, y) // 文字色、背景
  M5.Lcd.printf("V  ( %04.0f )", ad_val); // アナログ入力値表示
  M5.Lcd.setCursor(200, 165);             // 座標指定(x, y)
  M5.Lcd.printf("V  ( %04.0f )", da_val); // アナログ出力値表示

  // バッテリー残量表示（表示更新10回に1回）
  if (cnt == 10) {                        // サンプリング
    M5.Lcd.setTextFont(1);                // フォント
    M5.Lcd.setCursor(295, 228); M5.Lcd.setTextColor(DARKGREY, BLACK); // 座標指定(x, y) // 文字色、背景
    M5.Lcd.printf("%d%%", M5.Power.getBatteryLevel());  // バッテリー残量表示
    cnt = 0;                              // サンプリング回数0リセット
  }
  cnt++;      // 表示回数カウント +1
  delay(100); // 遅延時間
}

// 変数宣言
String data = "";       // 受信データ格納用

// 初期設定 -----------------------------------------------
void setup() {
  M5.begin();           // 本体初期化
  // 使用するシリアル通信ごとに通信速度を指定して初期化
  Serial.begin(9600);   // 標準のシリアル通信初期化（初期値はG3（RX）,G1（TX））
  Serial2.begin(9600);  // シリアル通信2初期化 (初期値は G16（RX）, G17（TX）)
}
// メイン -------------------------------------------------
void loop() {
  // データ受信時処理
  if (Serial.available()) {                // シリアルデータ受信で
    data = SerialBT.readStringUntil('\n'); // 改行の手前までデータ取得
    Serial.print(data);                    // 受信データ送信
  }
  delay(100);  // 0.1秒ごとに実行
}