ボリュームで7色変化！フルカラーLEDコントローラーを作ろう「ATOM LITE」

#include <M5Atom.h>   //Atomのヘッダファイルを準備

// FastLEDライブラリの設定（CRGB構造体）
CRGB dispColor(uint8_t r, uint8_t g, uint8_t b) {
  return (CRGB)((r << 16) | (g << 8) | b);
}
// 変数宣言
float an_val;       //アナログ換算値（0～4095）格納用
float an_volt;      //アナログ電圧（0～3.3V）格納用
float r,g,b;        //LED明るさ指定用（赤、緑、青）
int cnt = 0;        //シリアル表示周期カウント用

// 初期設定 -----------------------------------------------
void setup() {
  M5.begin(true, false, true);  //Serial,POWER,LED
  Serial.begin(9600);           //標準のシリアル通信設定
  pinMode(33, ANALOG);          //アナログ入力端子設定
}
// メイン -------------------------------------------------
void loop() {
  r = 0;  //LED赤色0リセット
  g = 0;  //LED緑色0リセット
  b = 0;  //LED青色0リセット

  // アナログ入力処理
  an_val = analogRead(33);          //アナログ換算値（0～4095）取得
  an_volt = (3.3 / 4095) * an_val;  //アナログ電圧（0～3.3V）換算

  //LED色可変
  if(an_val < 1365) {   //アナログ値が1365より小さいなら赤、緑指定
    g = (an_val / 5.353);             //緑を指定（0～255へ換算）
    r = 255 - g;                      //緑が明るくなったら赤を暗く
  } else if(an_val >= 1365 && an_val < 2730) {
                //アナログ値が1365以上2730より小さいなら赤、緑指定
    b = ((an_val - 1365) / 5.353);    //青を指定（0～255へ換算）
    g = 255 - b;                      //青が明るくなったら緑を暗く
  } else if(an_val >= 2730) { //アナログ値が1365以上なら青、赤指定
    r = ((an_val -2730) / 5.353);     //赤を指定（0～255へ換算）
    b = 255 - r;                      //赤が明るくなったら青を暗く
  }
  M5.dis.drawpix(0, dispColor((int)r, (int)g, (int)b)); //LED点灯

  //シリアル出力周期（10ms × 100 = 1000ms）
  if(cnt == 100) {                //周期カウント100でシリアル出力
    // AN:アナログ値　VOLT：アナログ電圧換算値　LED色指定値（R,G,B）
    Serial.printf("AN = %d  VOLT = %1.2fV  R,G,B = %d, %d, %d\n",
                  (int)an_val, an_volt, (int)r, (int)g, (int)b);
    cnt = 0;  //周期カウント0リセット
  }
  cnt++;      //周期カウント+1
  delay(10);  //10ms待機
}