非接触ICカード(RFID)のデータ読み書き方法(Arduinoコマンド使用)

#include <M5Stack.h>
#include <MFRC522_I2C.h>

MFRC522_I2C mfrc522(0x28, 2, &Wire); // デバイスアドレスとリセット端子番号、TwoWireインスタンスを指定してインスタンス化（&Wire省略可）

// 変数宣言
byte read_data[16] = {};  // 読込みデータ格納用配列
byte write_data[16] = {}; // 書込みデータ格納用配列
int sector_num = 0;       // セクター番号格納用
int block_num = 0;        // ブロック番号格納用

// 関数 --------------------------------------------------------
// 全データ読み込みシリアルモニタ表示 ------------------------------------------
void readAllData() {
  byte piccType = mfrc522.PICC_GetType(mfrc522.uid.sak); // SAK（NFCタグの識別子）を取得し、変数に格納
  // カードタイプ確認
  if (piccType == MFRC522_I2C::PICC_TYPE_MIFARE_MINI ||
      piccType == MFRC522_I2C::PICC_TYPE_MIFARE_1K ||
      piccType == MFRC522_I2C::PICC_TYPE_MIFARE_4K) {
    mfrc522.PICC_DumpToSerial(&(mfrc522.uid));          // Mifare Classicのデータを出力
  } else if (piccType == MFRC522_I2C::PICC_TYPE_MIFARE_UL) {
    mfrc522.PICC_DumpMifareUltralightToSerial();        // Mifare Ultralightのデータを出力
  } else {
    M5.Lcd.setTextColor(RED, BLACK);
    M5.Lcd.fillRect(0, 57, 320, 200, BLACK);            // 液晶のデータ表示部を黒塗りリセット
    M5.Lcd.setCursor(0, 57);                            // 座標表示
    M5.Lcd.println("This card is not supported.");      // サポートされていないカードである旨を表示
    delay(5000);
  }
  mfrc522.PICC_HaltA(); // 現在読み込んでいるカードをハルトする
  mfrc522.PCD_Init();   // RFIDリーダーを初期化する
}
// ブロックデータ読み込み ------------------------------------------
void readData(int sector, int block) {  // (セクター番号, ブロック番号)
  MFRC522_I2C::MIFARE_Key key = {0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF}; // MIFARE_Key構造体でセクター認証キーを準備（ポインタで指定するため）
  Serial.println("カードデータ読み取り");

  uint8_t address = sector * 4 + block;         // ブロックアドレスを算出
  // 読込み対象のセクターを認証する(認証キータイプ, ブロックアドレス, 認証キーポインタ, カードのUIDプロパティへのポインタ)
  if (mfrc522.PCD_Authenticate(MFRC522_I2C::PICC_CMD_MF_AUTH_KEY_A, address, &key, &(mfrc522.uid)) == MFRC522_I2C::STATUS_OK) {
    Serial.println("認証に成功しました");
    byte buffer[18];                            // 読込みデータ16byte + エラーチェック用CRC用2byte分の配列を準備
    byte bufferSize = sizeof(buffer);           // バッファサイズをポインタで指定できるように準備
    // 認証成功で読込み実行(ブロックアドレス, データ格納バッファ配列ポインタ, 読込みデータバッファサイズポインタ)
    if (mfrc522.MIFARE_Read(address, buffer, &bufferSize) == MFRC522_I2C::STATUS_OK) { // 通信成功なら
      for (int i = 0; i < bufferSize-2; i++) {  // 読込んだデータのCRCを除いた16byte分繰り返す
        read_data[i] = buffer[i];               // バッファを読み込みデータ配列に格納
        Serial.printf("%02X ", read_data[i]);   // 16byteの読み込みデータをシリアルモニタに出力
      }
      Serial.printf("\n%s\n", read_data);
    }
  } else {
    Serial.println("認証に失敗しました");
  }
  mfrc522.PCD_StopCrypto1();  // 認証済み解除
}
// ブロックデータ書込み -------------------------------------------
void writeData(int sector, int block) { // (セクター番号, ブロック番号)
  MFRC522_I2C::MIFARE_Key key = {0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF}; // MIFARE_Key構造体でセクターキーを準備（ポインタで指定するため）
  Serial.println("カードデータ書込み");

  uint8_t address = sector * 4 + block;         // ブロックアドレスを算出
  // 書込み対象のセクターを認証する(認証キータイプ, ブロックアドレス, 認証キーポインタ, カードのUIDプロパティへのポインタ)
  if (mfrc522.PCD_Authenticate(MFRC522_I2C::PICC_CMD_MF_AUTH_KEY_A, address, &key, &(mfrc522.uid)) == MFRC522_I2C::STATUS_OK) {  // 通信成功なら
    Serial.println("認証に成功しました");
    if (address == 0 || block == 3) {                 // ブロックアドレスが0またはブロック3なら書込まず終了
        Serial.print("データブロックではないので書き込めません");
    } else {                                          // ブロック0〜2ならデータ書込み
      mfrc522.MIFARE_Write(address, write_data, 16);  // (ブロックアドレス, 書込みデータ, 書込みbyte数)
      // 書き込みデータをシリアルモニタに出力
      for (int i = 0; i < 16; i++) {            // 16byte分繰り返す
        Serial.printf("%02X ", write_data[i]);  // 16進数で出力
      }
    }
    Serial.printf("\n%s\n", write_data);
  } else {
    Serial.println("認証に失敗しました");
  }
  // カードから切断する
  mfrc522.PCD_StopCrypto1();  // 認証済み解除
}

