M5StickS3の使い方、初期設定、サンプルプログラム、旧モデルとの違いを詳しく紹介

[env:m5stack-sticks3]
platform = espressif32@6.12.0
board = esp32-s3-devkitc-1
framework = arduino
board_build.arduino.partitions = default_8MB.csv
board_build.arduino.memory_type = qio_opi
build_flags =
    -DESP32S3
    -DBOARD_HAS_PSRAM
    -mfix-esp32-psram-cache-issue
    -DCORE_DEBUG_LEVEL=5
    -DARDUINO_USB_CDC_ON_BOOT=1
    -DARDUINO_USB_MODE=1
lib_deps =
    M5Unified=https://github.com/m5stack/M5Unified
    M5PM1=https://github.com/m5stack/M5PM1 

#include <M5Unified.h>  // M5Stackシリーズ用共通ライブラリ
#include <M5GFX.h>      // グラフィックライブラリ（Canvas使用時はインクルード必要）

M5Canvas canvas(&M5.Display); // メモリ描画領域の設定

// 初期設定 *****************************************************
void setup() {
  auto cfg = M5.config(); // M5Unifiedの設定を取得
  M5.begin(cfg);          // M5Unifiedの初期化
  
  M5.Speaker.setVolume(150);  // ブザー音量設定（0～255）

  M5.Display.begin();
  M5.Display.setRotation(1);        // 必要なら画面回転
  M5.Display.fillScreen(TFT_BLACK); // 初期画面

  canvas.createSprite(M5.Display.width(), M5.Display.height()); // メモリ描画サイズを設定
  canvas.setFont(&fonts::lgfxJapanGothicP_28);  // フォント設定
  canvas.setTextSize(1);          // 文字サイズ
  canvas.setTextColor(TFT_WHITE); // 文字色

  M5.Power.setExtOutput(true);    // 外部電源を有効化（安定化）
}

// メインループ *************************************************
void loop() {
  M5.update();  // ボタン状態更新
  canvas.fillScreen(TFT_BLACK); // 背景色 黒

  bool isCharging = M5.Power.isCharging();  // 充電状態取得
  int vol_per = M5.Power.getBatteryLevel(); // バッテリー残量パーセント取得
  int vol = M5.Power.getBatteryVoltage();   // バッテリー電圧取得

  //  本体ボタン処理
  if (M5.BtnA.wasPressed()) {
    canvas.fillScreen(TFT_BLUE);  // 背景色 青
    M5.Speaker.tone(3000, 100);  // ブザー(周波数, 音の長さ)
  }
  if (M5.BtnB.wasPressed()) {
    canvas.fillScreen(TFT_RED); // 背景色 赤
    M5.Speaker.tone(1000, 200);  // ブザー(周波数, 音の長さ)
  }
  
  //  ディスプレイ表示処理
  canvas.drawString("M5StickS3 TEST", 0, 0);    // タイトル
  canvas.drawFastHLine(0, 32, 230, WHITE);      // 境界線
  canvas.setCursor(0, 34);                      // 座標指定
  canvas.setTextColor(TFT_WHITE);               // 文字色
  canvas.printf("Charging: %s \n", isCharging ? "Yes" : "No");  // 充電状態表示
  canvas.printf("Bat_level: %d%%\n", vol_per);  // バッテリー残量パーセント表示
  canvas.printf("Bat_volt: %d%mV\n", vol);      // バッテリー電圧表示
  canvas.pushSprite(5, 0);   // 画面に反映
  
  delay(200);  // 遅延時間
}

#include <M5Unified.h>  // M5Stackシリーズ用共通ライブラリ
#include <M5GFX.h>      // グラフィックライブラリ（Canvas使用時はインクルード必要）

#define IN      0     // 入力端子
#define OUT     1     // 出力端子
#define ADC     10    // アナログ入力端子
#define LED_PIN 8     // PWM の端子番号
#define PWM_CH0 0     // PWM チャンネル
#define PWM_FREQ 1000 // PWM 周波数
#define BIT_NUM 10    // bit10数 10bit (0〜1023)

M5Canvas canvas(&M5.Display); // メモリ描画領域の設定

