M5Stackをシリアルモニターに使用。パソコン不要でデータ確認Atom、Arduinoに便利

#include <M5Stack.h>    // CORE2の場合は <M5Core2.h>

#define LGFX_AUTODETECT // 自動認識(D-duino-32 XS, PyBadgeはパネルID読取れないため自動認識の対象から外れているそうです)
#define LGFX_USE_V1     // v1.0.0を有効に(v0からの移行期間の特別措置とのこと。書かない場合は旧v0系で動作)
#include <LovyanGFX.hpp>          // lovyanGFXのヘッダを準備
#include <LGFX_AUTODETECT.hpp>    // クラス"LGFX"を準備
static LGFX lcd;                  // LGFXのインスタンスを作成（クラスLGFXを使ってlcdコマンドでいろいろできるようにする）
static LGFX_Sprite canvas(&lcd);  // スプライトを使う場合はLGFX_Spriteのインスタンスを作成
// 変数宣言
char c;               // 受信データ（文字）格納用
int c_cnt = -1;        // 文字数カウント
String row[15] = {};  // 行配列
bool disp_set = 0;    // 画面出力フラグ

// 関数 ---------------------------------------------------------
/* --------------- 行スクロール処理関数 --------------- */
void scroll_disp() {
  for (int i = 1; i < 15; i++) {  // 最上行以外の14行分繰り返し
    row[i-1] = row[i];            // 行配列を左へシフト（上スクロール）
  }
  row[14] = "";                   // 最下行の表示を消去 
}
/* ---------- スクロール後の行一括表示処理関数 ---------- */
void disp_out() {                 // 表示実行（15行一括表示）
  canvas.fillScreen(BLACK);       // 画面リセット（黒塗り潰し）
  canvas.setCursor(0, 0);         // カーソル原点
  for (int i = 0; i < 15; i++) {  // 15行分繰り返し
    canvas.println(row[i]);       // 行配列を改行しながら順番に表示
  }
  canvas.pushSprite(0, 0);        // メモリ内に描画したcanvasを座標を指定して表示する
}
// 初期設定 ------------------------------------------------------
void setup() {
  M5.begin(true,true,true,false);           // 本体初期化（LCD, SD, Serial, I2C）※I2Cのみ無効
  Serial.begin(9600);                       // シリアル通信初期化(USBと共用、初期値は RX=G3, TX=G1)
  Serial1.begin(9600, SERIAL_8N1, 21, 22);  // シリアル通信1初期化(RX, TX) ※BASIC, GRAYのポートA
  // Serial1.begin(9600, SERIAL_8N1, 32, 33);  // シリアル通信1初期化(RX, TX) ※CORE2のポートA
  Serial2.begin(9600);                      // シリアル通信2初期化(初期値は RX=G16, TX=G17)※CORE2はG13,14

  // LCD初期設定
  lcd.init();                 // LCD初期化
  canvas.setColorDepth(8);    // カラーモード設定
  canvas.createSprite(lcd.width(), lcd.height()); // canvasサイズ（メモリ描画領域）設定（画面サイズに設定）

  // スプライト表示設定（canvas.で指定してメモリ内の仮想画面に描画）
  canvas.fillScreen(BLACK);           // 背景塗り潰し
  canvas.setTextColor(WHITE);         // 文字色
  // 液晶初期表示（シリアルデータ通信速度、使用端子番号）
  canvas.setFont(&fonts::Font4);                  // フォント設定
  canvas.println("Serial Monitor (9600bps)");     // 初期表示
  canvas.setFont(&fonts::Font2);                  // フォント設定
  canvas.println("Serial \n  RX = 3(R0)    / TX = 1(T0)    / GND = G");
  canvas.println("Serial1 (GROVE)\n  RX = 21        / TX = 22       / GND = G"); // BASIC, GRAYの場合
  // canvas.println("Serial1 (GROVE)\n  RX = 32        / TX = 33       / GND = G"); // ※CORE2の場合
  canvas.println("Serial2 \n  RX = 16(R2)  / TX = 17(T2)   / GND = G\n"); // BASIC, GRAYの場合
  // canvas.println("Serial2 \n  RX = 13(R2)  / TX = 14(T2)   / GND = G\n"); // ※CORE2の場合

  canvas.println("ButtonA : Scroll UP");
  canvas.println("ButtonB : Gothic");
  canvas.println("ButtonC : Mincho");
  canvas.pushSprite(0, 0);                        // メモリ内に描画したcanvasを座標を指定して表示する

  canvas.setFont(&fonts::lgfxJapanGothic_16);     // フォント日本語ゴシック（16px、等幅）
}
// メイン ------------------------------------------------------
void loop() {
  M5.update();  //本体のボタン状態更新
  // 受信データ処理
  if (Serial.available() || Serial1.available() || Serial2.available()) {  // 受信データがあれば
    disp_set = 1;                                     // 画面出力フラグ1
    if (int(Serial.available() || Serial1.available() || Serial2.available()) <= 64) {  // 受信データ64byte(MAX)以下なら
      if (Serial.available()) {c = Serial.read();}    // 1文字づつ文字変数に格納(Serial)
      if (Serial1.available()) {c = Serial1.read();}  // 1文字づつ文字変数に格納(Serial1)
      if (Serial2.available()) {c = Serial2.read();}  // 1文字づつ文字変数に格納(Serial2)
    }
    // 行スクロール処理（改行、半角、全角判定）
    if (c == '\n') { // 「改行」を受信したら
      c_cnt = 0;     // 文字数カウントを0リセット
      scroll_disp(); // 行スクロール処理
    } else {         // 「改行」でなければ（文字コードから全角半角を判定して文字数カウント）
      if (c <= 0x7F) {              // ASCII文字（半角）なら
        c_cnt++;                    // 文字数カウント+1
      }
      if (c >= 0xE0 && c <= 0xEF) { // 全角なら（半角ｶﾅは全角としてカウント）
        c_cnt = c_cnt + 2;          // 文字数カウント+2
      }
      if (c_cnt >= 39) {  // 文字数カウントが39なら
        c_cnt = 0;        // 文字数カウント0リセット
        scroll_disp();    // 行スクロール処理
        disp_out();       // スクロール後の行一括表示処理
      }
      row[14] += c;       // 行配列の最下行に1文字づつ追加して文字列へ
    }
  } else {                // 受診データがなければ
    if (disp_set == 1) {  // 画面出力フラグが1なら
      disp_set = 0;       // 画面出力フラグ0セット
      disp_out();         // スクロール後の行一括表示処理
    }
  }
  // ボタン操作処理
  if (M5.BtnA.wasPressed()) { // ボタンAが押されていれば
    scroll_disp();            // 行スクロール処理
    disp_out();               // スクロール後の行一括表示処理
  }
  if (M5.BtnB.wasPressed()) { // ボタンBが押されていれば
    canvas.setFont(&fonts::lgfxJapanGothic_16); // 日本語ゴシック体（16px、等幅）
    canvas.fillScreen(BLACK);                   // 背景塗り潰し
    canvas.setCursor(0, 0);                     // カーソルを(0, 0)へ
    canvas.println("フォント変更\nゴシック体");     // フォント設定表示
    canvas.pushSprite(0, 0);                    // メモリ内に描画したcanvasを座標を指定して表示する
  }
  if (M5.BtnC.wasPressed()) { // ボタンCが押されていれば
    canvas.setFont(&fonts::lgfxJapanMincho_16); // 日本語明朝体（16px、等幅）
    canvas.fillScreen(BLACK);                   // 背景塗り潰し
    canvas.setCursor(0, 0);                     // カーソルを(0, 0)へ
    canvas.println("フォント変更\n明朝体");        // フォント設定表示
    canvas.pushSprite(0, 0);                    // メモリ内に描画したcanvasを座標を指定して表示する
  }
}