// 初期設定 ------------------------------------------------------
void setup() {
  M5.begin();           // 本体初期化
  M5.Power.begin();     // 電源初期化
  Serial.begin(9600);   // シリアル通信初期化(USBと共用、初期値は RX=G3, TX=G1)
  Wire.begin();         // I2C通信初期化
  mfrc522.PCD_Init();   // RFID2（MFRC522）初期化

  // 初期画面表示
  M5.Lcd.setTextFont(4);                          // フォント
  M5.Lcd.println("RFID2  Card  Reader / Writer"); // タイトル表示
  M5.Lcd.println("Please put the card");
  M5.Lcd.fillRect(0, 51, 320, 2, WHITE);          // 横線
}
// メイン ------------------------------------------------------
void loop() {
  // 新しいカードが読み込まれない、または、カードのシリアル番号が読み取れないならループ
  while (!mfrc522.PICC_IsNewCardPresent() || !mfrc522.PICC_ReadCardSerial()) {
    delay(100); // 待機時間
  }
  // カードが読み取られたら以下を実行

  M5.update();  // 本体ボタン初期化
  // AボタンONでセクター番号＋1（0〜15）
  if (M5.BtnA.wasPressed()) {
    sector_num = (sector_num + 1) % 16; // 16なら0リセット
  }
  // BボタンONでブロック番号＋1（0〜2）
  if (M5.BtnB.wasPressed()) {
    block_num = (block_num + 1) % 3;    // 3なら0リセット
  }
  // CボタンONでブロックデータ読込み
  if (M5.BtnC.wasPressed()) {
    readData(sector_num, block_num);    // データ読込み関数(セクター番号, ブロック番号)
  }
  // Cボタン長押しで全データ読込みシリアルモニタ表示関数呼び出し
  if (M5.BtnC.pressedFor(1000)) {
    readAllData();                      // シリアルモニタ表示関数
  }

  // シリアルモニタから書込みデータを設定
  if (Serial.available()) {             // 受信データがあれば
    int bytesRead = Serial.available(); // 受信データバイト数を取得
    if (bytesRead <= 16) {              // 16byte以下なら
      for (int i = 0; i < 16; i++) {    // 書込みデータ配列を0で初期化
        write_data[i] = 0x00;
      }
      // 受信データを書込みデータ配列に格納
      for (int i = 0; i < bytesRead; i++) {
        write_data[i] = Serial.read();
      }
      Serial.printf("%s\n", write_data);
      writeData(sector_num, block_num); // データ書込み関数(セクター番号, ブロック番号)
    } else {
      Serial.println("文字数が16文字を超えています");
      while (Serial.available()) {      // 16byte以上のデータは破棄
        Serial.read();
      }
    }
  }

  // 液晶表示
  // カードデータ表示
  M5.Lcd.fillRect(0, 57, 320, 200, BLACK);  // 液晶のデータ表示部を黒塗りリセット
  M5.Lcd.setCursor(0, 57);                  // 座標表示
  // UID表示
  String uidString = "";                                  // UIDシリアル
  char byte_string[3];                                    // 1byteの16進数表示を格納する文字配列を準備
  for (byte i = 0; i < mfrc522.uid.size; i++) {           // 取得したbyte数分繰り返す
    sprintf(byte_string, "%02X", mfrc522.uid.uidByte[i]); // 2桁で大文字の16進数として文字配列に格納
    uidString += String(byte_string) + " ";               // String型でスペース区切りで連結
  }
  M5.Lcd.setTextColor(CYAN, BLACK);
  M5.Lcd.printf("UID : %s\n", uidString.c_str());         // Cスタイルの文字列に変換して表示
  // Mifareカード(タグ)タイプ表示
  byte piccType = mfrc522.PICC_GetType(mfrc522.uid.sak);  // SAK（Select Acknowledge:NFCタグの識別子）を取得し、変数に格納
  M5.Lcd.setTextColor(WHITE, BLACK);                      // 文字色
  M5.Lcd.print("TYPE No. ");
  M5.Lcd.println(piccType);                               // SAKを表示
  M5.Lcd.print("TYPE Name : ");
  M5.Lcd.println(mfrc522.PICC_GetTypeName(piccType));     // SAKを基にタイプ名を表示
  // 書込みデータ、読み込みデータ確認表示
  M5.Lcd.setTextColor(GREEN, BLACK);
  M5.Lcd.printf("Sector : %d/Block : %d/Add : %d\n", sector_num, block_num, sector_num * 4 + block_num);  // ブロック情報
  M5.Lcd.printf("Write : %s\n", write_data);  // 書込みデータ
  M5.Lcd.setTextColor(ORANGE, BLACK);
  M5.Lcd.printf("Read : %s\n", read_data);    // 読み込みデータ
  
  delay(100); // 遅延時間
}