// 変数宣言
float ad_val;    // アナログ入力値格納用 12bit (0〜4095)
float ad_volt;   // アナログ入力格納電圧換算用 (0〜3.3V)
float duty = 0;  // アナログ入力電圧換算値をPWNのDuty比へ
bool btn_state = false; // 本体ボタンA,Bの状態
bool led_state = false; // LEDの状態
bool state = false;     // ボタン状態の保持

// 初期設定 *****************************************************
void setup() {
  auto cfg = M5.config(); // M5Unifiedの設定を取得
  M5.begin(cfg);          // M5Unifiedの初期化

  // 入出力端子設定
  pinMode(IN, INPUT_PULLUP); // 入力設定（プルアップ）
  pinMode(OUT, OUTPUT);      // 出力設定
  digitalWrite(OUT, LOW);    // 出力初期値

  // アナログ入力設定
  pinMode(ADC, ANALOG); // アナログ入力

  // PWM 初期化
  ledcSetup(PWM_CH0, PWM_FREQ, BIT_NUM); // PWM1出力波形の初期設定（チャンネル、周波数、分解能bit）
  ledcAttachPin(LED_PIN, PWM_CH0);       // チャンネルに対する出力端子を設定

  M5.Display.begin();
  M5.Display.setRotation(1);        // 必要なら画面回転
  M5.Display.fillScreen(TFT_BLACK); // 初期画面

  canvas.createSprite(M5.Display.width(), M5.Display.height());
  canvas.setFont(&fonts::lgfxJapanGothicP_28);  // フォント設定
  canvas.setTextSize(1);
  canvas.setTextColor(TFT_WHITE);
}

// メインループ *************************************************
void loop() {
  M5.update();  // ボタン状態更新

  //  本体ボタン処理
  if (M5.BtnA.wasPressed()) {
    btn_state = true;  // ボタン状態をtrueに
    led_state = true;  // 外部LED状態をtrueに
  }
  if (M5.BtnB.wasPressed()) {
    btn_state = false; // ボタン状態をfalseに
    led_state = false; // 外部LED状態をfalseに
  }

  // 外部スイッチ入力処理
  if (digitalRead(IN) == LOW && state == false) {
    state = true;           // ボタン状態stateをtrue
    led_state = !led_state; // 外部LED状態を反転
  }
  if (digitalRead(IN) == HIGH) { // ボタンCと外部入力がOFFなら
    state = false;          // ボタン状態stateをfalse
  }

  // 外部LED点灯処理
  if (led_state) {
    digitalWrite(OUT, HIGH); // LED点灯
  }
  else {
    digitalWrite(OUT, LOW);  // LED消灯
  }
  
  // アナログ入力処理
  ad_val = analogRead(ADC); // アナログ入力値を取得(0〜4095、12bit)
  ad_volt = 3.3 * (ad_val / 4095);   // アナログ入力電圧(0～3.3V)へ換算
  duty = ad_val * (1023.0 / 4095.0); // 1023Vへ換算
  ledcWrite(PWM_CH0, (int)duty);     // アナログ入力値をDuty比に指定してPWM出力(チャンネル, Duty比)

  //  ディスプレイ表示処理
  if (btn_state) {  // 本体ボタンA,Bの状態true(AがONされた)
    canvas.fillScreen(TFT_BLUE);  // 背景色 青
  }
  else {
    canvas.fillScreen(TFT_BLACK); // 背景色 黒
  }
  canvas.drawString("M5StickS3 TEST", 0, 0);    // タイトル
  canvas.drawFastHLine(0, 32, 230, WHITE);      // 境界線
  canvas.setCursor(0, 34);                      // 座標指定
  canvas.setTextColor(TFT_WHITE);               // 文字色
  canvas.printf("ADC_val:  %.0f\n", ad_val);    // アナログ入力値表示
  canvas.printf("ADC_volt: %.2fV\n", ad_volt);  // アナログ電圧換算値表示
  canvas.printf("PWM_duty: %.0f\n", duty);      // PWM Duty比表示
  canvas.pushSprite(5, 0);   // 画面に反映
  
  delay(100);  // 遅延時間
}