if (c <= 0x7F) {              // ASCII文字（半角）なら
  c_cnt++;                    // 文字数カウント+1
}
if (c >= 0xE0 && c <= 0xEF) { // 全角なら（半角ｶﾅは全角としてカウント）
  c_cnt = c_cnt + 2;          // 文字数カウント+2
}

#include <M5Atom.h>    //M5Atomのヘッダファイルを準備
CRGB dispColor(uint8_t r, uint8_t g, uint8_t b) { //FastLEDライブラリの設定（CRGB構造体）
  return (CRGB)((r << 16) | (g << 8) | b);
}
// 初期設定 -----------------------------------------------
void setup() {
  M5.begin(true, false, true);              // 本体初期化（UART, I2C, LED）
  Serial.begin(9600);                       // 標準のシリアル通信初期化(RX, TX)
  Serial2.begin(9600, SERIAL_8N1, 32, 26);  // シリアル通信2初期化(RX, TX)
  // 初期LED白点灯（赤, 緑, 青）
  M5.dis.drawpix(0, dispColor(20, 20, 20));
}
// メイン -------------------------------------------------
void loop() {
  M5.update();  //本体のボタン状態更新
  if (M5.Btn.wasPressed()) {                   //ボタンが押されていれば
    M5.dis.drawpix(0, dispColor(0, 30, 30));   //LED水色

    for (int i = 0; i < 12; i++) {Serial2.println("");} // スクロールクリア
    Serial2.println("  ∧_∧    ｶﾀ");  delay(100);
    Serial2.println("(´･ω･ `)  ／ シリアルデータを");  delay(100);
    Serial2.println("  U U       ＼ M5Stackに表示！");  delay(100);
    Serial2.println(" ＼ Hello  ＼");  delay(100);
    Serial2.println("   ＼        ＼          ｶﾀ");  delay(100);
    Serial2.println(" ｶﾀ  ＼        ＼");  delay(100);
    Serial2.println("");  delay(100);
    delay(3000);

    for (int i = 0; i < 12; i++) {Serial2.println("");} // スクロールクリア
    Serial2.print("０１２３４５６７８９0123456789いろはにほへとちりぬるをわかよたれそつねならむうゐのおくやまけふこえてABCDEFGHIJKLMNOPQRSTUVWXYZＡＢＣＤＥＦＨＩＪＫＬＭＮＯＰＱＲＳＴＵＶＷＸＹＺabcdefghijklmnopqrstuvwxyz!\"#$%&'()*+,-./:;<=>?@[\\]^_`{|}~寿限無、寿限無、五劫のすりきれ海砂利水魚の水行末、雲来末、風来末食う寝るところに住むところやぶら小路のぶら小路パイポパイポ、パイポのシューリンガンシューリンガンのクーリンダイクーリンダイのポンポコナーのポンポコピーの長久命の長助『』【】〆→↓←↑≧≦〒・、。⊂⊃∪∩／＼￥∴⊥∠≡…：‖＿＊▽▼≪∀ゞ≠§○△□×●▲■◇");
    Serial2.println("");
    delay(4000);

    for (int i = 0; i < 12; i++) {Serial2.println("");} // スクロールクリア
    Serial2.println("　　┏━━━━━━━━━━━━━━┓");
    Serial2.println("　　┃┏━━━━━━━━━━━━┓┃");
    Serial2.println("　　┃┃         ／  ＼         ┃┃");
    Serial2.println("　　┃┃      ／  ／    ＼      ┃┃");
    Serial2.println("　　┃┃   ／  ／    ＿    ＼   ┃┃");
    Serial2.println("　　┃┃   ＼  ＼ ／   │　／   ┃┃");
    Serial2.println("　　┃┃  │　＼    ＿／ ／ │  ┃┃");
    Serial2.println("　　┃┃  │　   ＼   ／    │  ┃┃");
    Serial2.println("　　┃┃  │　              │  ┃┃");
    Serial2.println("　　┃┃   ＼              ／   ┃┃");
    Serial2.println("　　┃┃      ＼        ／      ┃┃");
    Serial2.println("　　┃┃         ＼  ／         ┃┃");
    Serial2.println("　　┃┗━━━━━━━━━━━━┛┃");
    Serial2.println("　　┗━━━━━━━━━━━━━━┛");
    delay(1500);

    for (int i = 0; i < 12; i++) {Serial2.println("");} // スクロールクリア
    Serial2.println("　　　　　　　　　　　 ロジカラブログ");  delay(100);
    Serial2.println("　　　　　　　　　　　 logikara.blog");  delay(100);
    for (int i = 0; i < 5; i++) {Serial2.println("");  delay(100);}  // スクロールクリア
    Serial2.println("  ∧_∧");  delay(100);
    Serial2.println("(´ >ω<`)  ／ 使える・・");  delay(100);
    Serial2.println("　  U U     ＼ ・・と思う・・");  delay(100);
    Serial2.println(" ＼        ＼");  delay(100);
    Serial2.println("   ＼        ＼        ｶﾀ");  delay(100);
    Serial2.println("ｶﾀ   ＼        ＼");  delay(100);
    Serial2.println("");  delay(100);
  } else {                                    //ボタンが押されてなければ
    M5.dis.drawpix(0, dispColor(20, 20, 20)); //LED（白）
  }
  delay(100);   //100ms待機
}