#include <M5Stack.h>
#include <MFRC522_I2C.h>

// デバイスアドレスとリセット端子番号、TwoWireインスタンスを指定してインスタンス化（&Wire省略可）
MFRC522_I2C mfrc522(0x28, 2, &Wire);

// 初期設定 ------------------------------------------------------
void setup() {
  M5.begin();           // 本体初期化
  M5.Power.begin();     // 電源初期化
  Serial.begin(9600);   // シリアル通信初期化(USBと共用、初期値は RX=G3, TX=G1)
  Wire.begin();         // I2C通信初期化
  mfrc522.PCD_Init();   // RFID2（MFRC522）初期化
}

// メイン ------------------------------------------------------
void loop() {
  // 新しいカードが読み込まれない、または、カードのシリアル番号が読み取れないならループ
  while (!mfrc522.PICC_IsNewCardPresent() || !mfrc522.PICC_ReadCardSerial()) {
    delay(100); // 待機時間
  }
  // カードが読み取られたら以下を実行

// 全データ読み込みシリアルモニタ表示 ------------------------------------------
void readAllData() {
  byte piccType = mfrc522.PICC_GetType(mfrc522.uid.sak); // SAK（NFCタグの識別子）を取得し、変数に格納
  // カードタイプ確認
  if (piccType == MFRC522_I2C::PICC_TYPE_MIFARE_MINI ||
      piccType == MFRC522_I2C::PICC_TYPE_MIFARE_1K ||
      piccType == MFRC522_I2C::PICC_TYPE_MIFARE_4K) {
    mfrc522.PICC_DumpToSerial(&(mfrc522.uid));          // Mifare Classicのデータを出力
  } else if (piccType == MFRC522_I2C::PICC_TYPE_MIFARE_UL) {
    mfrc522.PICC_DumpMifareUltralightToSerial();        // Mifare Ultralightのデータを出力
  } else {
    M5.Lcd.setTextColor(RED, BLACK);
    M5.Lcd.fillRect(0, 57, 320, 200, BLACK);            // 液晶のデータ表示部を黒塗りリセット
    M5.Lcd.setCursor(0, 57);                            // 座標表示
    M5.Lcd.println("This card is not supported.");      // サポートされていないカードである旨を表示
    delay(5000);
  }
  mfrc522.PICC_HaltA(); // 現在読み込んでいるカードをハルトする
  mfrc522.PCD_Init();   // RFIDリーダーを初期化する
}

// ブロックデータ読み込み ------------------------------------------
void readData(int sector, int block) {  // (セクター番号, ブロック番号)
  MFRC522_I2C::MIFARE_Key key = {0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF}; // MIFARE_Key構造体でセクター認証キーを準備（ポインタで指定するため）
  Serial.println("カードデータ読み取り");

  uint8_t address = sector * 4 + block;         // ブロックアドレスを算出
  // 読込み対象のセクターを認証する(認証キータイプ, ブロックアドレス, 認証キーポインタ, カードのUIDプロパティへのポインタ)
  if (mfrc522.PCD_Authenticate(MFRC522_I2C::PICC_CMD_MF_AUTH_KEY_A, address, &key, &(mfrc522.uid)) == MFRC522_I2C::STATUS_OK) {
    Serial.println("認証に成功しました");
    byte buffer[18];                            // 読込みデータ16byte + エラーチェック用CRC用2byte分の配列を準備
    byte bufferSize = sizeof(buffer);           // バッファサイズをポインタで指定できるように準備
    // 認証成功で読込み実行(ブロックアドレス, データ格納バッファ配列ポインタ, 読込みデータバッファサイズポインタ)
    if (mfrc522.MIFARE_Read(address, buffer, &bufferSize) == MFRC522_I2C::STATUS_OK) { // 通信成功なら
      for (int i = 0; i < bufferSize-2; i++) {  // 読込んだデータのCRCを除いた16byte分繰り返す
        read_data[i] = buffer[i];               // バッファを読み込みデータ配列に格納
        Serial.printf("%02X ", read_data[i]);   // 16byteの読み込みデータをシリアルモニタに出力
      }
      Serial.printf("\n%s\n", read_data);
    }
  } else {
    Serial.println("認証に失敗しました");
  }
  mfrc522.PCD_StopCrypto1();  // 認証済み解除
}

// ブロックデータ書込み -------------------------------------------
void writeData(int sector, int block) { // (セクター番号, ブロック番号)
  MFRC522_I2C::MIFARE_Key key = {0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF}; // MIFARE_Key構造体でセクターキーを準備（ポインタで指定するため）
  Serial.println("カードデータ書込み");

  uint8_t address = sector * 4 + block;         // ブロックアドレスを算出
  // 書込み対象のセクターを認証する(認証キータイプ, ブロックアドレス, 認証キーポインタ, カードのUIDプロパティへのポインタ)
  if (mfrc522.PCD_Authenticate(MFRC522_I2C::PICC_CMD_MF_AUTH_KEY_A, address, &key, &(mfrc522.uid)) == MFRC522_I2C::STATUS_OK) {  // 通信成功なら
    Serial.println("認証に成功しました");
    if (address == 0 || block == 3) {                 // ブロックアドレスが0またはブロック3なら書込まず終了
        Serial.print("データブロックではないので書き込めません");
    } else {                                          // ブロック0〜2ならデータ書込み
      mfrc522.MIFARE_Write(address, write_data, 16);  // (ブロックアドレス, 書込みデータ, 書込みbyte数)
      // 書き込みデータをシリアルモニタに出力
      for (int i = 0; i < 16; i++) {            // 16byte分繰り返す
        Serial.printf("%02X ", write_data[i]);  // 16進数で出力
      }
    }
    Serial.printf("\n%s\n", write_data);
  } else {
    Serial.println("認証に失敗しました");
  }
  // カードから切断する
  mfrc522.PCD_StopCrypto1();  // 認証済み解除
}

// セクタートレーラーの初期値を設定
byte sector_traler[16] = {0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF,  // 認証キーA（初期値）
                          0xFF, 0x07, 0x80, 0x69,              // アクセスコンディション（初期値）
                          0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF}; // 認証キーB（初期値）
byte access_bits[4];       // 各ブロックの設定したいアクセスビットを格納(下位3bit)
byte access_condision[3];  // アクセスコンディション算出結果格納用

// 各ブロック（0〜3）のアクセスビット(Access bits)を設定
access_bits[3] = 0x01;     // ブロック3（セクタートレーラー）のアクセスビットを設定（[C1 C2 C3] = [0 0 1]の時「b00000001」）
access_bits[2] = 0x00;     // ブロック2のアクセスビットを設定（[C1 C2 C3] = [0 0 0]の時「b00000000」）
access_bits[1] = 0x02;     // ブロック1のアクセスビットを設定（[C1 C2 C3] = [0 1 0]の時「b00000010」）
access_bits[0] = 0x03;     // ブロック0のアクセスビットを設定（[C1 C2 C3] = [0 1 1]の時「b00000011」）
// 各ブロック（0〜3）のアクセスビットの設定からアクセス条件(ブロック3の6〜8byte目の値)を算出
mfrc522.MIFARE_SetAccessBits(access_condision, access_bits[0], access_bits[1], access_bits[2], access_bits[3]);

// 算出したアクセスコンディションをセクタートレーラーの6〜8byteに設定
for (int i = 0; i < 3; i++) {
  sector_traler[i + 6] = access_condision[i];
}
// 液晶、シリアルモニタ表示
M5.Lcd.setTextColor(GREEN, BLACK);
M5.Lcd.printf("AccessBits : [");
Serial.print("Access_condision: [");
for (int i = 0; i < 3; i++) {
  M5.Lcd.printf("%02X ", sector_traler[i + 6]);
  Serial.printf("%02X ", access_condision[i]);
}
M5.Lcd.println("]");
Serial.println("]");